Ｅｘｃｅｌ VBA セルの指定の方法

質問

ＶＢＡの初心者です。処理1　のサブルーチンを使わずに直接記述すれば、エラーはでませんが、以下のように記述すればエラーが出てしまいます。宜しくお願いします。
Sub Macro10()
i = 1
Do Until Cells(i, 1) = ""
処理1
i = i + 1
Loop
End Sub

Sub 処理1()
Cells(i, 2).Select　　←　ここでエラーになります。　　　　　　　
ActiveCell.FormulaR1C1 = "◎"
End Sub

回答No.2

noname#140971 · ベストアンサー

＞関数は、その中身に関して、何も心配しないで使えるようにある処理をブラックボックスの中につめ込むのに便利な方法である。
＞われわれは関数定義の中のカッコ内にリストされた変数を一般にパラメータと呼び、関数呼び出しに使われる値を引数(argument)という。
＞同じ区別を行うのに、仮引数および実引数ということばが使われることもある。

Sub Macro10()
　　Dim i As Long

　　i = 1
　　Do Until Cells(i, 1) = ""
　　　　処理1 i
　　　　i = i + 1
　　Loop
End Sub

Sub 処理1(ByVal i As Long)
　　Cells(i, 2).Select
　　ActiveCell.FormulaR1C1 = "◎"
End Sub

ところで、引数では、call by reference (参照による呼び出し)、call by value(値による参照）という２つのタイプを指定できます。
上では、call by value　であることを指示しています。
元の引数にアクセスできる call by reference　を指示する必要はないからです。

Sub Macro10()
　　Dim i As Long

　　i = 1
　　Do Until Cells(i, 1) = ""
　　　　処理1 i
　　Loop
End Sub

Sub 処理1(ByRef i As Long)
　　Cells(i, 2).Select
　　ActiveCell.FormulaR1C1 = "◎"
　　i = i + 1
End Sub

もちろん、元の引数にアクセスして +1 すれば Macro10 では +1 する必要はありません。

まあ、普通は、前者のやり方をします。

この関数の基礎レクチャーで疑問も解消したでしょうか・・・。

お礼

丁寧な回答ありがとうございました。

回答No.1

merlionXX

処理1のサブルーチンに変数iが渡されてないからです。
以下のようにしてみてください。

Sub Macro10()
Dim i As Long
i = 1
Do Until Cells(i, 1) = ""
Call 処理1(i) '処理１にiを渡す
i = i + 1
Loop
End Sub

Sub 処理1(i) '←　Macro10からiを受け取る。
Cells(i, 2).FormulaR1C1 = "◎"
End Sub

お礼

早速の回答ありがとうございました。