エクセルのマクロでの満年齢および経過時間の表示

質問

はじめまして、初めて質問させていただきます。

私は、社会福祉施設に勤務しているのですが、
入所されている方のデータをユーザーフォームを使って
管理したいと考えています。
ユーザーフォーム自体は以前に作った事があるのですが
日付のデータは扱ったことがありませんでした。
自動で、入所時の年齢、現在の年齢、入所期間を表示させたいと
考えています。

エクセル上では
　 A 　　　　　　　　B 　　　　　 C 　　　　　　　　D 　　　　 E　　　　　　　　Ｆ
　名前　生年月日　　入所年月日　入所時年齢　現在の年齢　入所期間
1　Aさん　2007/02/21　2008/02/21　　50歳　　　51歳　　　3ヶ月
2　Bさん　2007/02/21　2008/02/21　　55歳　　　62歳　　　6ヶ月
3　Cさん　2007/02/21　2009/02/21　　60歳　　　73歳　　　7ヶ月
4　Dさん　2007/02/21　2010/02/21　　65歳　　　84歳　　　8ヶ月
5　Eさん　2007/02/21　2012/02/21　　70歳　　　90再　　　9ヶ月

というようなデータになっています。（数字は適当です）
マクロでは、datediffを使えば、計算させることはできるのですが
満年齢ではないと、入所した時の年齢などに不整合が生じてしまい
ます。（たとえば、月をまたぐと、一日し変わらないのに入所期間が一月分増えているなど。）
エクセルの関数ではdatedifを使えて楽なのですが…
（datedifを使って上の表を作ることはできます）
マクロで扱うやり方がわかりません。

いくつかのサイトで答えらしきものも見たのですが、
ユーザーフォームを作る以上、変数でも処理しなくてはいけないので
たとえば
Ｃells(gyou,1)
（gyouは行番号をあらわす変数）など
このように変数も使って扱うのでさらに混乱しております。

http://okwave.jp/qa2511599.html
なども参考にしては見たのですが

長々としたので質問の要旨は
1マクロで満年齢、満経過日数を扱う方法
2その際に、変数を使えるのかrenge("a1")などのセル指定以外の　
指定の仕方、cells(1.1)などでも扱えるのか
です。

マクロに関しては、初心者なので、なにとぞよろしく御願いします。

回答No.3

Wendy02

こんにちは。

全体的な組み立て方が、分かりませんが、UserForm の　テキストボックス を三つを入力すると、

----------------------

名前　　　「TextBox1　　　　　　」
生年月日　「TextBox2　　　　　　」
入所年月日　「TextBox3　　　　　　」
CommandButton1
---------------------
セルには、
名前、生年月日、入所年月日、入所年齢、現在の年齢、入所期間

の5つが入れられるようにしたいというわけですね。

しかし、問題は、
>Ｃells(gyou,1)
>（gyouは行番号をあらわす変数）など

このgyou　をどうするか、という具体的な案が出されていません。

以下は、データの最後の行にしてありますが、「現在の年齢」「入所期間」は、「今日」に対する差ですから、実際、マクロで入れてしまうというのには、少し、無理があるのかなって思います。

私が、ご質問者さんの同じ立場なら、マクロにはしないで、#2さんのようなスタイルにします。リストされたデータがあれば、圧倒的に、ワークシートスタイルのほうが入力が早いです。私は、現役の時は、数千件のデータを、延べ6時間ぐらいで入力していましたから。マクロは使っても、数式を入れる程度です。それは、データ量にもよります。

'UserForm モジュール
---------------------------

Private Sub CommandButton1_Click()
Dim myDate1 As Variant
Dim myDate2 As Variant
Dim o1 As Long
Dim o2 As Long
Dim o3 As Long
Dim i As Long

　　myDate1 = "": myDate2 = ""
　　o1 = 0: o2 = 0: o3 = 0

　　If TextBox2.Value <> "" And TextBox3.Value <> "" Then
　　　　If IsDate(TextBox2.Value) And IsDate(TextBox3.Value) Then
　　　　　　myDate1 = CDate(TextBox2.Value)　'生年月日
　　　　　　myDate2 = CDate(TextBox3.Value)　'入所年月日

　　　　　　o1 = mDATEDIF(myDate1, myDate2) '入所時の年齢
　　　　　　o2 = mDATEDIF(myDate1, Date)　'現在の年齢
　　　　　　o3 = mDATEDIF(myDate2, Date, "m") '入所期間

　　　　　　With ActiveSheet
　　　　　　'行数の決定(データの最後の次）
　　　　　　i = .Range("A65536").End(xlUp).Offset(1).Row
　　　　　　If MsgBox(TextBox1.Value & "さん" & vbCrLf & _
　　　　　　　　　 CDate(myDate1) & vbCrLf & _
　　　　　　　　　 CDate(myDate2) & vbCrLf & _
　　　　　　　　　 o1 & "歳" & vbCrLf & _
　　　　　　　　　 o2 & "歳" & vbCrLf & _
　　　　　　　　　 o3 & "ヶ月" & vbCrLf & _
　　　　　　　　　 i & "行目に書き込みますが、これでよろしいですか？", vbOKCancel) = vbCancel Then
　　　　　　　　　Exit Sub
　　　　　　 End If

　　　　　　.Cells(i, 1).Value = TextBox1.Value & "さん"
　　　　　　.Cells(i, 2).Value = myDate1
　　　　　　.Cells(i, 3).Value = myDate2
　　　　　　.Cells(i, 4).Value = o1 & "歳"
　　　　　　.Cells(i, 5).Value = o2 & "歳"
　　　　　　.Cells(i, 6).Value = o3 & "ヶ月"
　　　　　End With
　　　　End If
　　End If

End Sub

Function mDATEDIF(日付1 As Variant, 日付2 As Variant, Optional typ As String)
Dim Fdate As Long
Dim Ldate As Long
Dim i As Integer
　If typ = "" Then
　　typ = """y"""
　　i = 1
　Else
　　typ = """" & typ & """"
　　i = 0
　End If
　Fdate = CLng(日付1)
　Ldate = CLng(日付2) - i　'満年齢を出す場合
mDATEDIF = Evaluate("DATEDIF(" & Fdate & "," & Ldate & "," & typ & ")")
End Function

'------------------------------
たぶん、もし、こういうスタイルで、不満を感じるとしたら、やはり、行数の決め方にあるとは思います。別途、TextBox に行数を入れるようなスタイルがよいのかもしれません。

お礼

ありがとうございます。

実際のところ、私も、マクロは使いたくないのです。
実際に、上記のデータ以外にも、入所されている方のデータは
たくさんあり、入所者のデータベースは横に長いデータベース
になります。実際には、それの簡便に行う関数は全て作ってあり
自分で操作をする分には何の支障も無いのですが、私以外の
人が使えないというデメリットがあります、誰でもデータの
入力と、変更を行えるものを作る必要があったのです。
私の職場では、エクセルの罫線を引くのもままならない人がいるので・・・

gyouをどうするのかが不明確というのは、指摘いただいて、気がつき増した。実際には、
私は『すっきりわかったエクセルＶＢＡマクロ作成のつぼ』などの
本に準拠して作ったのですが、
private sub commanndbutton_click()
gyou=cells(1.1)'行の番号が表示されているセル
gyou=gyou+1
とし、ボタンを押すたびに、表示される行が変わっていくように作っていました。
ご指摘に答えられたかどうかも自信がありませんが、これからも
学習していきます。