エクセルのマクロでの満年齢および経過時間の表示

質問

はじめまして、初めて質問させていただきます。

私は、社会福祉施設に勤務しているのですが、
入所されている方のデータをユーザーフォームを使って
管理したいと考えています。
ユーザーフォーム自体は以前に作った事があるのですが
日付のデータは扱ったことがありませんでした。
自動で、入所時の年齢、現在の年齢、入所期間を表示させたいと
考えています。

エクセル上では
　 A 　　　　　　　　B 　　　　　 C 　　　　　　　　D 　　　　 E　　　　　　　　Ｆ
　名前　生年月日　　入所年月日　入所時年齢　現在の年齢　入所期間
1　Aさん　2007/02/21　2008/02/21　　50歳　　　51歳　　　3ヶ月
2　Bさん　2007/02/21　2008/02/21　　55歳　　　62歳　　　6ヶ月
3　Cさん　2007/02/21　2009/02/21　　60歳　　　73歳　　　7ヶ月
4　Dさん　2007/02/21　2010/02/21　　65歳　　　84歳　　　8ヶ月
5　Eさん　2007/02/21　2012/02/21　　70歳　　　90再　　　9ヶ月

というようなデータになっています。（数字は適当です）
マクロでは、datediffを使えば、計算させることはできるのですが
満年齢ではないと、入所した時の年齢などに不整合が生じてしまい
ます。（たとえば、月をまたぐと、一日し変わらないのに入所期間が一月分増えているなど。）
エクセルの関数ではdatedifを使えて楽なのですが…
（datedifを使って上の表を作ることはできます）
マクロで扱うやり方がわかりません。

いくつかのサイトで答えらしきものも見たのですが、
ユーザーフォームを作る以上、変数でも処理しなくてはいけないので
たとえば
Ｃells(gyou,1)
（gyouは行番号をあらわす変数）など
このように変数も使って扱うのでさらに混乱しております。

http://okwave.jp/qa2511599.html
なども参考にしては見たのですが

長々としたので質問の要旨は
1マクロで満年齢、満経過日数を扱う方法
2その際に、変数を使えるのかrenge("a1")などのセル指定以外の　
指定の仕方、cells(1.1)などでも扱えるのか
です。

マクロに関しては、初心者なので、なにとぞよろしく御願いします。

回答No.4

rooksan

1.マクロで満年齢を扱うには以下のような感じで

(1)subプロシジャーを定義します
(2)その中で満年齢と入所期間を計算するfunctionプロシジャーを定義します
　満年齢 プロシジャー
誕生日と計算対象の日時が引数。満年齢が返ります
　入所期間プロシージャー
　　　入所日時と計算対象の日時が引数。満の月数が返ります

　※ともにdatediff関数を利用しています

Sub check()
Set s = Sheet1.Cells(1, 1).CurrentRegion
Dim 現在の日時
現在の日時 = Now()

For i = 2 To s.Rows.Count
s.Cells(i, 4) = 満年齢(s.Cells(i, 2), s.Cells(i, 3))
s.Cells(i, 5) = 満年齢(s.Cells(i, 2), 現在の日時)
s.Cells(i, 6) = 入所期間(s.Cells(i, 3), 現在の日時)
Next i
End Sub

Function 満年齢(誕生日, 日時)
満年齢 = DateDiff("yyyy", 誕生日, 日時)

If (Month(日時) < Month(誕生日) Or (Month(日時) = Month(誕生日) And Day(日時) < Day(誕生日))) Then
満年齢 = 満年齢 - 1
End If
End Function

Function 入所期間(入所日, 日時)
入所期間 = DateDiff("m", 入所日, 日時)
If Day(日時) < Day(入所日) Then
入所期間 = 入所期間 - 1
End If

End Function

満年齢と入所期間は標準モジュールに定義すれば、ユーザー定義関数と
して扱えるので、ワークシートの計算式として使えます
　たとえば セルに =満年齢(A2,NOW()) に入力する

2その際に、変数を使えるのかrenge("a1")などのセル指定以外の　
指定の仕方、cells(1.1)などでも扱えるのか?
扱えます

Set s = Sheet1.Cells(1, 1).CurrentRegion
Sheet1.Cells(1,1)はSheet1のA1と同等です
　その次のCurrentRegionですが、A1で囲まれたデータがあるセルを
　sのRangeに設定するマクロ命令です。
　つまり A1:E5がsに設定されます
　そのRangeの２行目(1行目は表題ですので）から行数分(s.rows.count)
計算します

お礼

ひとつひとつに丁寧な回答ありがとうございます。
ユーザー定義関数のことについては、過去ログなどにも
触れられ、他のサイトでも触れられていたのですが
よくわからなかったのです。rooksanのとおりにやってみます。