FLASHの表現方法(Actionscript)についての質問です。

質問

FLASHの表現方法(Actionscript)についての質問です。

http://www2.nissan.co.jp/EVENT/ECOMARCH2010/index.html?scnisid=r20100630nis000000701
ここのサイトのトップにあるような「ボヨン」というか「プルン」というか・・・
一瞬大きくなって少しバウンド?しながら元の大きさに戻る表現方法が知りたいです。

当方の環境はWindows XP + FLASH 8ですので、それで作れるように(FLASH初心者なので、若干丁寧に(^^;))教えて頂けるとありがたいです。

回答No.1

BlurFiltan · ベストアンサー

> FLASHの表現方法(Actionscript)についての質問

Actionscript と書かれていますが
「作成が手間」 とか 「動的な使い回がしにくい」 などの理由を除けば
動き自体は ActionScript ではなくて
カスタムイージング を使った モーショントゥイーン で作成できますよね。
というか...
あくまでも動き方のみを見た場合
モーショントゥイーン そのものっぽく見えます。

※もし以上で書いている内容がわからない場合は
　 「カスタムイージング モーショントゥイーン」などと
　 Google で検索してみてください。
　 ヒットするページ例↓
http://openflash.org/jp/designcenter/dialogbox/achieveamazingeffects/

ですから
何らかの理由があって ActionScript で動かす場合も
Tween クラス系のアクションを利用すれば良いと思います。

===以下は具体的な作成方法です===

ステージ上に適当な大きさの ● でも描きます。
その ● をムービークリップに変換しますが
そのときに "基準点" を "中央" にして変換します。

その ムービークリップ● に
例えば 「circle_mc」 というインスタンス名を付けます。
(シンボル名 ではなく インスタンス名)

その「circle_mc」が登場するフレームに記入(コピペ)↓

------------
//Tweenクラスとeasingクラスのインポート
import mx.transitions.Tween;
import mx.transitions.easing.*;

//最初だけcircle_mcを小さくしておく
circle_mc._xscale = 20;
circle_mc._yscale = 20;

//関数 setTween を定義(引数:対象MC,拡大秒数)
function setTween(target:MovieClip, sec:Number) {
//対象MCに対する横方向拡大のTweenを作成
var t_xscale1 = new Tween(target, "_xscale", Regular.easeIn, target._xscale, 125, sec, true);
//対象MCに対する縦方向拡大のTweenを作成
var t_yscale1 = new Tween(target, "_yscale", Regular.easeIn, target._yscale, 125, sec, true);
//
//拡大Tween終了時のイベントハンドラメソッドを定義
t_xscale1.onMotionFinished = function() {
//対象MCに対する横方向縮小のTweenを作成
var t_xscale2 = new Tween(target, "_xscale", Elastic.easeOut, target._xscale, 100, 1.5, true);
//対象MCに対する縦方向縮小のTweenを作成
var t_yscale2 = new Tween(target, "_yscale", Elastic.easeOut, target._yscale, 100, 1.5, true);
};
}

//関数setTweenを実行(引数:対象MC,拡大秒数)
setTween(circle_mc, 0.4);

//setTweenを4000ミリ秒間隔で実行 引数:対象MC,拡大秒数
var id:Number = setInterval(setTween, 4000, circle_mc, 0.15);
------------

※Flash MX 2004 以降(Flash 8 も含む)で使用可
　 Flash Player 6 以上パブリッシュで閲覧可
　 ActionScript 2.0

考え方は次のようなイメージになっています↓

お礼

丁寧なお返事をありがとうございました。
早速やってみます!!
また、結果は報告させて頂きます。
取り急ぎ。

補足

http://www.tomato.gr.jp/test/test_bcat.html
出来ました!!!!
ただ、大きくなった時に画像が荒れてしまうのは、これはもうどうしようもないんでしょうか・・・(T△T)