-PR-
解決済み

エクセル関数です

  • 困ってます
  • 質問No.855104
  • 閲覧数38
  • ありがとう数3
  • 気になる数0
  • 回答数5
  • コメント数0

お礼率 36% (4/11)

頭の悪い私に誰か教えてください。
エクセルでA1が0以外の時に、B1<5であれば1を、B1<10であれば2を、B1<20であれば3の値を出すにはどうしたらいいのでしょうか。
きっと過去に回答はあると思うのですが探せませんでした。
通報する
  • 回答数5
  • 気になる
    質問をブックマークします。
    マイページでまとめて確認できます。

質問者が選んだベストアンサー

  • 回答No.1
レベル12

ベストアンサー率 42% (337/793)

=IF(A1=0,0,IF(B1<5,1,IF(B1<10,2,IF(B1<20,3,0))))
とりあえずこれでいけます。
頑張ってくださいヽ(^。^)ノ

その他の回答 (全4件)

  • 回答No.2
レベル10

ベストアンサー率 25% (40/156)

IF関数でどうでしょうか?
セルA1に次の式を入れます
=IF(B1<5,1,IF(B1<10,2,IF(B1<20,3)))
するとB1に記入した数値によって質問の内容どおりにA1に表示されるはずです。ただしB1に20以上の数値を入れると設定していないのでFALSEが表示されます。


  • 回答No.3
レベル14

ベストアンサー率 28% (4404/15619)

オフィス系ソフト カテゴリマスター
多分質問題は例示であって、もっと沢山のケースが実際はある、と勘ぐって、下記関数の利用を勧めます。
D1:E4に(どこでも空きのセル範囲でよい。)
01
52
103
204
区分けが増えれば、範囲値と評価値を下行に続ける。
C1セルに
=IF(A1<>0,VLOOKUP(B1,$D$1:$E$4,2,TRUE),"")
といれて下方向に複写する。
A列、B列に値が入っていない場合の式の変え方は略。
$の付いているところは必ず付けること。TRUE型に対し
FALSE型があるので、この問題には、TRUEを指定のこと。
111
141
152
192
1103
1193
1204
1214
1304
  • 回答No.4
レベル14

ベストアンサー率 39% (7413/18940)

A1が0の場合と、B1が20以上の場合はどうするのですか?

非表示として
=IF(OR(A1=0,B1>=20),"",CHOOSE(INT(MAX(B1,0)/5+1),1,2,3,3))

上記の式
IF(OR(条件1,条件2),結果1,結果2)は、
条件1または条件2が成立で結果1を、両方不成立で結果2を返します。

MAXでB1が負の数値の場合、0に置換
5で割ってINTで小数点切り捨てで0,1,2,3になります。
これに1を足して、1,2,3,4
結果が4の場合3にするため、CHOOSE関数で調整
MID("1233",INT(MAX(B1,0)/5+1),1)+0
でも同じ結果です。
  • 回答No.5
レベル11

ベストアンサー率 55% (132/236)

=IF(A1=0,"",MATCH(B1,{0,5,10,20}))
はどうでしょう?

0~4は1 , 5~9は2 , 10~19は3 , 20~は4で表示されます。
(MATCH関数でシートを使用しない方法です。)
シートを利用してもできます。

0以下もあるのならば、
=IF(A1=0,"",MATCH(B1,{-10,5,10,20}))
のようにすれば、-10~4まで1になります。
それ以下の場合エラー表示が出ますし、20以上は全て4ですので
数字の範囲指定をした方がいいと思います。
例えば
=IF(A1=0,"",IF(OR(B1<0,B1>29),"Error",MATCH(B1,{0,5,10,20})))
お礼コメント
meyer

お礼率 36% (4/11)

taisuke555さん、ありがとうございました。
今回は簡単なIF関数で事足りました。
でも本当にありがとうございました。勉強になりました。
投稿日時 - 2004-05-11 16:12:51
このQ&Aで解決しましたか?
関連するQ&A
このやり方知ってる!同じこと困ったことある。経験を教えて!
このQ&Aにはまだコメントがありません。
あなたの思ったこと、知っていることをここにコメントしてみましょう。

その他の関連するQ&A、テーマをキーワードで探す

キーワードでQ&A、テーマを検索する
-PR-

特集


開業・独立という夢を持つ人へ向けた情報満載!

ピックアップ

ページ先頭へ