今の自分の年齢を取得するｖｂａコードが知りたい

質問

今の自分の年齢を取得するｖｂａコードが知りたいのですが

Sub test1()
Dim dtm誕生日 As Date
dtm誕生日 = #7/1/1986#

MsgBox Format(Date - dtm誕生日, "yyyy/mm/dd")
MsgBox DateDiff("yyyy", dtm誕生日, Date)

End Sub
を作ってみたのですが
違うのが返りました。

DateDiff("yyyy", dtm誕生日, Date)
は、30が返ってしまいます。

今日の時点ではまだ29歳なのですが
そういう場合どうすればいいでしょうか？

「現在は29歳です」と返したいのですが、
どのようにすればいいでしょうか？

回答No.4

real beatin（@realbeatin） · ベストアンサー

こんにちは。

DateDiff()関数に関するＶＢＡのヘルプには、
> 12 月 31 日とその次の年の 1 月 1 日を比較すると、DateDiff 関数の年 ("yyyy") は、1 日後であっても、1 を返します。
とあります。
「"年"の"差"」は求められても、「経過年数（例えば年齢）を求める」ことは出来ません。

ＶＢＡでということなら、例えば、こんな感じのが簡単かな、と。
　　年月日をyyyymmddと連続した十進数として看做した文字列値を基準にして
　　（Variant型のキャストを経て）
　　数値として引き算をして、10000で割った商を求めます。
' ' ///
Sub ReW9110770c()
Dim dtBD As Date
Dim dtCD As Date
　　dtBD = "1986/7/1"
　　dtCD = Date()

　　MsgBox (Format(dtCD, "yyyymmdd") - Format(dtBD, "yyyymmdd")) \ 10000

End Sub
' ' ///

一応、「経過年数（例えば年齢）を求める」ということでしたら、
閏年ぐらいは動作確認・検証しておいた方が良いでしょうから、
　　dtBD = "2012/2/29"
　　dtCD = "2014/2/28"
と
　　dtBD = "2012/2/29"
　　dtCD = "2014/3/1"
のようなサンプルで試してみて下さい。

「年齢を求める簡単な関数」
というのが、ご質問でお求めの答、だと理解していますが、
ひとつの関数だけで簡単に求めることはできないでしょう。
こちらで提示するものは、関数２つと演算子の組合わせになっています。
いちいち書くのが面倒に感じるようでしたら、
ご自身で専用の関数（Function）を書いて、
アドインにでも保存しておくと良いでしょう。

余談に近い話ですが、今日的な意味付けとして、
「ＶＢＡだけを使用して」
「Date型で宣言した変数に日付値を格納する場合は」
日付リテラル（#7/1/1986#等）を使う必要は無いです。
むしろ、
　データ型を指定できない言語や
　Variant型で（暗黙にせよ明示したにせよ）宣言した変数に
　関数を用いることなく日付型の値を設定したい場合に
例外的に用いるのが日付リテラル、といった感じなのではないでしょうか。
　　dtBD = DateValue("1986/7/1")
のように関数を用いることが推奨されていますが、
「... でななければならない」という根拠は薄いと思っています。
Variant型の扱いや型のキャストを十分に理解していればいいことです。
「日付リテラルとか型宣言文字とか使うべきではない」という流派の方も
多くみられるようになってきました。
何故「使っちゃいけない」とまで言うのか、という理由についても、
根拠はあるらしいのですが、私にはよく解りません。
ただ、現存する旧いテキストでは、日付リテラルを奨めることが多いようですし、
今でも入門書で書かれていることもあるようですから、
「知っておいた方がいいこと」であることは間違いないです。
でも、もしも「日付リテラルを使うべし」と覚えてらっしゃる様でしたら、
それはそれで違うので、一応申し添えておきます。

以上です。

※ここで扱っている日付については、専ら日付値であって
　時刻値を無視した日付です。
　これは元質問の例題に副ってお応えしたものです。

お礼

回答ありがとうございました。

回答No.5

keithin

sub macro1()
　dim dx as date
　dx = #7/1/1986#

　msgbox evaluate("datedif(""" & dx & """,""" & date & """, ""y"")")
end sub
みたいな。

お礼

回答ありがとうございました。

回答No.3

imogasi

VBらしく、VBの関数DateDif(ｆが２つ）を使ってみた。
場合分けが２つになってしまうが。
家族などの誕生日でやってみて、正しいか、確認して使ってください。
Sub test01()
t = Date '操作したきょうの日付
't = #10/31/2016#　’テスト用
't = #10/30/2016#
't = #9/1/2016#
MsgBox t
'--誕生日
’実際は他のデータ項目か、Ｉｎｐｕｔｂｏｘ関数などで取り込むこと(下記注）
'bt = #10/15/1980#
bt = #1/11/1987#
MsgBox bt
'--以上テスト用日付
If t >= DateSerial(Year(t), Month(bt), Day(bt)) Then
n = DateDiff("yyyy", bt, t)
Else
n = DateDiff("yyyy", bt, t) - 1
End If
MsgBox n　'満年齢
End Sub
DateDiff関数は
＞年が異なる場合、１秒だけの差でも１年差と返す(月や日,時,分でも同様)
http://note.phyllo.net/?eid=1106128
なので上記のようにしてみた。
--
＞「インプットボックスに日付以外入力できないようにしたい」
http://park11.wakwak.com/~miko/Excel_Note/13-01_msgbox.htm

お礼

回答ありがとうございました。

回答No.2

山田 太郎（@f_a_007）

私が用いているGrtAge()は次のようです。

Public Function GetAge(ByVal dteBirthday As Date, ByVal dteToday As Date) As Integer
　　Dim intAge　　 As Integer
　　Dim lngValue_1 As Long
　　Dim lngValue_2 As Long

　　dteToday = DateAdd("d", 1, dteToday)
　　lngValue_1 = Format(dteToday, "yyyy") * 10000 + Format(dteToday, "mm") * 100 + Format(dteToday, "dd")
　　lngValue_2 = Format(dteBirthday, "yyyy") * 10000 + Format(dteBirthday, "mm") * 100 + Format(dteBirthday, "dd")
　　intAge = Fix((lngValue_1 - lngValue_2) / 10000)
　　GetAge = intAge
End Function

Public Function GetAge(ByVal dteBirthday As Date, ByVal dteToday As Date) As Integer
　　If Format(dteBirthday, "MMDD") >= Format(dteToday, "MMDD") Then
　　　　GetAge = DateDiff("YYYY", dteBirthday, dteToday) - 1
　　Else
　　　　GetAge = DateDiff("YYYY", dteBirthday, dteToday)
　　End If
End Function

それは、添付図のように29歳と計算します。なお、イミディエイトウインドウでは

? Format(#7/1/1986#, "yyyy/mm/dd")
1986/07/01

となりますので当然のことです。

【原因は】月日を比較していないことかと・・・・。

お礼

回答ありがとうございました。

回答No.1

kagakusuki

次の様なVBAにされると良いと思います。

Sub test()
Const dtm誕生日 = "1986/1/7"
MsgBox DateDiff("yyyy", dtm誕生日, Date) + (DateValue(Year(Date) & Mid(dtm誕生日, 5)) - Date > 0)
End Sub

>DateDiff("yyyy", dtm誕生日, Date)
>は、30が返ってしまいます。

> 今日の時点ではまだ29歳なのですが

　違います。
　誕生日として設定されている

7/1/1986

は1986年1月7日なのですから、1月13日現在においては30回目の誕生日は既に過ぎていますので、30が返るのが正しい事になります。

お礼

回答ありがとうございました。