ロートルの初心者です、VBAについての質問です。

質問

エクセル2003で以下のVBAを色々な資料を基に、「テスト２」のシートに条件検索されたデータ、マクロ起動（？）で「入力履歴」に追記されるものを作成しました。

Sub prog()

Dim myFld As String, myCri As String
Dim myRow As Long
Dim Sh2 As Worksheet, Sh3 As Worksheet
Set Sh2 = Worksheets("テスト２")
Set Sh3 = Worksheets("入力履歴")

With Sh2

myRow = .Range("D" & Rows.Count).End(xlUp).Row

Range("A1:H" & myRow).Copy Destination:=Sh3.Range("A" & Rows.Count).End(xlUp).Offset(1)

End With

Sh3.Activate
Range("A1").Select

End Sub

ここで問題となるのが抽出データには関数が含まれているため「入力履歴」シートに書き込まれたデータにもそのまま貼り付けられるので「＃A/N」となってしまいます。

Range("A1:H" & myRow).Copy Destination:=Sh3.Range("A" & Rows.Count).End(xlUp).Offset(1)の
「Destination」を変えれば良いかと思ったのですが・・・、うまくいきません。

エクセルでいう、「形式を選択して貼り付け→値」をやりたいのですが書き方がわかりません。

ロートルの初心者によろしく愛の手をお願い申します。

PS:説明文があると助かります。

回答No.1

tsubuyuki · ベストアンサー

「マクロの記録」機能はご存知ですか？
http://www4.synapse.ne.jp/yone/excel2010/excel2010_macro_kiroku.html
上記など、解説サイトはゴロゴロしていますので、別途お調べくださいませ。
要するに「記録中のエクセルでの操作をコードに置いてくれる」機能です。
これで大体の基本操作を記録することが出来ます。

さて、本題の「コピー→値の貼り付け」の操作ですが、
例えば「Ａ１セルをコピー→Ｂ１セルに値を貼り付け」を
マクロに記録してやると、

Sub Macro1()
'
' Macro1 Macro
'

'
　　　　Range("A1").Select
　　　　Selection.Copy
　　　　Range("B1").Select
　　　　Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
　　　　　　　　:=False, Transpose:=False
End Sub

このように録れるはずです。
「形式を選択して貼り付け」には「.PasteSpecial」を使うんだなぁ、と気が付くでしょう。
ついでに、なんとな～く、
「値を貼り付け」＝「Paste:=xlPasteValues」なんだろうなぁ、と読めてくるはずです。
さらにちょっとだけツッコムと、「形式を選択して貼り付け」ダイアログと照らし合わせ、
・Operation:=xlNone⇒演算＝なし
・SkipBlanks:=False⇒空白セルを無視するのチェック＝なし
・Transpose:=False⇒行列を入れ替えるのチェック＝なし
というのが見えてきます。（ちなみにこれらは「なし」なら省略可能です。）

では、あとはこれをお望みの形に書き換えてやりましょう。

例）
Sub prog2()
Dim myFld As String, myCri As String
Dim myRow As Long
Dim Sh2 As Worksheet, Sh3 As Worksheet
Set Sh2 = Worksheets("テスト２")
Set Sh3 = Worksheets("入力履歴")

With Sh2
　　　　myRow = .Range("D" & Rows.Count).End(xlUp).Row

　　　　' コピーして
　　　　Range("A1:H" & myRow).Copy　　　　

　　　　' 値を貼り付け
　　　　Sh3.Range("A" & Rows.Count).End(xlUp).Offset(1).PasteSpecial Paste:=xlPasteValues

　　　　Application.CutCopyMode = False
End With

Sh3.Activate
Range("A1").Select

End Sub

こんな具合にしてやると、おそらく上手くいくと思いますよ。

お礼

出張中で確認が遅れました。

回答ありがとうございました、分かりやすく私が求めていた通りで
大変助かります。

年をとると頭が固くなり一寸したことが浮かばなくて・・・f^ ^;

回答No.2

play_with_you

＞「形式を選択して貼り付け→値」
セルの「値」はValue、「数式」はFunctionで参照できます。
ここで、「式の結果の値」つまりセルに表示されているものは…じつはValueで取得できます。
なので、ややこしいことは考えず、

貼り付け先セル.Value = コピー元セル.Value

とすればOKだったりします。
PasteSpecialについて知るのはもちろんいいことですけどね。

お礼

遅くなり申し訳ありません。

そうですね、難しく考えることはなかったのですね。

ありがとうございました。