Excelマクロ行数が不定な場合のコピーペースト等

質問

こんにちは。
Excel2007を使用しています。

4つのBook(Book1,2,3,4)にそれぞれ60000行ほどのデータが格納されています
データーの最終行はそのときによって変わります。（ですので困っています）

Book2,3,4をBook1の最後にコピーして一つのBookにしたいのですが
具体的な行番号が書かれてしまい汎用性が有りません。

最後の行を選択する場合の例
Windows("Book1.xlsx").Activate
Selection.End(xlDown).Select
Range("A595002").Select

ソートする場合の例
With ActiveWorkbook.Worksheets("sheet1").Sort
.SetRange Range("A1:AP231196")
.Header = xlYes
.MatchCase = False
.Orientation = xlTopToBottom
.SortMethod = xlPinYin
.Apply
End With

このような場合どう書けば良いでしょうか？
おわかりの方お教えください。

回答No.4

mt2008 · ベストアンサー

ANo.3です。
あぁ、シート名の変更ミスだったのですね。
納得しました。

> 実際にしたいことは4枚のtxtファイル（30列x約65000行のCSVファイル、データーベースのログファイルです）をExcelに読み込ませる。
> 1枚目のtxtファイルに他の3枚の内容を追加する。
> コピーし終わった3枚のファイルは変更せずにtxtのまま終了させる

ここまでは出来ているという事ですね……。
で、あればソートはこんな感じでいいと思います。
キーは、先頭の1つだけ指定してあれば大丈夫です。ソートの範囲も列指定でいけます。

ActiveWorkbook.Worksheets("Sheet1").Sort.SortFields.Clear
ActiveWorkbook.Worksheets("Sheet1").Sort.SortFields.Add Key:=Range("I2"), SortOn:=xlSortOnValues, Order:=xlDescending, DataOption:= xlSortNormal
With ActiveWorkbook.Worksheets("Sheet1").Sort
　　.SetRange Range("A:AP")　’30列ならAPではなくADでは？
　　.Header = xlYes
　　.MatchCase = False
　　.Orientation = xlTopToBottom
　　.SortMethod = xlPinYin
　　.Apply
End With

余談ですが、４つのテキストファイルを以下のような内容のバッチファイルを作って結合させてから開くと楽かもしれません。
copy aaa.txt+bbb.txt+ccc.txt+ddd.txt append.txt

お礼

ありがとうございます。
おかげで実用的なマクロになりました。

回答No.3

mt2008

補足に対して……

> ソートする前の段階で困っています

どこかで拾ってきたコードの寄せ集めでしょうか。
Activeなシートが何なのか解りませんし、"sheet1"と"0_Ver2_PER_Summary"の関係も不明で
何をしたいのか読み取れませんでした。

やりたい事を具体的に文章で書いてください。

補足

ご指摘申し訳ありません。

実際の作業を「マクロの記録」でマクロを作成し、コードを掲載しました。
理解していただきやすいように"0_Ver2_PER_Summary"を"sheet1"に書き換えましたが書き換え忘れです。

実際にしたいことは4枚のtxtファイル（30列x約65000行のCSVファイル、データーベースのログファイルです）をExcelに読み込ませる。
1枚目のtxtファイルに他の3枚の内容を追加する。
コピーし終わった3枚のファイルは変更せずにtxtのまま終了させる
1枚目のファイルの先頭行は項目なのでI行を降順にソートする。
決まった名前をつけてxlsx形式でデスクトップに保存する。
作業を続けたいのでxlsxファイルは開いたままにしておく。

困っていることは4枚目のtxtファイルは毎日行数が増えるので、作業を行うたびに最終行が変わることです。

そのため今回、質問をしました。
よろしくお願いいたします、

回答No.2

keithin

簡易法１：
workbooks("Book2.xlsx").worksheets("Sheet1").range("A1").currentregion.copy _
　destination:=workbooks("Book1.xlsx").worksheets("Sheet1").cells(rows.count, "A").end(xlup).offset(1)

Book3,4についても同じ。

簡易法２：
workbooks("Book2.xlsx").worksheets("Sheet1").range("A1:AP65536").copy _
　destination:=workbooks("Book1.xlsx").worksheets("Sheet1").cells(rows.count, "A").end(xlup).offset(1)
workbooks("Book3.xlsx").worksheets("Sheet1").range("A1:AP65536").copy _
　destination:=workbooks("Book1.xlsx").worksheets("Sheet1").cells(rows.count, "A").end(xlup).offset(1)
workbooks("Book4.xlsx").worksheets("Sheet1").range("A1:AP65536").copy _
　destination:=workbooks("Book1.xlsx").worksheets("Sheet1").cells(rows.count, "A").end(xlup).offset(1)

ゲンミツがいいなら：
Ａ：Ｚ列をコピーするとして
Ａ列でデータの最下行を検出できるとして
workbooks("Book1.xlsx").select
worksheets("Sheet1").select
with workbooks("Book2.xlsx").worksheets("Sheet1")
　.range("A1:Z" & .cells(.rows.count, "A").end(xlup).row).copy _
　　destination:=cells(rows.count, "A").end(xlup).offset(1)
end with

Book3,4についても同じ。

回答No.1

mt2008

こんな感じでどうでしょう

> 最後の行を選択する場合の例
Windows("Book1.xlsx").Activate
Selection.End(xlDown).Select
Range("A595002").Select

↓
Windows("Book1.xlsx").Activate
Cells(Rows.Count, 1).End(xlUp).Select

> ソートする場合の例
With ActiveWorkbook.Worksheets("sheet1").Sort
　　.SetRange Range("A1:AP231196")
　　.Header = xlYes
　　.MatchCase = False
　　.Orientation = xlTopToBottom
　　.SortMethod = xlPinYin
　　.Apply
End With

↓
With ActiveWorkbook.Worksheets("sheet1").Sort
　　.SetRange Range("A:AP")
　　.Header = xlYes
　　.MatchCase = False
　　.Orientation = xlTopToBottom
　　.SortMethod = xlPinYin
　　.Apply
End With

補足

ご回答ありがとうございます。
ソートする前の段階で困っています

Selection.CurrentRegion.Select
ActiveWorkbook.Worksheets("sheet1").Sort.SortFields.Clear
ActiveWorkbook.Worksheets("sheet1").Sort.SortFields.Add Key:= _
ActiveCell.Offset(0, 9).Range("A1:A231195"), ---->ここSortOn:=xlSortOnValues, Order:= _
xlDescending, DataOption:=xlSortNormal
With ActiveWorkbook.Worksheets("0_Ver2_PER_Summary").Sort
.SetRange ActiveCell.Offset(-1, 0).Range("A1:AP231196")---->削除したら保存された
.Header = xlYes
.MatchCase = False
.Orientation = xlTopToBottom
.SortMethod = xlPinYin
.Apply
End With

4行目の処理方法をお教えください