オートフィルター後の見出し以外をコピー

質問

お世話になっております。Excel2003を使ってます。

オートフィルター後の、見出し以外をコピーしようと考えています。
現在は
With　ThisWorkbook.Worksheets("テスト")
.Range("B2:B" & Cells(Rows.Count, 2).End(xlUp).Row).SpecialCells(xlCellTypeVisible).Select '可視セルの選択
Selection.Copy '可視セルコピー
ThisWorkbook.Worksheets("フィルタ用").Range("A" & m).PasteSpecial 'A列に貼り付け！
Excel.Application.CutCopyMode = False 'クリップボードの内容クリア
End with

この内容で上手くいっていましたが、
見出し+1行しかない場合、
全範囲選択になってしまい、上手くいかない状況です。

どうやったら、見出し以外のB列をコピーできるのでしょうか？
Offset　とか、　Resize　を使えばいけるのでしょうか…？

見出し以外の行、
B列、C列、D列　F列　を　「TEST」シートにコピーしたいです。

With ThisWorkbook.Worksheets("テスト").Range("A1").CurrentRegion
.Offset(1, 1).Resize(.Rows.Count - 1, 3).Copy _
Destination:=Thisworkbook.worksheets("TEST").Range("A" & m)
.Offset(1, 4).Resize(.Rows.Count - 1, 1).Copy _
Destination:=Thisworkbook.worksheets("TEST").Range("D" & m)
End With

考えたのですが、良く分からなくなってしまいました。
回答をお願い致します！

回答No.1

keithin · ベストアンサー

オートフィルタを取り付けるところから。

sub macro1()
　　m = ■■
　　with thisworkbook.worksheets("テスト")
　　.range("A:F").autofilter field:=■■, criteria1:=■■

　　with .autofilter.range.offset(1)
　　　.columns(2).copy destination:=thisworkbook.worksheets("TEST").cells(m, "A")
　　　.columns(3).copy destination:=thisworkbook.worksheets("TEST").cells(m, "B")
　　　.columns(4).copy destination:=thisworkbook.worksheets("TEST").cells(m, "C")
　　　.columns(6).copy destination:=thisworkbook.worksheets("TEST").cells(m, "D")
　　end with
　end with
end sub

他にも
application.intersect(worksheets("テスト").autofilter.range.offset(1), worksheets("テスト").range("B:B")).copy
なんて方法もあります。

お礼

回答ありがとうございます！

おぉおお、こんな方法があるのですね！
回答を頂くまでの間に

------------------
With ThisWorkbook.Worksheets("テスト").Range("A1").CurrentRegion
.Offset(1, 1).Resize(.Rows.Count - 1, 3).SpecialCells(xlCellTypeVisible).Copy _
Destination:=ThisWorkbook.Worksheets("TEST").Range("A" & m)
.Offset(1, 5).Resize(.Rows.Count - 1, 1).SpecialCells(xlCellTypeVisible).Copy _
Destination:=ThisWorkbook.Worksheets("TEST").Range("D" & m)
Excel.Application.CutCopyMode = False 'クリップボードの内容クリア
End With
---------------------------------------
こういった方法を考えておりました。
とても分かりにくくて、残念ですorz

でも、keithin様の回答してくださったプログラムを見たら
一発で何がしたいか分かりましたし、
何より1文が短いです！

ありがとうございました＾＾
使わせて頂きます！