エクセルVBA 自動設定のグラフ系列色のRGB

質問

VBA初級者です。
エクセルで自動設定されたグラフ系列色（点のみ、線なし）の
RGBを取得するにはどうしたらいいのでしょうか？
系列色を設定する方法は以下のようにすればいいようですが。。。

ActiveSheet.ChartObjects("グラフ 1").Activate
ActiveChart.SeriesCollection(1).Select

With Selection
.MarkerBackgroundColorIndex = 色番号 / xlAutomatic
.MarkerForegroundColorIndex = 色番号 / xlAutomatic
　　　または、
　　　 .MarkerBackgroundColor = RGB(?,?,?)
.MarkerForegroundColor = RGB(?,?,?)

End With

私がやりたいことは、上のような記述でxlAutomaticで自動的に設定された
ある系列の色を他の系列にも適用したいのです。もう少し具体的に言うと、
系列1，2、系列3，4、のように隣り合う系列を同色にしたいのです。
系列数が少なければ各組合せに対してRGBを設定すればいいのですが、
系列が大量になってきますと、自分でRGBを設定するのも大変で、
系列１，３，５・・・に関しては、xlAutomaticで自動設定して、その色を
系列２，４，６・・・に適用しようと思ったのですが、よくわかりませんでした。

ActiveChart.SeriesCollection(1).Select　
With Selection
.MarkerBackgroundColorIndex = xlAutomatic
Color = MarkerBackgroundColorIndex
End With

ActiveChart.SeriesCollection(2).Select　
With Selection
.MarkerBackgroundColorIndex = Color
End With

などとしてみましたがダメでした。恥ずかしながら基礎を
理解できていないので詳しく説明していただけると幸いです。
よろしくお願いいたします。

回答No.5

real beatin（@realbeatin） · ベストアンサー

＃３-４です。＃４お礼欄拝見しました。

> 系列１３からは濃淡を変えるなどして、色分けするにはどうしたらよいでしょうか？
濃淡といっても、例えば、
セルの書式等にも使うカラーパレットは同系色５段階になっていますが、
これをチャート上で見分けられるかどうか、というと、
私の仕事環境でも、会議室のプレゼン環境でも、
モニターやスクリーンに全画面チャートを表示した場合で、
同系色２～３段階程度が限界と思います。
思う、のであって、他の環境では違う、他の人は違う、
と言うかも知れないので、非常に相対的です。
これがいい、とか、私の判断は全く介在しない事務的な仕事でしたが、
とりあえず、濃淡織り交ぜて、こちらの環境では見分けられる
適当な配色を２０色で作ってみて、マクロを書き換えました。
あとは、マーカーのスタイル、マーカーのサイズ、等を工夫すれば、
と思います。
ブック固有の（既定の）配色パターンにある色は
そもそも濃淡を表現するのが難しい色として選ばれているように思います。
強いて言えば[マーカーの塗りつぶし][透過性]を使うてもありますが、
これで見分けが付くのは原色系でも２段階が限界に思います。
独自の配色にしたのは、そういう理由からです。
組合わせ方は無限にあるでしょうから、方針とか目標とか必要条件とか、
そういうことから絞って考えていった方が決め易いかも知れませんね。

あくまでも一例、です。

Sub Re8916999_RndColors()
Const S_ARRAY_HEX = "0000FF A03070 00FF00 0080FF FF0000 70A030 FF00FF 00FFFF FFFF00 000000" & _
　　　　　　　　　　" 8080FF 80FF80 FF8080 FFAAFF AAFFFF FFFFAA AAAAAA CCCCFF CCFFCC FFCCCC"
Dim oSeries As Series
Dim arrS() As String
Dim arrN() As Long
Dim nUbColor As Long
Dim i As Long

　　arrS() = Split(S_ARRAY_HEX)
　　nUbColor = UBound(arrS())
　　ReDim arrN(0 To nUbColor) As Long
　　For i = 0 To nUbColor
　　　　arrN(i) = CLng("&H" & arrS(i))
　　Next i

　　nUbColor = nUbColor + 1
　　i = 0
　　For Each oSeries In ActiveChart.SeriesCollection
　　　　oSeries.MarkerBackgroundColor = arrN((i \ 2) Mod nUbColor)
　　　　oSeries.MarkerForegroundColor = arrN((i \ 2) Mod nUbColor)
　　　　' ' oSeries.MarkerStyle = xlMarkerStyleSquare
　　　　i = i + 1
　　Next
End Sub

お礼

ご回答大変ありがとうございました。
あまり実用的に意味のない要望に対しても
ご丁寧にご説明いただき、感謝しております。
コードの書き方はもとより、配色の考え方に
ついても勉強になりました。

私は技術系で、データ数が数十になることも
珍しくなく、散布図で全て同色にして傾向だけを
示すか、グラフを複数にわけるか、それとも
自動配色にさせておいて一応データを探せるように
しておくか、悩むことが多いです。今回の質問は
シートに新しいデータを取り込んで、それと同時に
グラフに新データの中の二種類のパラメータを追加する
マクロを作っていたときに出てきた問題でした。
同じデータ中の二種類のパラメータは点の形状で区別し、
色は同じにしたかったのです。

データが増えてきますとご指摘のよう色の判別
が難しくなりますので、工夫が必要ですよね。　
色々とありがとうございました。

回答No.4

real beatin（@realbeatin）

＃３です。こちらからの追加補足です。

＃３のマクロ。
系列の数が１２を超えると当然ながらエラーになりますね。
ちょとうっかりしました。もっと注意するべきでした。
系列の数が多いからこそ、生じる課題ですものね。

以下２行分、＃３のコード、該当行と差し替えてください。
　　　　oSeries.MarkerBackgroundColor = arrTcsRgb((idx \ 2) Mod 6)
　　　　oSeries.MarkerForegroundColor = arrTcsRgb((idx \ 2) Mod 6)
系列１２までで６色を使い切ると、Accent1に戻り、
１２系統単位の繰り返しで色を替えます。
既定の色の場合も、６色６系統単位の繰り返しですから、
同じよう（相似）な規則性です。

系列の数を増やして作り直したサンプルでテストしてみて気が付いたのですが、
マーカーのスタイルについては、自動のままでいいのでしょうかね？
、、、あれこれ話が拡がりすぎるのも、難しいですから、
これは、次の段階での課題、ということで、、、。

実は、各ブック固有の配色パターンの数＝６、
これに縛られる必要はない訳ですから、
数を増やした独自の配色パターンを用意すれば、
理論上は、RGB関数等でも 16777215 通りの色分けは出来ます。
色の数を増やし過ぎても現実的でないことは言うまでもありませんが、
8、10色程度なら独自の配色パターンを決めている企業も見かけます。
そもそも機能的な要求として、区別が付き易いように色を付けている訳ですが、
実際のグラフの大きさ・細かさ・表示の仕方・系列数など様々な状況から、
とても相対的に、機能性に対するアプローチは変わると思います。
また、デザイン性だとか、Corporate Identityからの要求もあるかも知れませんね。

案外、選択肢（決めていかないと次が出来ないこと）が多い課題ですから、
少しずつ進化させていった方が紛れなくていいかもです。

補足、以上です。

お礼

ご丁寧な説明ありがとうございました。
私のエクセルは２０１０です。書き忘れて失礼いたしました。

早速動作確認してみましたところ確かに隣り合う二系列が同色になりました。
ただ、配色はmsoThemeAccent1～6の繰り返しになって、１２系列ごとの
色の組み合わせは同じになってしまうようです。（系列１と系列１３は同色）
系列１３からは濃淡を変えるなどして、色分けするにはどうしたらよいでしょうか？

そもそもそんなにたくさんの系列をグラフで色分けすること自体意味がないのですが、
向学のためにご教授願えれば幸いです。

（本来は、あらかじめ見分けやすい色のRGBを用意しておいて、系列が多くなって
きたら古いデータはまとめて同色にするなどするの方法が良い気がしてきました。）

回答No.3

real beatin（@realbeatin）

こんにちは。

お求めのままにお応えすると、例えばこんな感じ。
（Excelのバージョン判らないですが、xl2010で書いてます）

Sub Re8916999()　'　このサンプルは必ず、Chart（総体）をアクティブにしてから実行
Dim oSeries As Series
Dim iSc As MsoThemeColorSchemeIndex
Dim arrTcsRgb(0 To 5) As Long
Dim idx As Long

　　With ThisWorkbook.Theme.ThemeColorScheme
　　　　For iSc = msoThemeAccent1 To msoThemeAccent6　' 5 To 10
　　　　　　arrTcsRgb(iSc - msoThemeAccent1) = .Colors(iSc).RGB
　　　　Next iSc
　　End With

　　idx = 0
　　For Each oSeries In ActiveChart.SeriesCollection
　　　　oSeries.MarkerBackgroundColor = arrTcsRgb(idx \ 2)
　　　　oSeries.MarkerForegroundColor = arrTcsRgb(idx \ 2)
　　　　idx = idx + 1
　　Next
End Sub

【ThisWorkbook.Theme.ThemeColorScheme.Colors(index)】
という書式で各ブック固有の配色パターンから、
グラフ系列に用いる[アクセント]の色（Accent1-Accent6の６種類）を取得します。

その色を（使い回しがし易いようにする為に）一旦、
配列変数 arrTcsRgb(0 To 5) に格納しておきます。

ActiveChart.SeriesCollection の各Seriesを総当たりでループして、
> 系列1，2、系列3，4、のように隣り合う系列を同色に...
します。

一応、こちらでは動作結果を確認していますが、
せっかく書いたので、そちらでも動かしてみて、
望みの結果が得られるか、教えて下さいね。

ところで、こんな感じで書いてはみたものの、
ブックの配色パターンをユーザー定義で追加登録しておけば、
既定の色で設定してある（変更を加えていない）グラフの色を
一斉に、簡単に切り替えることが出来ます。
予め追加登録しておくか、既存のグラフの色を弄っていない場合なら、
マクロなんて必要ないってことになるかもしれませんね。
（ここら辺は、実際にお使いになるユーザーさんのニーズの問題なので、
　私には、どちらとも判断つきませんが）

『グラフの既定の配色を好きな色に設定する』
http://www.moug.net/tech/exopr/0010017.html

ユーザー定義で追加登録した配色パターンを、
各ブックに適用させるマクロなら、マクロの記録で簡単に採れる筈です。
xl2010の場合
　　ActiveWorkbook.Theme.ThemeColorScheme.Load ("フォルダパス\配色パターン名\.xml")
のような書式になります。

とりあえず。以上です。何か不足有れば補足ください。

回答No.2

okormazd

#1です。
すみません。うまくいかないようです。ごめんなさい。
#1回答は取り消します。「破棄」してください。お手数を煩わしました。

お礼

いえいえ。ご回答くださったことがありがたいです。
今後もよろしくお願いいたします。

回答No.1

okormazd

前景色については何も言ってないが、背景色を自動と同じにしても前景色はそのままなので、それも変えるには、MarkerForegroundColorを使えばいいでしょう。 bcolor をMarkerBackgroundColorIndexでとるとbcolor は相変わらず自動になって、SeriesCollection(2)も(本来の)自動になってしまう。変数にColor(予約語?)を使うのはどうかな。
下記でどうでしょう。

ActiveChart.SeriesCollection(1).Select
With Selection
.MarkerBackgroundColorIndex = xlAutomatic
bcolor = .MarkerBackgroundColor
' fcolor = .MarkerForegroundColor
End With

ActiveChart.SeriesCollection(2).Select
With Selection
.MarkerBackgroundColor = bcolor
' .MarkerForegroundColor = fcolor
End With