EXCEL（エクセル）の関数について

質問

こんにちは、お世話になります。
エクセルの数式で困っており、ご教示頂きたいです。

C1のセルに、値を返させたいのですが、
A1の値が◆でB1が空白セルでなければ◇
A1の値が●でB1が空白セルでなければ○
A1の値が▲でB1が空白セルでなければ△
A1の値が■でB1が空白セルでなければ□
、と返させたいです
全ての条件が満たされない場合は空白セルを表示させたいのですが、これを可能にするにはどのような数式を用いればよいでしょうか？
宜しくお願いします。

回答No.5

kagakusuki

この様な場合に使用するのは、VLOOKUP関数よりは、LOOKUP関数の方が良いと思います。

=IF(OR(B1="",ISERROR(MATCH(A1,{"◆","●","▲","■"},0))),"",LOOKUP(A1,{"◆","●","▲","■";"◇","○","△","□"}))

回答No.4

kmetu

他には

たとえばE列とF列に

　　E　　　F
１　◆　　◇
２　●　　○
３　▲　　△
４　■　　□

とデータを並べておいて

=IF(B1="","",IF(ISERROR(INDEX($F$1:$F$4,MATCH(A1,$E$1:$E$4,FALSE),1)),"",INDEX($F$1:$F$4,MATCH(A1,$E$1:$E$4,FALSE),1)))

というのもありでしょう。

回答No.3

MackyNo1

ご希望の条件を数式だけで実行する場合は、例えば以下のような数式になります。

=IF(OR(B1="",NOT(OR({"◆";"●";"▲";"■"}=A1))),"",VLOOKUP(A1,{"◆","◇";"●","○";"▲","△";"■","□"},2,0))

回答No.2

imogasi

こんなのはＶＬＯＯＫＵＰ関数のＴＲＵＥ型でやれば仕舞いではない？
ＶＬＯＯＫＵＰ関数を知らないのは、エクセルの勉強不足。エクセルの良く使う関数。
Ｅ１：Ｆ４に（何処でも空きセル範囲で良いが）
◆ ◇
● ○
▲ △
■　　　　　　(チェックボックス 空欄)
例データ
Ａ１：Ｂ7　Ｃ列は関数の結果
A列　　　Ｂ列　　　　Ｃ列
◆ aa ◇
◆
● ｂ ○
●
▲ ｃ △
▲

x
x y

ーー
Ｃ１の式は
=IF(AND(B1<>"",NOT(ISERROR(VLOOKUP(A1,$E$1:$F$4,2,FALSE)))),VLOOKUP(A1,$E$1:$F$4,2,FALSE),"")
下方向に式を複写
意味は
Ｂ１が空白でなく、検索表Ｅ列に見つかれば、Ｆ列の値を取る。
でなければ空白をセット。

回答No.1

kmetu

単純に

=IF(B1="","",IF(A1="◆","◇",IF(A1="●","○",IF(A1="▲","△",IF(A1="■","□","")))))

でいかがですか