わからない・・・!!!

質問

Flashド素人です。一応、1フレームずつ画像やオブジェクトの形を変える、いわゆる根性アニメーションを作ったり、ボタンやマウス操作などの要素の入った簡単なASは書いたことがある程度です。
とあるフラッシュを作らなくてはならないのですが、調べても本を読んでみてもわからなくて何をどうしていいやら・・・とお手上げ状態で困っています。
作りたいフラッシュの内容は以下の通りです。
「ゼンマイを巻くと踊る人形＆動力メーター」と考えていただくとわかりやすいかもしれないです。
まず画面上に
(1)人
(2)メーター
(3)ゼンマイの3つの要素を入れたいです。

＜１＞デフォルトの状態は
・人は止まっている
・メーターはゼロ
・ゼンマイも止まっている

＜２＞マウスを奥に動かす（y軸座標をマイナス方向に移動させる）と
・人は変化無し
・メーターが溜まる
・ゼンマイが巻かれる（右回りに）

＜３＞マウスを手前に戻す（y軸座標をプラス方向に移動させる）と
・人が動いて踊り始める
・メーターが減っていく
・ゼンマイが戻る（左回り）

＊人の踊る動きは何フレームか毎に画像を変えていく感じで作ろうと思います。30フレームほど踊ったらまた踊りの最初のフレームにいって止まるまでループするといった感じです。
止まるときは最後の踊った体勢で止まるのではなく、繋ぎが悪くなっても＜１＞に戻るようにしたいです。

＊＜２＞のときマウスを動かした分だけメーターもゼンマイも動くようにしたい（両方ともに限界であるＭＡＸと、止まるポイントはつくる）

＊＜３＞のとき＜２＞で動力が溜まった分だけ全てが動くようにしたいので（MAXまで動力を溜める（マウスを奥に動かしていく）と人は長い時間踊る、ということです）、メーターとゼンマイが止まるときは人も止まるようにして、また＜１＞の初期状態に戻るようにしたい

以上です。要は同じような要素を持った２つのオブジェクトと、それとは微妙に違う動きをする１つのオブジェクトを１つのFlashに入れて、それをマウスのy軸で（ホイールで可能なら、ホイールでもOKです）動かしたいということです。言葉だけではわかりにくいかと思ったので一応画像をつけてみます。が、即席の絵なので残念な感じです・・・これでわかっていただけたら幸いです。こういう名のムービークリップを作ってそれにどの要素を収めるか、またどういう階層構造になるかなども時間がありましたらよろしくお願い致します。
長々と失礼しました。

回答No.1

BlurFiltan · ベストアンサー

「メーター」 と 「ゼンマイ」 は同期しています。
これを１つのムービークリップ内のタイムラインアニメーションで作成すれば良いのではないかと思います。

「人」は同期していません。
これは上の２つのムービークリップとは別のムービークリップ内のタイムラインアニメーションで作成すれば良いのではないかと思います。

「メーター」＆「ゼンマイ」 は一方向のみのアニメーションで良いです。
「メーター」は増えるだけのアニメーション，
「ゼンマイ」は右回りするだけのアニメーションです。

マウスの座標が上がったとき（yにマイナス方向に動いたとき），
「メーター」＆「ゼンマイ」 ムービークリップの再生を正の方向に進めます。
そして，
マウスの座標が下がったとき（yにプラス方向に動いたとき），
「メーター」＆「ゼンマイ」 ムービークリップの再生を逆方向に進めます。つまり逆再生させます。

私は下の図のような簡単なムービークリップ（MC）を２つ作成して実験してみました。
左のMC には 「meter_mc」 というインスタンス名を付けています。
右のMC には 「man_mc」 というインスタンス名を付けています。

その場合それら２つがあるフレームに次のように書けば，
ご質問で書かれていらっしゃるようなことができると思います。

--------------------------------------------
// メーターMC が逆再生するスピードを設定
spd = 2;

// メーターMC と 人MC を停止
meter_mc.stop();
man_mc.stop();

// マウス監視用オブジェクト mouseObj を作成
var mouseObj = new Object();

// マウスが動いたときの動作を定義
mouseObj.onMouseMove = function() {
//
// もし 変数 mouseY1 が未定義であれば
if (mouseY1 == undefined) {
// mouseY1に マウスの y 座標を代入
mouseY1 = _root._ymouse;
// もし 変数 mouseY1 が定義済であれば
} else {
// 変数 mouseY2 に mouseY1 の値を保管(旧マウス座標)
mouseY2 = mouseY1;
// そして mouseY1に マウスの y 座標を代入(新マウス座標)
mouseY1 = _root._ymouse;
//
// 新マウス座標が旧マウス座標より大きい場合
if (mouseY1>mouseY2) {
// メーターMC に １フレーム進む時間毎に随時実行する動作を定義
meter_mc.onEnterFrame = function() {
//
// もし メーターMC の再生フレームが spd より大きい場合
if (meter_mc._currentframe>spd) {
// 人MC を再生
man_mc.play();
// メーターMC をspdのフレーム数分逆生成
meter_mc.gotoAndStop(meter_mc._currentframe-spd);
// メーターMC の再生フレームが 1 であれば
} else {
// メーターMC をフレーム1で停止
meter_mc.gotoAndStop(1);
// 人MC をフレーム1で停止
man_mc.gotoAndStop(1);
}
};
//
// 新マウス座標が旧マウス座標より小さい場合
} else if (mouseY1<mouseY2) {
// メーターMC の １フレーム進む時間毎に随時実行する動作を削除
delete meter_mc.onEnterFrame;
// 人MC をフレーム1で停止
man_mc.gotoAndStop(1);
// 新旧マウス座標の差分だけ meter_mc のフレームを進める
meter_mc.gotoAndStop(meter_mc._currentframe+mouseY2-mouseY1);
}
}
};

// Mouseクラスのリスナーとして mouseObj を登録
Mouse.addListener(mouseObj);
--------------------------------------------
(ActionScript1.0　Flash MX 以上で使用可能)

ゼンマイですが，
これはムービークリップの中でくるくる回るアニメーションを作成するのではなくて，
グラフィックインスタンスの中で１回転するアニメーションを作成します。

そして，そのゼンマイが１回転するアニメが入ったグラフィックインスタンスを 「meter_mc」 の中に入れます。
そしてそのタイムラインを伸ばして，
ゼンマイグラフィックインスタンスを選択した状態で，
プロパティインスペクタから再生方法を 「ループ」 に指定すれば，
「meter_mc」 のタイムラインと同期して動くインスタンスが容易に作成できます。

「meter_mc」 の中に，ゼンマイが回転するムービークリップを入れた場合はこれができません。
ムービークリップではなくグラフィックインスタンスを使用する所がポイントです。
また，
「meter_mc」 の中のタイムラインを直接使うと，
ゼンマイを何回転も何回転もさせなければならなくなりますから，
かなり面倒ですし，位置を変えるのも一苦労になります。

お礼

遅くなってしまってすみません。
ご回答ありがとうございました！お陰さまで無事アニメーションを作ることができました!!（回答をいただくまでは、絶対に出来ないと思っていたので、感動してPCの前で「おぉーっ動いた!!!」とか叫んでました笑"）
本当に助かりました。説明も丁寧に書いてくださってわかりやすかったです。これからまたFlashを勉強する時にも参考にさせていただきます。ありがとうございました！