マクロを使って抽出する

質問

マクロを使った抽出について教えてください。

Ａ列　　Ｂ列　　Ｃ列　　Ｄ列
番号　　区分　　氏名　　年齢

　＊区分はＡ～Ｐが入ります。
　＊リスト範囲：Ａ１：Ｄ２００

セル[Ｆ１]に区分（Ａ～Ｐ）を入力して実行すると３５歳以上を抽出する。
オートフィルタの設定を使わずマクロで実行したいのですが、どのようなマクロを書けばよいのかわかりません。

マクロ初心者で申し訳ありませんが、よろしくご教授ください。

回答No.4

imogasi

マクロも
（１）VBAのメソッドプロパティをどれを使ったらよいかの勉強
（２）処理ロジックの勉強
があって、（２）は時間がかかる。解説者やWEB情報でも取り立てて区分しては書いてなくて、場を積むよりほか無い。
本件は基本的な「検索」の問題です
（１）全データ行を総なめ比較・判別して該当を抜き出す
　　判別は、区分＝P　AND　年齢＞＝３５
　　全データのための最下行は
　　d = Range("A65536").End(xlUp).Row
　　　かセルの初出空白行で捉えられる。
（２）データをコピーし、「区分」列でソートし、区分＝Pの行から
　　pの行全てで年齢＞＝３５を判別し、該当するものを探す
　　　最初行はMatch関数やFindメソッドで出来る。
（３）Find,Findメソッドで順次、区分＝Pを探し、年齢＞＝３５
　以外は捨てる。
（３）はVBA初心者には難しい。
（１）（２）は１０００行ぐらいなら樹幹的に大丈夫でしょう
コードは既回答も有るので省略。
練習にやってみてはどうかな。

回答No.3

mitarashi

on memoryのrecordset操作にチャレンジしてみました。興味を持たれたら、参考URLで勉強してください。XL2007で動くかどうかは疑問です。
Sub test()
Dim i As Long
Dim targetRange As Range
Dim targetRow As Range
Dim rs As Object

Set rs = CreateObject("ADODB.Recordset")
With rs
.Fields.Append "番号", 8, 20 'adBSTR
.Fields.Append "区分", 8, 50 'adBSTR
.Fields.Append "氏名", 8, 150 'adBSTR
.Fields.Append "年齢", 3 'adInteger
.CursorType = 3 ' adOpenStatic
.LockType = 3 ' adLockOptimistic
.Open
End With
Set targetRange = ActiveSheet.Range("a1").CurrentRegion
Set targetRange = targetRange.Offset(1, 0).Resize(targetRange.Rows.Count - 1, targetRange.Columns.Count)
With rs
For Each targetRow In targetRange.Rows
.AddNew
For i = 1 To targetRow.Columns.Count
.Fields(i - 1).Value = targetRow.Cells(i).Value
Next i
Next
End With
rs.Filter = "(区分='" & ActiveSheet.Range("f1").Value & "') And (年齢>=35)"
ActiveSheet.Range("f2").CopyFromRecordset rs
rs.Filter = 0 'adFilterNone
Set rs = Nothing
End Sub

参考URL：

http://home.att.ne.jp/zeta/gen/excel/c04p14.htm

回答No.2

tinu 2000（@tinu2000）

区分が何なのか分かりませんが、例えば地区だとすると、
Ｐ地区で３５歳以上の顧客リストを表示したい。
そんなところかな？？？

そんな訳で、
Ｆ１に抽出地区、Ｇ１に年齢を入れて、
Ｈ１をクリックすると抽出を開始。
Ｉ１をクリックすると全件表示（元に戻す）
の条件で作って見ました。
２００件だったらこんなもんでどうかな？
これが２０，０００件だったらスピードを考慮しないといけないと思う。

リストがあるシートに貼り付けて下さい。

Option Explicit
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
　Dim I As Integer
　If Target.Address = "$H$1" Then
　　　Rows("2:200").EntireRow.Hidden = False
　　　For I = 2 To 200
　　　　　If Range("F1") <> Range("B" & I) Or _
　　　　　　　Range("G1") > Range("D" & I) Then
　　　　　　　Rows(I).EntireRow.Hidden = True
　　　　　End If
　　　Next I
　End If

　If Target.Address = "$I$1" Then
　　　Rows("2:200").EntireRow.Hidden = False
　End If
End Sub

回答No.1

noname#77845

補足してください。

「セル[Ｆ１]に区分（Ａ～Ｐ）を入力して実行すると３５歳以上を抽出する。」
意味不明です。
区分に何を入力しても必ず35歳以上のデータを抽出するの？
それとも、F1と同じ区分の中で35歳以上を抽出するの？

因みに、「新しいマクロの記録」でオートフィルタを使用すれば、どういうマクロか判ると思いますよ。
戻すマクロも作った方がいいかも…。