並べ替え？抽出？

質問

A　　　B　　　　　　C　　　　D　　　　E　　　　F
1:CD　　社名　　　金額　　　　CD　　社名　　　金額
2:1010 ○○商事　321,987　1020 ××商事　654,321　
3:1020 ××商事　654,321　1080 □□商事　963,741　
4:1030 △△商事　663,591　2100 ★★商事　656,982　
5:1080 □□商事　963,741　3330 ◆◆商事　200,100　
6:2100 ★★商事　656,982　1010 ○○商事　321,987　
7:3330 ◆◆商事　200,100　4210 ※※商事　998,825

以上のようなデータがありA1～A7のコードに合わせて
Dのコードを同じセルに順番どおり並べ替えたい。
EやFの社名や金額も一緒に並べ替えたい。
Aには、1030が有るがDには、無いのでその部分は、
空白にし逆にDには、4210が有るがAには、無いので
Aのその部分は、空白にしたい。
別々で入力したExcelデータの比較をしたいと思って
おります。数件のデータならいいのですが数百件も
ある場合手間がありまして・・・

どうか宜しくお願い致します。

回答No.2

zap35 · ベストアンサー

＃０１です。ではマクロにしました
以下のマクロをALT＋F11でVBE画面を開き、左上のVBA Projectでシート名を右クリックし「挿入」→「標準モジュール」で表示される画面に貼り付けて下さい。マクロの実行はシートに戻り、ALT＋F8でマクロ一覧を開き、マクロ名「Macro2」を選択して「実行」ボタンです

Dim ws As Worksheet
Dim ptrA, ptrD, idx As Long
Dim wkA, wkD
Sub Macro2()
'シートコピー＆並び替え
　ActiveSheet.Copy After:=ActiveSheet
　Set ws = ActiveSheet
　idx = ws.Range("A65536").End(xlUp).Row
　Range(ws.Cells(1, "A"), ws.Cells(idx, "C")).Sort Key1:=Range("A2"), _
　　　Order1:=xlAscending, Header:=xlGuess
　idx = ws.Range("D65536").End(xlUp).Row
　Range(ws.Cells(1, "D"), ws.Cells(idx, "F")).Sort Key1:=Range("D2"), _
　　　Order1:=xlAscending, Header:=xlGuess
'編集シート追加
　Worksheets.Add After:=ActiveSheet
　ptrA = 2
　ptrD = 2
　idx = 2
　ActiveSheet.Range("A1:F1").Value = ws.Range("A1:F1").Value
　Do Until ws.Cells(ptrA, "A").Value = "" And _
　　　ws.Cells(ptrD, "D").Value = ""
　　wkA = ws.Cells(ptrA, "A").Value
　　wkD = ws.Cells(ptrD, "D").Value
　　If wkA = wkD Then
　　　Call Macro2A
　　　Call Macro2D
　　Else
　　　If wkD = "" Then
　　　　Call Macro2A
　　　Else
　　　　If wkA = "" Or wkA > wkD Then
　　　　　Call Macro2D
　　　　Else
　　　　　Call Macro2A
　　　　End If
　　　End If
　　End If
　　idx = idx + 1
　Loop
　Application.DisplayAlerts = False
　ws.Delete
　Application.DisplayAlerts = True
　Set ws = Nothing
End Sub
Sub Macro2A()
　ActiveSheet.Cells(idx, "A").Resize(1, 3).Value = _
　　ws.Cells(ptrA, "A").Resize(1, 3).Value
　ptrA = ptrA + 1
End Sub
Sub Macro2D()
　ActiveSheet.Cells(idx, "D").Resize(1, 3).Value = _
　　ws.Cells(ptrD, "D").Resize(1, 3).Value
　ptrD = ptrD + 1
End Sub

実行結果はこうなりました
CD　　社名　　　　金額　　CD　　社名　　　金額
1010　○○商事　321987　1010　○○商事　321987
1020　××商事　654321　1020　××商事　654321
1030　△△商事　663591
1080　□□商事　963741　1080　□□商事　963741
2100　★★商事　656982　2100　★★商事　656982
3330　◆◆商事　200100　3330　◆◆商事　200100
　　　　　　　　　　　　　　　4210　※※商事　998825
5210　◎◎商事　555000

お礼

無事に表示されるようになりました。
違うデータから引っ張ってきているので
照合するのに困っていました。

本当にありがとうございました。

回答No.1

zap35

マッチング処理ですね。
　A　　　B　　　　　　C　　　　D　　　　E　　　　F
1:CD　　社名　　　金額　　　　CD　　社名　　　金額
2:1010 ○○商事　321,987　1010 ○○商事　321,987　
3:1020 ××商事　654,321　1020 ××商事　654,321　
4:1030 △△商事　663,591　
5:1080 □□商事　963,741　1080 □□商事　963,741　
6:2100 ★★商事　656,982　2100 ★★商事　656,982　
7:3330 ◆◆商事　200,100　3330 ◆◆商事　200,100　
8:　　　　　　　　　　　　4210 ※※商事　998,825
のようにしたいということでしょうか、補足お願いします

１）Ａ列のコードは昇順に並んでいるように見えますが、昇順に並んでいない場合は昇順に並び替えして良いですか？
　（それにより実現方法が変わってきます）
２）「Ａ列になく、Ｄ列にあるデータ（4210）」は必ずＡ列の行より下に並ぶことになりますが、その解釈で正しいですか。
３）マッチングリストは別シートに作成しても良いですか？
４）マクロで実現してもよいですか（関数だと4210のようなデータは結構難しいかもしれません）

補足

１）昇順で結構です。
２）もしA列に5210のコードがある場合には、
7:3330 ◆◆商事　200,100　3330 ◆◆商事　200,100　
8:　　　　　　　　　　　　　　　　　4210 ※※商事　998,825
9:5210 ◎◎商事　255,385
のように出来れば、問題ございません。
３）シートは、別でも構いません。
４）マクロでも構いません。

宜しくお願い致します。