エクセルのマクロでの満年齢および経過時間の表示

質問

はじめまして、初めて質問させていただきます。

私は、社会福祉施設に勤務しているのですが、
入所されている方のデータをユーザーフォームを使って
管理したいと考えています。
ユーザーフォーム自体は以前に作った事があるのですが
日付のデータは扱ったことがありませんでした。
自動で、入所時の年齢、現在の年齢、入所期間を表示させたいと
考えています。

エクセル上では
　 A 　　　　　　　　B 　　　　　 C 　　　　　　　　D 　　　　 E　　　　　　　　Ｆ
　名前　生年月日　　入所年月日　入所時年齢　現在の年齢　入所期間
1　Aさん　2007/02/21　2008/02/21　　50歳　　　51歳　　　3ヶ月
2　Bさん　2007/02/21　2008/02/21　　55歳　　　62歳　　　6ヶ月
3　Cさん　2007/02/21　2009/02/21　　60歳　　　73歳　　　7ヶ月
4　Dさん　2007/02/21　2010/02/21　　65歳　　　84歳　　　8ヶ月
5　Eさん　2007/02/21　2012/02/21　　70歳　　　90再　　　9ヶ月

というようなデータになっています。（数字は適当です）
マクロでは、datediffを使えば、計算させることはできるのですが
満年齢ではないと、入所した時の年齢などに不整合が生じてしまい
ます。（たとえば、月をまたぐと、一日し変わらないのに入所期間が一月分増えているなど。）
エクセルの関数ではdatedifを使えて楽なのですが…
（datedifを使って上の表を作ることはできます）
マクロで扱うやり方がわかりません。

いくつかのサイトで答えらしきものも見たのですが、
ユーザーフォームを作る以上、変数でも処理しなくてはいけないので
たとえば
Ｃells(gyou,1)
（gyouは行番号をあらわす変数）など
このように変数も使って扱うのでさらに混乱しております。

http://okwave.jp/qa2511599.html
なども参考にしては見たのですが

長々としたので質問の要旨は
1マクロで満年齢、満経過日数を扱う方法
2その際に、変数を使えるのかrenge("a1")などのセル指定以外の　
指定の仕方、cells(1.1)などでも扱えるのか
です。

マクロに関しては、初心者なので、なにとぞよろしく御願いします。

回答No.9

Wendy02 · ベストアンサー

こんにちは。

せっかく、zap35さんが書いていただいたので、私から少し書かせていただきたいのですが、A1 方式で書くと、別になりますが、R1C1 方式ですと、相対参照にする場合は、すべて同じ式になってしまいます。

前回のレイアウトから、コントロールツールの[テキストボックス]を一つ増やしました。

ワークシート
　　　　　名前　　　生年月日　　入所年月日　行数　
---------------------------------------------------
　　　TextBox1　 TextBox2　 TextBox3　 TextBox4 コマンドボタン　　[日付]　←名前-定義－登録[今日]
==================================================　←ウィンドウ枠の固定

TextBox4 に行数を入れる。
(コマンドボタンをクリックすると、最終データの次の行が出る）
　　　　　　　数式の保護はなされてはいません。
　　　　　　　今は、自動スクロールがされていません。

TextBox4 に、入力してある行を入力すると、その行に入力されているデータが出てきます。

-----------------------------------------------------

'***********************
'シートモジュール　(シートタブから、コードの表示をクリック）
'***********************
'-----------------------------------------------------

Private Sub CommandButton1_Click()

　　Dim gyou As Long
　　Dim Tx1 As String, Tx2 As String, Tx3 As String
　　'行数のチェック
　　If Val(TextBox4.Value) = 0 Then
　　　　MsgBox "行数が入っていません。", vbInformation
　　　　Exit Sub
　　Else
　　　　gyou = Val(TextBox4.Value)
　　End If

　　'名前
　　If TextBox1.Text = "" Then
　　　　MsgBox "お名前が入っておりません。", vbInformation
　　　　Exit Sub
　　Else
　　　　Tx1 = TextBox1.Text
　　End If

　　'生年月日
　　If Not IsDate(TextBox2.Value) Or Year(DateValue(TextBox2.Value)) < 1900 Then
　　　　MsgBox "生年月日の日付の入れ方が違います。 " & TextBox2.Text, vbInformation
　　　　Exit Sub
　　Else
　　　　Tx2 = CDate(TextBox2.Text)
　　End If

　　'入所年月日
　　If Not IsDate(TextBox3.Value) Or Year(DateValue(TextBox2.Value)) < 1900 Then
　　　　MsgBox "入所年月日の日付の入れ方が違います。" & TextBox2.Text, vbInformation
　　　　Exit Sub
　　Else
　　　　Tx3 = CDate(TextBox3.Text)
　　End If

　　'本日に対する日付のチェック
　　If Not (DateValue(Tx3) > DateValue(Tx2) And _
　　　　Date > DateValue(Tx3) And _
　　　　Date > DateValue(Tx2)) Then
　　　　MsgBox "日付の入力をもう一度調べてください。本日より先の日付は入れられません。", vbInformation
　　　　Exit Sub
　　End If
　　'入力
　　Cells(gyou, 1).Value = Tx1

　　Cells(gyou, 2).NumberFormatLocal = "yy/mm/dd"　'日付書式
　　Cells(gyou, 2).Value = Tx2

　　Cells(gyou, 3).NumberFormatLocal = "yy/mm/dd"　'日付書式
　　Cells(gyou, 3).Value = Tx3

　　Cells(gyou, 4).FormulaLocal = "=DATEDIF(RC[-2],RC[-1]-1,""y"")&""歳"""
　　Cells(gyou, 5).FormulaLocal = "=DATEDIF(RC[-3],今日-1,""y"")&""歳"""
　　Cells(gyou, 6).FormulaLocal = "=DATEDIF(RC[-3],今日,""m"")&""ヶ月"""

'データの最後の次の行
　　TextBox4.Value = Cells(65536, 1).End(xlUp).Offset(1).Row

End Sub

Private Sub TextBox1_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
'名前
　If KeyCode.Value = 9 Or KeyCode.Value = 13 Then
　　TextBox2.Activate
　End If
End Sub
Private Sub TextBox2_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
'生年月日
　If KeyCode.Value = 9 Or KeyCode.Value = 13 Then
　　TextBox3.Activate
　End If
End Sub
Private Sub TextBox3_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
'入所年月日
If KeyCode.Value = 9 Or KeyCode.Value = 13 Then
　　TextBox1.Activate
　End If
End Sub

Private Sub TextBox4_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
　　'行数の入力
　　Dim i As Integer
　　Dim gyou As Long
　　gyou = Val(TextBox4.Value) '行をずらす場合は、数字を足します
　　If gyou > 0 Then
　　　　If KeyCode = 13 Then
　　　　　　If IsDate(Cells(gyou, 2).Value) Then
　　　　　　　　For i = 1 To 3
　　　　　　　　　　Me.OLEObjects("TextBox" & i).Object.Value = Cells(gyou, i).Text
　　　　　　　　Next i
　　　　　　Else
　　　　　　　　'2列目が文字列の場合は、終了(タイトルの場合）

　　　　　　　　If VarType(Cells(gyou, 2)) = vbString Then Exit Sub
　　　　　　　　For i = 1 To 3
　　　　　　　　　　Me.OLEObjects("TextBox" & i).Object.Value = ""
　　　　　　　　Next i
　　　　　　　　TextBox1.Activate
　　　　　　End If
　　　　End If
　　End If
End Sub

お礼

本当に何度もありがとうございます。

全て試したわけではないですが、なんかうまくいきそうな予感がします。
やはり、値そのものより式を入れるという発送の転換が
大切でした。

いろいろな本を読んでも、それぞれ書いてあることが違って
迷っていたのですが、皆さんのおかげで何とかなりそうです。
これからも他にこの欄を参考にされる方もいると思うので、ユーザーフォームや日付などのことについて触れられていた、私の持っている本を書いておきます。
『すっきりわかったエクセルＶＢＡ』
→ユーザーフォームについては書いてあり、
　満年齢の表示は触れられていません。回答していただいた
　中にあった、エラーの処理については触れられています。
『かんたんプログラミングＥＸＣＥＬＢＶＡ』
→基礎的な内容らしく、フォームには触れられていません。
『ＥＸＣＥＬＶＢＡスーパーマスター』
→満年齢の表示にdateddiffを使っていますが他に操作を
　している様子があります。該当部分以外の内容もほとんど
　理解できませんでした。全体的に敷居が高いようです。
『やさしく学ぶエクセルＶＢＡ』
→満年齢の表示にマクロのdateddiffは使うなと書いてありました。
『日経ＰＣエクセルマクロ活用バイブル』
→満年齢については触れられていない。
です。

本当の所、私が習作で作ったコードとかも貼っていきたいのですが
業界は結構狭いので私の身元が割れてしまうこともあるので、
それは、ご容赦願います。これからは自分で努力しますが
もし、他にも質問が出た場合には
（実は他に列が40以上もあったりします…）
いつかご協力を御願いいたします。

皆さん本当にありがとうございました。