半導体 出払い領域 不純物領域

質問

半導体の温度特性による電気伝導について調べています。
シリコンを素材とした半導体の不純物領域と出払い領域の境目となる温度は、一般的に何度くらいになるのでしょうか？よろしくお願いします。

回答No.2

inara1

不純物領域と出払い領域の境目となる温度をExcelで計算する方法を紹介します。

【Excel VBA による Tb の計算法（Excel2002の場合）】
Excel のメニューバーの [ツール] → [マクロ] → [Visual Basic Editor] → [挿入] → [標準モジュール] で出た空白のコード画面に末尾のプログラムをコピー&ペーストで貼り付け、Excelシートに戻って、セルに　=Tb( m, E, N )　と書けば式(3)の解を計算できます。m はキャリアの比有効質量（0.36など）、E は不純物準位の深さ [eV単位]、N は不純物密度 [1/m^3単位] です。以下のプログラムでは計算精度を 10^(-6) K としています。

↓ここから
Const m0 As Double = 9.10938215E-31
Const kB As Double = 1.3806504E-23
Const hB As Double = 1.054571628E-34
Const q As Double = 1.602176487E-19
Const pi As Double = 3.14159265358979
Function Tb(m As Double, E As Double, N As Double)
If m <= 0 Or E <= 0 Or N <= 0 Then Tb = "VALUE!": Exit Function ' 入力パラメータが負ならエラー
Dim s0 As Double, s1 As Double, Tmin As Double, Tmax As Double, T As Double, eps As Double
Tmin = 1: Tmax = 1000 ' 解の範囲 [K]
s0 = N - Sqr(2 * N * (m * m0 * kB * Tmin / 2 / pi / hB ^ 2) ^ (3 / 2)) * Exp(-q * E / 2 / kB / Tmin)
s1 = N - Sqr(2 * N * (m * m0 * kB * Tmax / 2 / pi / hB ^ 2) ^ (3 / 2)) * Exp(-q * E / 2 / kB / Tmax)
If Sgn(s0 * s1) > 0 Then Tb = "VALUE!": Exit Function ' Tmin～Tmax の範囲で解がないならエラー
' ---------------------- ２分法による解探し ----------------------
eps = 1 / 10 ^ 6 ' 温度計算の精度 eps = 0.001 なら 0.001K の精度で探す
While Abs(Tmax - Tmin) > eps
T = (Tmax + Tmin) / 2
s0 = N - Sqr(2 * N * (m * m0 * kB * T / 2 / pi / hB ^ 2) ^ (3 / 2)) * Exp(-q * E / 2 / kB / T)
s1 = N - Sqr(2 * N * (m * m0 * kB * Tmax / 2 / pi / hB ^ 2) ^ (3 / 2)) * Exp(-q * E / 2 / kB / Tmax)
If Sgn(s0 * s1) < 0 Then Tmin = T Else Tmax = T
Wend
Tb = T
End Function
↑ここまで

【Excelのセキュリティーレベルの設定】
Excelのセキュリティーレベルが「高」になっていると、マクロを含むファイルを開いたときに、マクロを使っているという警告が出てマクロを使うことができません。その場合、警告ダイアログでOKをクリックした後、以下の手順でセキュリティーレベルを「中」に変更してください（Excel2002の場合）。
　　メニューバーの [ツール] → [オプション] → [セキュリティー]タブ → [マクロセキュリティー] → [中] を選択 → OK → OK
セキュリティーレベルを「中」に変更した後にファイルを開くと、マクロを使っているという注意が出ますが、「マクロを有効にする」を選択すればマクロを使うことができます。

お礼

ありがとうございます。
Excelのマクロは使用したことがないので挑戦してみようと思います。