１００種類の画像をランダムに読み込みたい(AS2)

質問

• １００種類の画像をランダムに読み込み、表示できるスクリプトを作成したいです。また、読み込みが遅くなる場合の解決方法も教えてください。
• 現在、１００枚の画像ファイルが連番でimgフォルダに保存されています。また、URLはLink.asに記述されています。
• AS2とFlash Player８を使用していますが、初心者のため苦戦しています。ご教授いただけると幸いです。

回答No.2

BlurFiltan · ベストアンサー

＃１です。

> 100枚の画像から100枚をランダムな順にチョイスしたい
> と考えています。（ページを開くたびに順番は変わる）
> 重複についてはしても大丈夫です。

と言うことでしたら
次のようにすれば良いのではないかと思います。

//-------------------------------------------
import mx.transitions.Tween;
import mx.transitions.easing.*;

var num:Number = 10;

//最高数字の設定(「img/p100.jpg」まであった場合)
var max_num:Number = 100;

var bar_h:Number = 200;
var bar_w:Number = 150;
var bar_n:Number = 10;
var margin:Number = 0;
var lag:Number = 1000;
var speed:Number = 1;

var transMode:Boolean = true;

//setInterval参照用IDの宣言
var ID:Number;

//ランダムな整数を入れる変数rの宣言
var r:Number;

//ロード監視用にするObjectインスタンス「obj」を作成
var obj:Object = new Object();

//MovieClipLoaderインスタンス「mcl」を作成
var mcl:MovieClipLoader = new MovieClipLoader();

//カウンタの初期化
var cnt:Number = 0;

//JPEGロード完了時の動作定義
obj.onLoadInit = function(target:MovieClip):Void {
cnt++;
if (cnt == 10) {
ID = setInterval(bar_trans, lag);
}
};

//「mcl」のリスナーとして「obj」を登録
mcl.addListener(obj);

for (i=1; i<=num; i++) {
mc = this.createEmptyMovieClip("p"+i, i);
mc.createEmptyMovieClip("inner", i);
//r に 1～max_num のランダムな整数を代入
r = Math.floor(Math.random()*max_num)+1;
//ランダムな外部JPEGをロード
mcl.loadClip("img/p" + r + ".jpg", mc.inner);
mc._x = margin+(bar_w+margin)*(i-2);
mc._y = 0;
mc._alpha = 100;
//mc内の変数nにrを代入
mc.n = r;
mc.onRollOver = rollover;
mc.onRollOut = rollout;
mc.onRelease = releas;
}

function rollover() {
this._alpha = 100;
transMode = false;
}

function rollout() {
this._alpha = 100;
transMode = true;
}

function releas() {
transMode = true;
url = _root["link"+this.n];
getURL(url);
}

function bar_trans() {
if (transMode) {
for (i=1; i<=num; i++) {
bar_mc = _root["p"+i];
bar_mc.x0 = bar_mc._x;
if (bar_mc.x0>margin+(margin+bar_w)*(num-3)) {
bar_mc._visible = false;
bar_mc.targetx = -bar_w;
//r に 1～max_num のランダムな整数を代入
r = Math.floor(Math.random()*max_num)+1;
//ランダムな外部JPEGをロード
bar_mc.inner.loadMovie("img/p" + r + ".jpg");
//bar_mc内の変数nにrを代入
bar_mc.n = r;
} else {
bar_mc._visible = true;
bar_mc.targetx = margin+bar_w+bar_mc.x0;
}
myTween(bar_mc);
}
}
}

function myTween(bar_mc) {
new Tween(bar_mc, "_x", Regular.easeOut, bar_mc.x0, bar_mc.targetx, speed, true);
}

#include "Links.as"
//-------------------------------------------

お礼

具体的なコードを教えていただいて、ありがとうございます。
無事理想的なもの作成することができました。

本当にありがとうございました！