Accessでの禁止文字チェック方法とは？

質問

• Accessでのデータチェックについて質問がありました。具体的には、「データ一覧」と「許可文字一覧」という2つのテーブルを利用して、データ一覧に許可文字一覧以外の文字が含まれているかをチェックしたいとのことです。質問文には具体的なデータ例も掲載されており、エラーレコードの表示方法についても言及されています。
• 質問者は、Excel版の回答を見つけたものの、Accessでの関数や呼び出し方が分からないとのことです。そこで、Accessでの禁止文字チェックについて詳しく教えていきましょう。
• Accessでは、許可文字一覧テーブルを作成し、テーブル間のクエリを使用してデータ一覧テーブルのチェックを行うことができます。具体的な手順やクエリの作成方法について説明します。ハッシュタグも用意しており、Accessでのデータチェックに関心のある方に役立つ情報となっています。

回答No.3

30246kiku · ベストアンサー

＃２です。

> Dim rs As New ADODB.Recordset　行で
> で「ユーザ定義型は定義されていません」が出てしまい、

VBE のメニュー「ツール」→「参照設定」で、
Microsoft ActiveX Data Objects X.Y Library　を追加してみてください。

X.Y は、2.5　とか　2.8　とか。
2007 をメインで使ってますが、2000 形式にしたりするので、私は 2.5 を参照してますけど。

なお、DAO でする場合は以下のような感じに

Public Function DicMake() As Boolean
　　Dim rs As DAO.Recordset

　　If (dic Is Nothing) Then Set dic = CreateObject("Scripting.Dictionary")
　　dic.RemoveAll

　　Set rs = CurrentDb.OpenRecordset(sTable)
　　While (Not rs.EOF)
　　　　dic.Item(rs(sField).Value) = Null
　　　　rs.MoveNext
　　Wend
　　rs.Close
　　Set rs = Nothing
　　DicMake = True
End Function

仕様がもう少し固まっていれば・・・記述も変わってきます。

＃２では、
「名称」内に許可文字が複数回出現しても、それは許可しています。
（「名称」が "アイアイ" であっても許可）

また、「文字」が１文字長でなくても処理できるように冗長にしています。が、

許可の「文字」が、"アイ" "ア" であった場合、処理順を考える必要があります。
"アイアイ" を "アイ" "ア" の順で処理すると、全て削除され表示対象になりませんが、
"ア" "アイ" の順で処理すると、"イイ" が残ります。

許可の「文字」が、"イイ" "ア" であった場合、処理順を考える必要があります。
"アイアイ" を "ア" "イイ" の順で処理すると、全て削除され表示対象になりませんが、
"イイ" "ア" の順で処理すると、"イイ" が残ります。

レコードセットを得る時等で、順を考える必要があります。
テーブル名を指定する際に、SQL記述にして順を指定・・・とか
例えば、クエリで見た時の記述（文字列長が長い順で、昇順）

SELECT * FROM 許可文字一覧
ORDER BY Len(文字) DESC, 文字;

を指定するとか・・・
また、出現頻度が高い順に得られていると、少ないループで処理できると思います。

「文字」は１文字長しかない場合、以下の様な記述でも良いのかも・・・
（クエリに変更はありません）

Public Function DicCheck(vSrc As Variant) As Boolean
　　Dim sS As String
　　Dim i As Long

　　DicCheck = True
　　If (dic Is Nothing) Then Exit Function
　　If (dic.Count = 0) Then Exit Function
　　sS = vSrc & ""
　　For i = 1 To Len(sS)
　　　　If (Not dic.Exists(Mid(sS, i, 1))) Then Exit Function
　　Next
　　DicCheck = False
End Function

> キャッシュに展開せずに、DicCheck　だけを実行する形に
> 変えようとしていますが、うまく修正できません。

＃２での 削除する（Replace を使う）方法で毎回レコードセットを得るものにすると
（DAO での例になります）

Public Function DicCheck(vSrc As Variant) As Boolean
　　Dim rs As DAO.Recordset
　　Dim sS As String

　　DicCheck = True
　　sS = vSrc & ""
　　Set rs = CurrentDb.OpenRecordset("許可文字一覧")
　　Do While (Not rs.EOF)
　　　　sS = Replace(sS, rs("文字"), "")
　　　　If (Len(sS) = 0) Then Exit Do
　　　　rs.MoveNext
　　Loop
　　rs.Close
　　Set rs = Nothing
'　　sS = Trim(sS)
　　If (Len(sS) = 0) Then DicCheck = False
End Function

の記述だけで、クエリは

SELECT * FROM データ一覧 WHERE DicCheck(名称);

でいけると思います。

「文字」が１文字長しかなかった場合は、FindFirst で検索し、
NoMatch で判断する等いろいろ考えられると思います。

> 許可文字数が150字程度と少ないので
> キャッシュに展開しない方法をご教授いただけないでしょうか。

おそらく、
処理スピードは許可文字の件数ではなく、「名称」の件数に大きく左右されると思います。
（「名称」の件数がどれだけかわかりませんが、１件ごとに OpenRecordset するので・・・）
環境にあった速い方法を見つけられたらと思います。
（Dictionary 展開が速い・・・・　わかりません）

お礼

お礼が遅くなり申し訳ありません。
ライブラリを追加してキャッシュに展開するロジックを
活用させていただきました。

何度も丁寧な回答をありがとうございました。