VBAか関数で「２と３の組合せ」の行数を算出する方法

質問

• VBAか関数で「２と３の組合せ」の行数を算出する方法について教えてください。
• 質問の例では、答えは3行となりますが、存在しない場合は0行になります。
• 他にも「１と３の組合せ」や「*と*の組合せ」などの行数も算出できるので、教えていただけますか？

回答No.5

jcctaira

VBAでユーザ関数を作成して見ました。

【基本的使用例】
=組み合わせ件数(C7:E13,2,3)

【VBA】
Function 組み合わせ件数(範囲 As Range, ParamArray 検索値())
　Dim マッチセル As Range
　Dim マッチ集合行 As Range
　Dim セル As Range

　組み合わせ件数 = 0
　If UBound(検索値) < 0 Then Exit Function
　For I = 0 To UBound(検索値)
　　　For Each セル In 範囲
　　　　　If セル = 検索値(I) Then
　　　　　　　If マッチセル Is Nothing Then Set マッチセル = セル
　　　　　　　Set マッチセル = Union(マッチセル, セル)
　　　　　End If
　　　Next
　　　If マッチセル Is Nothing Then Exit Function
　　　If I = 0 Then Set マッチ集合行 = マッチセル.EntireRow
　　　Set マッチ集合行 = Intersect(マッチ集合行.EntireRow, マッチセル.EntireRow)
　　　Set マッチセル = Nothing
　Next I
　組み合わせ件数 = Intersect(マッチ集合行, Columns(1)).Count
End Function

【蛇足】
関数は汎用的に作成していますので…
・検索値を任意の個数で指定できます。
　=組み合わせ件数(C7:E13,1)
　=組み合わせ件数(C7:E13,1,2,3)
・検索範囲を任意な範囲で指定できます。
　=組み合わせ件数(C7:Z13,1,2,3,4)
　=組み合わせ件数((C7:C14,D7:D14),1)

良ければ試してみて下さい。

お礼

早速のご回答、ご詳細、誠に有難うございました。
1,2,3,4　にも対応できるのですね！
自分には高レベルなコードかもしれませんが、
がんばって、使用させて頂きます。