Excel VBA で二つのシートを比較して合致するレコードを別のシー

質問

Excel VBA で二つのシートを比較して合致するレコードを別のシートに抽出する方法

全然詳しくはありません。

やりたいこととしては、fax1,fax2,fax3のシートがありまして、

fax1：a列にfax_id
fax2：fax1同様に、c列にfax_id

のようなExcelのデータがあります。

ここから、fax1のシートのidを一つ一つ読み込みながら、fax2のidと比較して、合致したらfax3シートにコピーするようなプログラムを作りたいです。

やり方はいろいろあるみたいなのですが、どうしても下記の記述をベースに作ってみたいのですが、単純にfax1からfax3にコピーするのはわかるのですが、ここから先がよくわかりません。

基本的なことで申し訳ないのですが、どなたかご教授いただけませんでしょうか。

よろしくお願いいたします。

Public Sub copy()

Dim tempRange As Range
Dim fax1Table As Range
Dim fax2Table As Range
Dim dst As Range

'fax1範囲指定
Worksheets("Fax1").Activate
Set fax1Table = Range("a1").CurrentRegion
Set fax1Table = fax1Table.Offset(1)
Set fax1Table = fax1Table.Resize(fax1Table.Rows.Count - 1)

'fax2範囲指定
Worksheets("Fax2").Activate
Set fax2Table = Range("a1").CurrentRegion
Set fax2Table = fax2Table.Offset(1)
Set fax2Table = fax2Table.Resize(fax2Table.Rows.Count - 1)

'比較開始
Worksheets("fax1").Activate

'見出しコピー
Set dst = Worksheets("fax3").Range("a1")
Range("a1:g1").Copy dst

'レコード抽出
For Each tempRange In fax1Table.Rows
Set dst = dst.Offset(1)
tempRange.Copy dst
Next

'比較終了

'セル幅自動調整
Worksheets("fax3").Range("a:g").Columns.AutoFit
Worksheets("fax3").Activate
End Sub

回答No.1

myRange · ベストアンサー

抽出部分だけのコードです。。。

'----------------------------------------
'●スピードが速い（FINDメソッド使用）

Dim FoundCell As Range

For Each tempRange In fax1Table.Rows
　　Set FoundCell = fax2Table.Columns(3).Find(tempRange.Columns(1).Value, , xlValues, xlWhole)
　　　　If Not FoundCell Is Nothing Then
　　　　　　Set dst = dst.Offset(1)
　　　　　　tempRange.copy dst
　　　　End If
Next tempRange
'--------------------------------

●スピード遅い（Fax2TableのＣ列をひとつずつ全て比較するので）

　Dim Fax2C As Range

For Each tempRange In fax1Table.Rows
　　For Each Fax2C In fax2Table.Columns(3).Cells
　　　　If tempRange.Columns(1).Value = Fax2C.Value Then
　　　　　　Set dst = dst.Offset(1)
　　　　　　tempRange.copy dst
　　　　　　Exit For
　　　　End If
　　Next Fax2C
Next tempRange
'----------------------------------------

このような処理では、Activateの必要はありませんので
実際のコードではそこらあたりに考慮したコードにした方がいいでしょう。
以上です。

お礼

ありがとうございました。

教えていただきました考え方で意図したことができるような動きになってます。

一つ一つみていくと数千件あるデータの場合、かなり遅くなるんですね。

ただ、コピーはされるのですが、なんでかレコードの途中までしかデータがコピーされなくて、もう少し考えてます。ちょっとお待ちください。

補足

お世話になっております。

返信が遅くなりましてすみません。

まだつっかかっているのと、閉じてしまったらやり取りができなくなってしまうのかと思って、まだ閉じていませんでした。

ここまで教えてもらったので、ここから先は自分でとおもってまして。
もう少しだけまっててもらえませんでしょうか。

よろしくお願いいたします。