EXCEL VBAフォームからPDFファイルを検索

質問

お世話になります。

下記のような名称のPDFファイルがあります。

(例：60期12345チョコパン.pdf)

説明をしますと、60期(必ず2桁)が作成された期で、12345が商品番号(必ず5桁)でチョコパンが商品名(最大20文字)です。
このように期と商品番号と商品名が異なるファイルが100個ほどあります。
XX期○○○○○▲▲▲▲▲.pdf
ファイルの置き場所は私のPCのローカル[C:\PDF] 配下です

(やりたい事)
このPDFファイルをExcelのフォームからVBAを使って検索したいのです。
下記の様に(1)、(2)の2つの方法で検索できるようにしたいのです。

(1)期で検索 【テキストボックス1に入力された期で検索】 検索ボタン1
(2)商品番号で検索 【テキストボックス2に入力された商品番号で検索】 検索ボタン2

(1)の検索で何個か候補としてヒットしたPDFをリストボックスか何か一覧表示させて、該当のデータがあった場合にそのデータがダブルクリックされたら、該当PDFを表示させたいです。
表示方法は別フォームで該当のPDFを表示しても、直接PDFを開いてもどちらでも結構です。

(2)の検索でPDFが見つかった場合は、(1)と同様に別フォームでPDFを表示しても直接PDFを開いてもどちらでも結構です。

お手数ですがどなたかご教授いただけませんでしょうか？

環境
Windows XP SP3 Excel2003

回答No.1

MSZ006 · ベストアンサー

これでどうでしょうか。
期もしくは品番で検索し、該当するファイルをリストボックス表示、ダブルクリックで開きます。
----------------

【ThisWorkbook】に下記を入力。

Sub FileSelect()
UserForm1.Show
End Sub

【UserForm】に下記を入力。

Private path As String

Private Sub UserForm_Initialize()
path = "C:\PDF\" 'ファイル格納フォルダ
End Sub

Private Sub CommandButton1_Click() '期検索
Dim i As Long
Dim str As String
Dim fname As String

str = TextBox1.Value
If Len(str) <> 2 Or Not (IsNumeric(str)) Then
i = MsgBox("入力値が不正です", vbOKOnly)
Exit Sub
End If

fname = Dir(path & "*.pdf")
ListBox1.Clear
Do While fname <> ""
If Left(fname, 2) = str Then
ListBox1.AddItem fname
End If
fname = Dir()
Loop
End Sub

Private Sub CommandButton2_Click() '品番検索
Dim i As Long
Dim str As String
Dim fname As String

str = TextBox2.Value
If Len(str) <> 5 Or Not (IsNumeric(str)) Then
i = MsgBox("入力値が不正です", vbOKOnly)
Exit Sub
End If

fname = Dir(path & "*.pdf")
ListBox1.Clear
Do While fname <> ""
If Mid(fname, 4, 5) = str Then
ListBox1.AddItem fname
End If
fname = Dir()
Loop
End Sub

Private Sub ListBox1_DblClick(ByVal Cancel As MSForms.ReturnBoolean) 'ファイル選択／表示
Dim fname As String

If ListBox1.Text = "" Then Exit Sub
fname = path + ListBox1.Text
Shell ("explorer.exe " & fname)
End Sub

お礼

MSZ006さん、おはようございます。

先ほど金曜日にご教授いただきましたロジックを動かしてみましたところ、完璧に動作しました!!

すごいですー！本当に助かりました！！

この度は本当にありがとうございましたm(_ _)m

補足

MSZ006さん、早速のご連絡ありがとうございます！

こんなに細かなロジックをご教授いただきましてありがとうございます！！

早速試してみたいのですが、急な外出が入ったため、連休中に試させていただきます！！
本当にありがとうございました。

取り急ぎ御礼申し上げますm(_ _)m