関数を教えてください。

質問

表）
　A B C D
1
2
3
4
5

●やりたいこと
Dのセルに、プルダウンでリストの　AAセル<品名>　を選択します。

Dのセルの元となるプルダウンリスト↓　
（AA1～AD6にリストがあり、AAセルのいずれかを選びます)

　　　AA　　　　　　AB　　　　　　AC　　　　　AD

１　<品名>　　　<産地>　　<契約会社>　<型番>
２　りんご　　　青森　　　　A社　　　　　FT001
３　みかん　　　愛媛　　　　B社　　　　　FT002
４　バナナ　　　台湾　　　　C社　　　　　FT003
５　アボカド　　メキシコ　　D社　　　　　FT004
６　パパイヤ　　インド　　　E社　　　　　FT005

Dのセルにいずれかを選択すると、A,B,Cセルにリストの情報(産地、契約会社、型番）が
自動反映されるようにしたいです。

例）D１セルに「アボカド」をプルダウンで選択する。
A1、B1、C1のそれぞれのセルに下記内容が自動反映される。

A1：メキシコ、B1：D社、C1：FT004

表としては、一列がすべて埋まります。A1：メキシコ、B1：D社、C1：FT004、D1：アボカド

関数初心者で色々設定してみましたが、
自動反映希望場所が「#N/A」になってしまったり、それをなくそうとすると
空白になってしまったり、どうすればいいのかよくわからなくなってしまいました。

プルダウン選択する前は、すべて空白。(例：D1未選択=空白時、A1、B1、C1も空白)
プルダウン選択した際（Dセル）、自動反映(A1,B1,C1)。
プルダウン情報しか入らないので、エラー表示は出ないようにしたい。

どなたかご教授いただけませんでしょうか。
よろしくお願いします。

回答No.2

keithin · ベストアンサー

ＶＬＯＯＫＵＰ関数が正しく利用できるようになれば、エクセル初級者卒業です。

練習：
http://www.eurus.dti.ne.jp/~yoneyama/Excel/kansu/vlookup2.htm

本番：
Ｄ１セルに入力規則でプルダウン選択できるように仕込む
Ａ１には
=IF(D1="","",VLOOKUP(D1,AA:AD,2,FALSE))
Ｂ１には
=IF(D1="","",VLOOKUP(D1,AA:AD,3,FALSE))
Ｃ１には
=IF(D1="","",VLOOKUP(D1,AA:AD,4,FALSE))
とそれぞれ仕込む
必要に応じて、Ａ１：Ｄ１を下向けにコピー貼り付けておく。
ＶＬＯＯＫＵＰ関数がちゃんと使えるようになったら、更に他の関数を組み合わせて利用できるようにガンバる。

＃応用
ご利用のエクセルのバージョンがご相談に書かれていませんが、エクセル２００７以降を利用している場合は
Ａ１：
=IFERROR(VLOOKUP(D1,AA:AD,2,FALSE),"")
などのようにすることもできます。

お礼

vlookupの勉強サイトまでつけていただきありがとうございます。

これを作ろうと思っていました。
間違い箇所が分かりました。

ありがとうございました。

回答No.1

tom04

こんばんは！
D1セルのリスト表示はできているのですね？

A1セルに
=IF($D1="","",VLOOKUP($D1,$AA:$AD,COLUMN(B1),0))
または
=IF($D1="","",INDEX(AB:AB,MATCH($D1,$AA:$AA,0)))
という数式を入れC1セルまでフィルハンドルでコピーしてみてください。m(_ _)m

お礼

早急にご回答ありがとうございます。

お恥ずかしいですが、COLUM、INDEX/MATCHについて初めて知りました。
こんな方法があるのですね。

勉強になりました。ありがとうございました。