エクセルの条件付き書式で同じ曜日毎に交互に行の色を変えたいのですが・・・

質問

エクセルの条件付き書式で同じ曜日毎に交互に行の色を変えたいのですが・・・
順番にずっと曜日が並んでいるわけではなく、抜けている曜日があったりするので、単純に「$A1=1」「$A1=2」「$A1=3」・・・などと設定すると交互ではなくなってしまいます・・・
3日ほど色々条件を考えたのですが・・・出来ませんでした・・・
どなたか詳しい方、教えてください。

下記のような感じで並んでいます。
　　　Ａ　　　Ｂ　　　Ｃ　　　Ｄ　・・・・
１　　月　　（この行を赤にしたい）
２　　月　　（この行を赤にしたい）
３　　水　　（この行を白にしたい）
４　　木　　（この行を赤にしたい）
５　　木　　（この行を赤にしたい）
６　　木　　（この行を赤にしたい）
７　　土　　（この行を白にしたい）
８　　土　　（この行を白にしたい）
・
・
・
どうかよろしくお願いします。

回答No.7

rukuku

こんにちは

作業列を２つ使ったやり方です。
オートフィルの都合上、データは２行目から始まっているとします。
D列とE列を作業列に使うとします。なおD1とE1は空欄にしておいてください。
D2に
=A2=A1
E2に
=IF(D2,E1,NOT(E1))
以下オートフィルします。そして、条件付書式で、E列がTrueのときに表示を赤にします。

考え方としては、まずD列で上の行と同じ曜日かを判定します。
そして、E列で色の記号を切り替えます。同じ曜日だったらそのまま、違う曜日だったら記号を変えます。

これを一つにまとめて（F列を使うとします）
=IF(A2=A1,F1,NOT(F1))
とすることも出来ます。

回答No.6

popuplt

条件付き書式設定したい範囲を選択して
=MOD(SUMPRODUCT(1/COUNTIF($A$1:$A1,$A$1:$A1)),2)
書式＝[赤]
行数が多いと重いかな？

お礼

回答していただいた皆様ありがとうございました。
補助列は作りたくなかったので・・・

書式設定したい行範囲がA2からD100だとしたら（質問ではA1からになってますが・・・）
条件付き書式設定したい選択範囲を「$A$2:$D$100」にして
条件を・・・
=MOD(SUMPRODUCT(($A$1:$A1<>$A$2:$A2)*1),2)=1
で、うまくいきました。

ありがとうございました。

回答No.5

KURUMITO

回答Ｎｏ３です。
次のように変更してください。
２行目からデータがあるとして作業列への入力の式は次のように変更してください。
Ｅ２セルに次の式を入力して下方にオートフィルドラッグします。
=IF(A2="","",IF(A2<>A1,MAX(E$1:E1)+1,E1))
次にＦ２セルに次の式を入力して下方にオートフィルドラッグします。
=IF(E2="","",MOD(E2,2))

回答No.4

某HN クロメート(Chromate)（@CoalTar）

案１(非推奨)
1行目は赤くするとして、２行目を選択して条件付き書式
数式が =MOD(SUMPRODUCT(($A$1:$A1<>$A$2:$A2)*1),2)=0
書式を赤にする 下へ書式のみ行ごとオートフィル

案２(推奨)
B1セルに TRUE
B2セルに =IF(A1=A2,B1,NOT(B1))
下へオートフィル
１行目を選択して条件付き書式
数式が =$B1
書式を赤にする 下へ書式のみ行ごとオートフィル

おのおの添付図参照

回答No.3

KURUMITO

作業列を作って対応することになるでしょう。
たとえばＥ１セルに次の式を入力して下方にオートフィルドラッグします。
=COUNTIF(A$1:A1,A1)
次にＦ１セルに次の式を入力して下方にオートフィルドラッグします。
=MOD(COUNTIF(E$1:E1,1),2)
各行は１か０に分かれますので１の行を赤くするようにします。
行をたとえば１行目から１００行目までを選択します。
その後に「条件付き書式」の設定で数式には次の式を入力して書式では塗りつぶしの色を赤に設定してＯＫします。
=$F1=1
EやＦの列が目障りでしたら列を非表示にすればよいでしょう。

回答No.2

tom04

こんにちは！
土曜日の場合の「白」は何もしなくても「白」になると思いますので

とりあえずA列に「月」または「木」が入力された場合、その行すべてが「赤」にする条件付書式になります。

条件付書式を適用したい行すべてを範囲指定します。

メニュー　→　書式　→　条件付書式　で
「数式が」を選択　→　数式欄に

=OR($A1="月",$A1="木")　と入力　→　書式　→　パターン　→　赤　を選択

これで希望に近い形にならないでしょうか？

以上、当方使用のExcel2003での回答でした。

尚、どうしても「土」を白に！ということであれば、条件2を同様に追加してみたください。

そして、今回の回答は行すべてに適用されてしまいますが、
条件付書式を適用させたい範囲指定がある場合は
セルの範囲指定をした後に、上記の操作方法を行えばOKかとおもいます。

以上、長々と失礼しました。
参考になれば幸いです。m(__)m

回答No.1

a987654

このままでは無理です。
補助列を（例えばＺ列）を使い、先頭のデータが２行目だとしたら
Ｚ２セルに０、Ｚ３セルに　=IF(A3=A2,Z2,MOD(Z2+1,2))
Ｚ３セルを必要行だけコピーする。
これでＺ列は０と１で区分けされますのであとは
条件付き書式の設定を”数式が”にしてＺ列の０と１で設定すれば
ご希望通りになります。