XMLを使わずに同様の事をしたいのですが…

質問

某掲示板に同様の質問をしたのですが、本当に困っておりどうにもならない状態です。どうぞ、御教授お願い致しますm(__)m

速習WEbテクニックFlashMX実例サンプル６０にある内容からです。
ムービーの再生が始まると同時に、外部のJPG画像ファイルのURLが書き込まれているXMLファイルをロードし、XMLのデータをもとにJPGファイルの数を割り出し、その分だけ読み込み用のムービークリップを複製、表示するというものです。

ソースは次の通りです。これをXMLファイルを使用せず、loadMovieを使用し同様の事をしたいと思っています。どなたかよろしくお願い致します。

myXML = new XML ();
myXML.ignoreWhite = true;
myXML.load ("photodata.xml");

v_titleArray = new Array ();
v_xOffset = myBase._x;

myXML.onLoad = function (loaded) {
if (loaded) {
v_rootNode = myXML.firstChild;
v_num = v_rootNode.childNodes.length;
v_currentPhoto = v_rootNode.firstChild;
v_currentNumber = 0;
for (i=0; i < v_num; i++) {
v_loadURL = v_currentPhoto.childNodes[1].firstChild;
v_titleArray.push (v_currentPhoto.childNodes[0].firstChild);
v_currentPhoto = v_currentPhoto.nextSibling;
f_makeAndLoad (i, v_loadURL);
}
} else {
trace ("error occured");
}
};

XMLファイルのソースは次の通りです。
- <photo>
- <picture>
<file>photo1.jpg</file>
</picture>
- <picture>
<file>photo2.jpg</file>
</picture>
- <picture>
<file>photo3.jpg</file>
</picture>
- <picture>
<file>photo4.jpg</file>
</picture>
- <picture>
<file>photo5.jpg</file>
</picture>
</photo>

回答No.3

DPE

＃１です。

MovieClipLoader を使う方がファイルの存否を早い段階で確認でき、効率もいいのでオススメです。MX 2004 から登場するクラスですから、MX 2004 で作成してください。
読み込むファイルは、image ＋通し番号＋.jpg という命名規則で管理していることが条件になります。この番号を変数で指定し、カウントアップしながら読み込みの命令を出していきます。
MovieClipLoader は１つのオブジェクトで複数の読み込みを管理できます。
例えば MovieClipLoader.loadClip で５件の読み込み命令を出したら、読み込みが始まった・終わった・エラーが出た時など、読み込みに関するイベントが５組、それぞれのムービークリップで発生します。
今回は、MovieClipLoader のイベントのうち、ロードが始まった時に発生する onLoadStart 、ロードが終わり初期化も済んで読み込んだものが利用可能になった時発生する onLoadInit 、エラーが起きた時に発生する onLoadError を利用します。

スクリプトの流れは、次のように考えます。
ファイル名を共通の名前＋通し番号で付けていますから、

　loadClip( "image" + cnt + ".jpg" );

このように、番号の部分に変数を使って読み込みの命令が出せます。変数ですので、+1 ずつカウントアップするといった算術演算も可能です。
ファイルオープンの状況を把握するために、変数（フラグといいます）を１つ用意します。仮に load_status という変数を用意するとして、値の意味を次のように決めます。

　0:待機（ファイルオープン待ち）　1:ファイルオープン成功　-1:ファイルオープン失敗

ムービークリップを複製し、とりあえず、読み込み命令を出します。
この読み込みで、onLoadStart イベントが発生するまで待機します。
onLoadStart イベントが発生した時、MovieClipLoader 側で load_status を１にして、ファイルのオープンに成功したことを知らせます。
タイムライン側では、フレーム間をループしながら load_status の値を監視します。１になった時はファイルがあったということなので、ファイルカウントを更新して次のファイルを探しに行きます。
これを繰り返していくと、image1 ～ image N の画像を読み込めることになりますが、いつかは画像ファイルが尽きて、指定のファイルが見当たらなくなります。その時はエラーになり、onLoadError イベントが発生します。
onLoadError イベントでは、ファイルが見付からないためにエラーになったのか（ URLNotFound ）、途中で何らかの理由で失敗してエラーになったのか（ LoadNeverCompleted ）を区別することができます。このうち、URLNotFound でエラーイベントが起きた時には load_status を -1 にし、ファイル探しが終了したことを知らせます。

ところで、１つ１つの読み込みは onLoadInit イベントが発生するので問題ないのですが、全部のムービークリップでの読み込みが終わったかどうかは、どのようにして検出できるでしょうか？
簡単なのは、ファイルの総数とロードが終了した件数を照合することです。
変数を１つ用意（仮に loaded_files とします）し、onLoadInit イベントが発生するたびに、この変数をカウントアップします。
回線のトラブルなどで途中でロードが失敗した場合は、とりあえず読み込み終了ということでカウントに入れておきます。
ファイルの総数は、読み込みの命令を出す時に利用した変数に保存されています。この数と loaded_files の数を照合し、同じになるまで待つ、といった流れになります。

整理してみますと、次のような構成になります。

　フレーム１：初期設定
　フレーム２：ムービークリップを複製し、画像の読み込み命令を出す
　フレーム３：待機（ファイルの存否確認待ち）
　フレーム４：ファイルオープン成功時は次のファイルを探しに行き、失敗時は先に進む
　フレーム５：待機（全読み込み完了待ち）
　フレーム６：全読み込の終了判定
　フレーム７：タイムラインはここで止める

MovieClipLoader は、イベント発生時の処理を予め定義しておくと、イベントが起きたムービークリップ全てに同じ処理をしてくれます。
また、どのムービークリップでイベントが起きたかも判別できますから、例えば、ダウンロードが途中で失敗した場合は読み込み直すといったことも可能です。
（ただし、ファイルを探すループに読み直しの処理を組み込むとファイルカウントがズレてしまい、不具合の原因になりかねないので、読み直しは別の工夫が必要です）

画像の読み込みには、その受け皿となるムービークリップが必要です。今回は画像の数が不定のため、必要な数だけ予め配置しておくことができません。代わりに、ムービークリップ（ここでは仮に、cell_org という名前にします）を１つだけ置いておき、これを複製しながらそこに読み込んでいくことにします。
なお、コピー元のオリジナルに設定したオブジェクトアクションは、コピーしたムービークリップにも継承されます。例えば、全部の読み込みが終わるまで非表示にしたい場合は、オリジナルに onClipEvent(load)で _visible プロパティを false にするスクリプトを書いておくと、コピーも最初は非表示になります。
以下のスクリプトでは、コピーされたムービークリップは cell ＋番号というインスタンス名が付きます。普通のムービークリップ同様に、cell1._x = ・・・などとして利用できます。

スクリプトは、大体次のようになります。
（↓このスクリプトをコピーして使う場合は、各行頭の全角のスペースを、全て半角のスペースかタブに置き換えてください。このまま使うとシンタックスエラーになります）

●フレーム１（初期設定）

　//ファイル数・セル番号を保持
　cnt = 1;
　//読み込みが完了したファイルの数
　loaded_files = 0;
　//ファイル存否確認の進行状況を管理
　//0:待機　1:ファイルオープン成功　-1：ファイルオープン失敗
　load_status = 0;

　//ロードに必要なオブジェクトの生成と登録
　load_obj = new MovieClipLoader();
　event_obj = new Object();
　load_obj.addListener( event_obj );

　/*ファイルのオープンに成功した時の処理*/
　event_obj.onLoadStart = function()
　{
　　//成功を知らせる
　　load_status = 1;
　};

　/*読み込み完了時の処理*/
　event_obj.onLoadInit = function( target_clip:MovieClip )
　{
　　//読み込みが完了したファイル数を更新
　　loaded_files++;
　};

　/*エラー発生時の処理*/
　event_obj.onLoadError = function ( target_clip:MovieClip , error_code:String )
　{
　　switch( error_code )
　　{
　　　case 'URLNotFound':
　　　　//ファイルが見付からなかった場合：
　　　　//読み込み用に作ったセルを削除する
　　　　target_clip.removeMovieClip();
　　　　//読み込むファイルがないと見なし、終了を知らせる
　　　　load_status = -1;
　　　　break;

　　　　case 'LoadNeverCompleted':
　　　　　//途中で失敗した場合：
　　　　　//読み込みが完了したファイル数を更新
　　　　　loaded_files++;
　　　　　break;

　　　　default:
　　　　　break;
　　}
　};

●フレーム２（画像の読み込み）

　//セルを複製して画像を読み込む
　cell_org.duplicateMovieClip( "cell" + cnt , cnt );
　load_obj.loadClip( "image" + cnt + ".jpg" , this[ "cell" + cnt ] );

●フレーム３
　フラグ監視用のダミーフレーム。スクリプトは設定しません。

●フレーム４（ファイルオープン判断）

　switch( load_status )
　{
　　case 0:
　　　//ファイルへのアクセス完了を待つ
　　　gotoAndPlay( 3 );
　　　break;

　　case 1:
　　　//ファイルオープン成功の場合：
　　　//次のファイルを探しに行く
　　　cnt++;
　　　load_status = 0;
　　　gotoAndPlay( 2 );
　　　break;

　　case -1:
　　　//ファイルオープン失敗の場合：
　　　//全てのファイルを探したものと見なし、先に進む
　　　　gotoAndPlay( 5 );
　　　　break;

　　default:
　　　　break;
　}

●フレーム５
　全読み込み完了を待つためのダミーフレームで、スクリプトは設定しません。
　ロード完了率を表示したい時は、ここで算出するといいでしょう。

●フレーム６（全読み込みが終わるまで待つ）

　//全ての読み込みが完了した場合
　if( loaded_files == ( cnt - 1 ) )
　{
　　var i;

　　//各画像の位置を決め、表示する
　　for( i = 1 ; i <= ( cnt - 1 ) ; i++ )
　　{
　　　this[ "cell" + i ]._x = 100 * ( i - 1 );
　　　this[ "cell" + i ]._visible = true;
　　}
　}
　//読み込み中の場合は終了を待つ
　else
　{
　　gotoAndPlay( 5 );
　}

●フレーム７（普段はこのフレームを表示）

　stop();

MovieClipLoader の getProgress では、ロードの総バイト数やロード完了済みバイトを取得できます。この値から完了率を算出して、Now Loading ○％という表示も可能です。
（戻り値が２つありますので、戻り値の取得方法にご注意ください。汎用型である Object 型の変数を作って受け取ります）
また、画面に入りきらないほど画像がある場合は、マスクとスクロールバーを使って、スクロールできるようにする方法もあります。
MX には ScrollBar という UI コンポーネントがありましたが、MX 2004 では廃止されてしまいました。しかし、MX 2004 のアップデータ Ver.7.2 を導入すると、ScrollBar より使いやすくなった UIScrollBar というコンポーネントが使えるようになります。
スクロールバーのあるサムネイル画面の基本的な考え方・作り方は、http://okweb.jp/kotaeru.php3?q=974758 で紹介していますので、よろしければご参照ください。
スクリプトは MX の ScrollBar 対応のものです。ScrollBar から MX 2004 の UIScrollBar に移行する時の変更ポイントは、http://okweb.jp/kotaeru.php3?q=989128の＃１や＃３で紹介しております。
長文である上に、半ば質問者様との対話のようになっており、見辛くて恐縮ですが、こちらもご参考程度に。

長くなってすみませんでした。
不明な点がありましたら、補足してください。

補足

Script付きの御説明ありがとうございます。
ASについてまだ経験が浅い分、中々解釈できなかった分が多かったのですが、丁寧な解説していただいたおかげでだいぶ分かってきたような気が致します。
１フレームでの処理ではなく、いくつかのフレームをまたいで作成する方法については全くイメージできなかったため、大変参考になりました。

もう一つ、お聞きしたいことがあるのですが、私が最初、提示したScriptはXMLファイルを用いての物でした。
その応用として、例えばムービー上のテキストフィールドにURLやjpg画像枚数を入力することにより、ActionScriptによってXMLファイルを作成し、自動的にそれを読み込み同様の事をすることができるのでしょうか？
要求ばっかりで大変申し訳ないですが、DPE様、またここを呼んでくださった方、御教授の程お願い致します。

回答No.2

kacchann

for(i=0;i<5;i++){f_makeAndLoad (i,"photo"+(i+1)+".jpg");}

補足

せっかく教えていただいたスクリプトなのですが、どうも上手くいかないです。

それと大変申し訳ないのですが、f_makeAndLoadファンクションについての記述がなかったので補足させていただきます。申し訳ありませんでした。

function f_makeAndLoad (num, path) {
myBase.myLoad.duplicateMovieClip ("myLoad"+num, num+1);
v_name = eval("myBase.myLoad"+num);
v_name._x = 150 * num;
v_name._y = 0;
v_name.loadMovie (path);
myBase.myLoad._visible = false;
}

回答No.1

DPE

お使いの Flash は MX でしょうか？

ファイル名を、共通の名前（例えば photo や image など）＋通し番号で付けており、途中に欠番がないことを前提にすると、ファイルオープンエラーを利用してフォルダにあるだけ読み込むことは可能です。
Flash の外部ファイルの読み込みは、複数のムービークリップで並行して実行できるようになっています。
これを、１つの読み込みが終わるのを待って次の読み込みの指示を出していたのでは、ロードにかなり時間がかかってしまいます。
ファイルの存否をいかに早く確認し、複数の読み込み指令を出していくかがポイントとなるわけですが、この方法が、MovieClip.loadMovie を使うか、MX 2004 から使えるようになった MovieClipLoader を使うかどうかで、作業効率もスクリプトも変わってきます。

エラーを利用してファイルがあるだけ読み込み、スクロールバー付きのサムネイル画面を作るというテーマで、何回かスクリプトや作り方の例をご紹介してきました。
長文で恐縮ですが、よろしければ、考え方のご参考までに。

　・エラーが出るまでファイルを読むループ
　　http://okweb.jp/kotaeru.php3?q=961443

　　＃７で、エラーを利用した読み込みのスクリプトを紹介しています。
　　対象が画像の場合は、読み込みが成功したかどうかの判定に少々工夫が必要です。

（同じ質問者様の、スクロールバーに関する質問やループを利用した読み込みに関する質問が、スクロールバー付きのサムネイル画面を作るという一連の作品に関する質問になっています）

試作品をいろいろ作ってきましたので、お役に立てるようであれば、スクリプトをご紹介します。

補足

環境をお伝え忘れておりました。すいません。
次の通りです。
Windows2000　IE６　FlashMXです。
Flashは一旦MXを使っていますが、MX2004も使用可です。

早々の御教授、ありがとうございます！
FlashのASを始めて、まだ浅いので解釈に時間がかかります故、これから深く読んでいきたいと思っています。
それと、DPE様がおっしゃられていた試作品のスクリプトを紹介していただきたいです。
よろしくお願い致します。