日付の自動表示がうまくできません。

質問

VBAを使って、EXCELで日付を自動表示するマクロを作ったのですが、うまく動作しません。
設定の条件は、（対象の行は６～３１行目で）
Ｄ列に入力があった場合、Ｇ列に日付を表示、
Ｍ列に入力があった場合、Ｎ列に日付と時間を表示
です。

Private Sub Worksheet_Change(ByVal Target As Range)
Dim r As Integer, c As Integer

'r 行番号
'C 列番号

r = Target.Row
c = Target.Column

If Target.Count > 1 Then Exit Sub

If c <> 13 Or r < 6 Or r > 31 Then End

If Cells(r, c) <> "" Then
If c = 13 Then Cells(r, c + 1) = Format(Now, "m/d hh:mm")
Else
Cells(r, c + 1) = ""

End If

If Target.Count > 1 Then Exit Sub

If c <> 4 Or r < 6 Or r > 31 Then End

If Cells(r, c) <> "" Then
If c = 4 Then Cells(r, c + 3) = Format(Now, "m/d hh:mm")
Else
Cells(r, c + 3) = ""

End If

End Sub

作っているうちに、どこがおかしいのかわからなくなってしまいました。
助けて頂ければと思います。

回答No.1

noname#22222 · ベストアンサー

こんな感じですかね。

(1) エラートラップ以外では　Exit Sub は使わない。
(2) 原則、End は使わない。

が、宜しいかと！

Private Sub Worksheet_Change(ByVal Target As Range)
　　Const D = 4
　　Const G = 7
　　Const M = 13
　　Const N = 14
　　Dim isNull As Boolean
　　Dim C　　　As Integer
　　Dim R　　　As Integer

　　R = Target.Row
　　C = Target.Column
　　'
　　' 6～31行の範囲外はノーアクション
　　' 4列、13列でなくればノーアクション
　　'
　　If (R >= 6 And R <= 31) And (C = D Or C = M) Then
　　　　'
　　　　' データが削除された場合は日付を消す
　　　　'
　　　　isNull = CBool(Len(Target.Value & "") = 0)
　　　　C = IIf(C = D, G, N)
　　　　Cells(R, C) = IIf(isNull, "", Format(Now, "m/d hh:mm"))
　　End If
End Sub