エクセルマクロ 最終行ではなく途中行を検索したい

質問

よろしくお願いします。

今現在、どこからかの流用で、下記のように3(C)列の3行目から最終行まで
入力する形にしていますが、最終行ではなく(1)途中の空白、若しくは(2)指定の
行がある場合、又は(3)罫線が引かれている所まで　はどのように書き換えれば
よいでしょうか？
※(1)、(2)、(3)のそれぞれの場合で回等頂ければと思います。

Dim LastRow As Integer
LastRow = Cells(Rows.Count, 3).End(xlUp).Row

For p = 3 To LastRow

Cells(p, 2).Select
ActiveCell.FormulaR1C1 = p - 2 '開始位置の2行ズレ分、-2を入力
Next p

回答No.2

keithin · ベストアンサー

sub macro1()
’C3から下向けに調べて最初に来た空白セルの一つ前の行まで
　dim r as long
　r = 3
　do
　　cells(r, "B") = r - 2
　　r = r + 1
　loop until cells(r, "C")= ""
end sub

＃Ｃ３セルからend(xldown)を使う方法は，Ｃ列の（詳しくはＣ３，Ｃ４，Ｃ５セルの）データの入り具合によって動作が不安定なのでお奨めしません

sub macro2()
’Ｃ３から「指定の行」まで
　dim r as long
　dim StopRow as long

　stoprow = 22

　for r = 3 to stoprow
　　cells(r, "B") = r - 2
　next r
end sub

sub macro3()
’Ｃ３から「罫線表の範囲内」
’簡易手法
　dim r as long
　dim LastRow as long
　lastrow = cells.specialcells(xlcelltypelastcell).row

　for r = 3 to lastrow
　　cells(r, "B") = r - 2
　next r
end sub

sub macro3r1()
’Ｃ３から「罫線表の範囲内」
’簡易手法がツカエナイ場合はmacro1のバリエーション
　dim r as long
　r = 3
　do
　　cells(r, "B") = r - 2
　　r = r + 1
　loop while cells(r, "C").borders(xledgebottom).linestyle = xlcontinuous
end sub

お礼

素早い回答ありがとうございました。
色々試し、少し難関もありましたが、うまくいきました！！

教えて頂いての事ですが、また少し上達しそうです。
用例３つともお応え頂き、感謝致します。

補足

＞データの入り具合によって動作が不安定

助言ありがとうございます。
エラーを沢山経験したいので、今後確認しながら試してみます。

回答No.1

mu2011

一例です。
For文直後で判定しては如何でしょうか。

If Cells(p, 3) = "" Or _
p >= 行数 Or _
Cells(p, 3).Borders(xlEdgeBottom).LineStyle <> xlNone Then Exit Sub

尚、罫線はセル下線部の有無を判定しています。

お礼

素早い回答ありがとうございました。
色々試しましたが、私のシートとの相性が良くないようで
エラーは出ませんでしたがうまくいきませんでした。
あまり時間がありませんので余裕ができました時に
別のパターンで試してみたいと思います。

次回の質問時にもお応え頂ければ嬉しいです。
ありがとうございました！