excelで検索ボタン

質問

excelで検索用のボタンを作りたいのですがよくわからいのでご教授願えないでしょうか？
内容は
検索ボタンをクリックしたら検索場所がsheet、検索対象が値に設定された状態でCtrl+Fの検索ボックスを開きたいと思っています。
若しくは上記の条件で検索できる検索窓とボタンがあればそちらでも構いません。
苦手分野なのでなかなかうまくいかず質問させていただきました。宜しくお願いします。

回答No.5

real beatin（@realbeatin） · ベストアンサー

こんにちは。お邪魔します。

> 検索ボタンをクリックしたら検索場所がsheet、検索対象が値に設定された状態でCtrl+Fの検索ボックスを開きたいと思っています。
　【検索場所がsheet】
　【検索対象が値】
　【Ctrl+Fの検索ボックス】
実現するのは簡単そうに見えて、意外と解り難いですよね。
マクロの記録で得られるレベルのものではないですから安心してください。

> 若しくは上記の条件で検索できる検索窓とボタンがあればそちらでも構いません。
その方がいい場合もある、とは思うのですが、
これはこれで、仕様をより明確に確定しなければなりませんから、
どんな仕様にするのか、をご自身で決めるまでに、
色々手を動かして試す必要があるような、、、。

なので今回は【Ctrl+F】で表示される[検索と置換]ダイアログでお応えします。

【検索対象が値】という点については二通りの解釈を持っています。
　a　[検索と置換]ダイアログのオプションとしての[検索場所(シート|ブック)]
　　　　に、シート、を指定する
　b　a の状況に加えて
　　　　検索範囲をシート全体にする（拡げる）（複数セル範囲選択中の範囲に限定しない）
a　を意図したものかも知れませんが、とりあえず、b という解釈で書いています。
その必要がないようでしたらば、★でマークした行を削除してください。

【検索場所がsheet】【検索対象が値】
以外の検索オプション（※【詳細】は下記）については、
（直近の検索・置換の際に指定変更があってもなくても）
Excel起動時の初期設定になる（強制される）ように書いています。
他のオプションを別途指定変更したい場合は、
VBE画面に記入したコードの
　Find
の部分にカーソル（キャレット）を当て
F1キーでVBAヘルプを表示して、
[Findメソッド]の各名前付き引数に[指定できる定数]の中から、
お望みのオプションを選んで指定を書き換えてください。

お求めに十分でなかった場合は遠慮なく、補足欄にでも書いてみて下さい。

' ' ///

Private Sub CommandButton1_Click()

' ' [書式の検索]を（設定中であってもなくても）クリア
Application.FindFormat.Clear

' ' [検索場所]:シート
' ' [検索対象]:値
' ' これ以外のオプション（※【詳細】は下記）をすべてデフォルトに設定して
' ' バックグラウンド（VBAのメソッド）で、空（ダミー）の検索を実行
ActiveCell.Find _
What:=ActiveCell, _
LookIn:=xlValues, _
LookAt:=xlPart, _
SearchOrder:=xlByRows, _
MatchCase:=False, _
MatchByte:=False, _
SearchFormat:=False

' ' 複数セル範囲を選択中の場合は、
' ' 検索範囲を（限定せずに）シート全体にする為に アクティブセルを選択
If ActiveCell.MergeArea.Address <> Selection.Address Then ActiveCell.Select　'　★

' ' 以上の処理による設定 を 反映した形で、、、
' ' [検索と置換]ダイアログを表示
Application.CommandBars.FindControl(ID:=1849).Execute

End Sub

' ' //

' ※【詳細】
' ■ Find メソッドをダミー実行することで
' →　[検索場所(シート|ブック)]　＝（お望みの設定）シート
' を指定（強制）したことになります。
' ▼ 以下、名前付き引数 と [検索と置換]ダイアログ上のオプション との 対照　＝指定値
' What　　　　:　[検索する文字列]　＝（仮の表示として）アクティブセルの値
' SearchOrder :　[検索方向(行|列)]　＝（起動時の初期値）行
' LookIn　　　:　[検索対象(数式|値|コメント)]　＝（お望みの設定）値
' MatchCase　 :　[大文字と小文字を区別する(T|F)]　＝（起動時の初期値）False
' LookAt　　　:　[セル内容が完全に同一であるものを検索する(T|F)]　＝（起動時の初期値）False
' MatchByte　 :　[半角と全角を区別する(T|F)]　＝（起動時の初期値）False

' ◆ ボタンの種類と運用方法
' ▼ 挿入した[図形]などのシェープや[ボタン(フォームコントロール)] の場合
' 　上記プロシージャ記入先は標準モジュール
' 　上記プロシージャ宣言（先頭）行の Private を削除
' 　[図形]などのシェープや[ボタン] の[マクロの登録]にて
' 　　　上記プロシージャの名前を登録
' ▼ [コマンドボタン(ActiveXコントロール)] の場合
' 　上記プロシージャ記入先はコ[コマンドボタン]を配置したシートのシートモジュール
' 　上記プロシージャはそのまま記入
' 　[コマンドボタン]のオブジェクト名がCommandButton1以外の場合は
' 　　　上記プロシージャ宣言（先頭）行の CommandButton1 を書き換え

' ' ///

お礼

お返事遅れて申し訳ございません。
希望通りの動作ができました。改めて自分の未熟さを実感するばかりです。
今回は本当にありがとうございました。

回答No.4

imogasi

検索窓をだすだけなら
標準モジュールに
Sub kensaku()
Sub kensaku()
'Application.Dialogs(xlDialogFormulaFind).Show
Application.Dialogs(xlDialogFormulaFind).Show Arg1:="ぎもん検索語句", Arg2:=2, Arg3:=2
'Arg2　1=数式　2=値　3=コメント
'Arg3　 1=行 2=列
End Sub
を実行すればよい。
しかし質問に、（利用者は）どういうタイミングでこの検索窓を出すべきか、を書いてないから、完全な答えができない。
シートに図形の四角を１つ張り付けて、右クリックして出てくる、マクロの登録で上記の標準モジュールにある「kensaku」を指定する。
シートの四角をクリックすれば、検索窓が出てくる。
しかし検索結果をどうするか（複数セルに見つかる場合が在るが）は、何も質問に書いてない。VBAでも定番のコードがあるので、解説書には載っているが、初心者にはむつかしい箇所と思う。
むしろ検索操作をやってマクロの記録を取り、そのコードを勉強する方が、課題には役立つだろう。
ーー
ウィンドウズのGUIにあこがれて、やりたいと思っただけで、力不足ではないかな。
普通の検索操作を使えばよいはず。
現状の力で、他人に使ってもらう仕組みを作るのは無理だろう。

お礼

おっしゃる通りで自分の未熟さを改めて実感しています。
当方の勤務する会社は小規模でエクセル等扱える中では自分が一番というレベルで、上司等に操作設定をなかなか理解してもらえず仕方なく今回のような質問をさせていただいた次第です。
今後は自分のスキル向上に力を入れていきたいと思っておりますので機会がありましたらご助言いただけると助かります。
今回はありがとうございました。

回答No.3

f272

Sub my_find_replace()
Const find_replace = 1849
Application.FindFormat.Clear
Cells.Find What:=ActiveCell.Value
Application.CommandBars.FindControl(ID:=find_replace).Execute
End Sub
こんな感じです。

回答No.2

kkkkkm

ボタンのマクロに以下のコードを登録して
検索文字列をB1に検索するシートをA1に入力してボタンをクリックしたください。

Sub Example()

ActiveCell.Find What:=Range("B1").Value
Sheets(Range("A1").Value).Activate
Application.CommandBars.FindControl(ID:=1849).Execute

End Sub

回答No.1

shintaro-2

まずマクロを作成します。
そしてボタンを配置したら、そのボタンでマクロが動くように登録します。

マクロのつくり方がわからない場合は、
キーボードマクロで
一連の動作を記録して
記録したコードを読んでみてください。

補足

色々調べて何度か試しているのですが記録されていないような感じです。
マクロは今まで使ったことがないのでやり方が間違っているのかもしれませんが(-_-;)