正規表現について

質問

VBSでRegExpで文字を抽出したいのですが、上手くいきません。

*****abc********
************}

*は不確定の文字で、キーワードはabcと}です。がabcの先頭行から}までの複数行を
抽出したいです。

re.Pattern = "[^*].*abc.*}" だと上手く動きません。

よろしくお願いします。

回答No.2

pacman_chie · ベストアンサー

一応、パターンを4つ用意しました。
おそらく最初ので十分だと思うので蛇足ですが。

devidさんの作成した "[^*].*abc.*}" の意味は以下のようになるので、[^*]は ほぼ無意味です。
*以外の1文字、色々な文字いっぱい、abc、色々な文字いっぱい、}で終わり

なお . に改行は含まれません。
改行にマッチさせるためには提示したコードのようにするか、明示的に (.|\n) のように改行を含める必要があります。

S1=_
"****" & vbCrLf &_
"*****abc********" & vbCrLf &_
"************}" & vbCrLf &_
"++++++++" & vbCrLf &_
"++++++++++abc++" & vbCrLf &_
"++}++++++" & vbCrLf &_
"@}@}@@@" & vbCrLf &_
"XXXXX"

Set R=CreateObject("VBScript.RegExp")
R.Global=True

R.Pattern=".*abc[^}]*}" 'abc以降、最初の } まで
'R.Pattern=".*abc[^}]*}.*" 'abc以降、最初の } がある行の最後まで
'R.Pattern=".*abc[\s\S]*}" 'abc以降、最後の } まで
'R.Pattern=".*abc[\s\S]*}.*" 'abc以降、最後の } がある行の最後まで

Set M=R.Execute(S1)
S2=M.Count & "個" & "にマッチ"

For I=0 to M.Count-1
S2=S2 & vbCrLf & vbCrLf & "Index=" & I & vbCrLf & M(I)
Next

WScript.Echo S2

お礼

できました。有難うございます。

回答No.1

jin34

「abcの先頭行から}までの複数行を抽出したいです。」の意味がよくわからないのですが、
構文としては
re.Pattern = "^.*abc.*}$"　でしょうか。
似たような質問に最近回答していますのでそちらを参照してください。

参考URL：

http://okwave.jp/qa/q7979844.html

補足

re.Pattern = "^.*abc.*}$"で動きません。。
abcの先頭行からとは、
****
****abc****
****}
のばあい、
上は無視して
****abc****
****}のみ抽出という意味です。
ちなみに"[^*].*abc"だと
****abcまでは抽出できています。。