同じ種類の単語だけを抽出したい

質問

はじめまして。
いま、Wordに以下のようなデータがあります。
　　What_2 is_1 a_1 burrito_0? What_2 is_1 that_3?
（各英単語の後ろに、アンダーバーと数字がついています）
これを、同じ数字が付いている単語を抽出してエクセル等でリストを
作りたいのですが、何か良い方法はないでしょうか？
たとえば、以下のようなリストが理想です。
（英単語の後ろにある数値は頻度です）
----------
0
burrito 1

1
a 1
is 2

2
what 2
----------
どうぞ、よろしくお願い致します。

回答No.1

mitarashi

Excel VBAのコードです。先日文章中の特定文字列のカウントの回答をしたものを改造してみました。ご呈示の文例では動作しましたが、他の文例に対しても適用できるかどうかは不明ですので、あらかじめ言い訳をしておきます。
'A部のコメントアウトを外すと、テキストファイルを読み込んで処理します。（Wordのファイルではありませんので悪しからず。Wordからテキスト形式で保存してから処理してください。実際のテキストファイルのパス、ファイル名に合わせてコードを変更して下さい。）
その場合、B部のテストデータ部はコメントアウトして下さい。
末尾のmyCellPrintは、debug.printで試験したのを書き換えるのが面倒なので、ワークシート上でシミュレートしようと即興で作成してみました。分かり難くしているだけと思いますがご容赦下さい。
Dim rowCounter As Long

Sub Test()
Dim FSO, buf As String
Dim strPattern As String
Dim srcFilePath As String
Dim Matches As Variant
Dim i As Long, j As Long
Dim myDic As Object
Dim myKey As Variant
Dim hitWord As String

'A:read from Textfile
' srcFilePath = "C:\Documents and Settings\?????\デスクトップ\testText.txt"
' Set FSO = CreateObject("Scripting.FileSystemObject")
' With FSO.GetFile(srcFilePath).OpenAsTextStream
' buf = .ReadAll
' .Close
' End With
' Set FSO = Nothing

'B:Test Data
buf = "What_2 is_1 a_1 burrito_0? What_2 is_1 that_3?"

rowCounter = 0
Cells.Clear
For j = 0 To 9 Step 1
strPattern = "(\S+)_" & CStr(j) & "[ .?]"
With CreateObject("VBScript.RegExp")
.Pattern = strPattern
.Global = True
Set Matches = .Execute(buf)
End With
myCellPrint j
If Matches.Count > 0 Then
Set myDic = CreateObject("Scripting.Dictionary")
For i = 0 To Matches.Count - 1
hitWord = Matches(i).submatches(0)
If Not myDic.exists(hitWord) Then
myDic.Add hitWord, 1
Else
myDic.Item(hitWord) = myDic.Item(hitWord) + 1
End If
Next i
myKey = myDic.keys
For i = 0 To myDic.Count - 1
myCellPrint myKey(i), myDic.Item(myKey(i))
Next i
Set myDic = Nothing
End If
myCellPrint
Next j
End Sub

'debug.print をワークシートでシミュレートしたつもり
Sub myCellPrint(Optional arg1 As Variant, Optional arg2 As Variant)
If rowCounter = 0 Then rowCounter = 1
If Not IsMissing(arg1) Then
Cells(rowCounter, 1).Value = arg1
If Not IsMissing(arg2) Then Cells(rowCounter, 2).Value = arg2
End If
rowCounter = rowCounter + 1
End Sub
正規表現でパターンマッチングしています。
strPattern = "(\S+)_" & CStr(j) & "[ .?]"
のところは環境に合わせて修正して下さい。
「VBA 正規表現」で検索すると多数参考サイトが見つかります。

補足

mitarashiさま、ご返答いただき、ありがとうございます。
せっかくVBAコードを書いていただいて恐縮ですが、、VBAの知識がなくExcelに組み込むことすらできないので、残念ながら実行出来ません。
もしもお時間があるようでしたら、エクセルのど素人にも分かるように使い方を教えていただけないでしょうかm_ _m