Excel 年間スケジュール表作成

質問

新年度に向けてスケジュール表を
作成しています。
週単位で予定を管理したいと考えているのですが、
その週の初めの日付を記載したいと考えています。
簡単に一括で記入できる方法を教えて頂きたいのですが？

　　　　　　　4月
1週目　2週目　3週目　4週目　5週目
4/1　　4/4　　4/11　　4/18　4/25

上記のように1週目の初日から7日後が必ずしも
2週目の始まりではないのでどのように入力すれば
いいのかわからず困っています。
よろしくお願いします。

回答No.4

tom04 · ベストアンサー

こんばんは！
すでに色々回答は出ていますので・・・
参考程度で目を通してみてください。

↓の画像のようにA1セルに「年」・C1セルに「月」を入力します。

1週目は必ず1日になりますので
A4セルは
=DATE(A1,C1,1)
そして、B4セルに
=IF(MONTH(A4+(8-WEEKDAY(A4)))=$C$1,A4+(8-WEEKDAY(A4)),"")
という数式を入れ、列方向にオートフィルでコピーすると
画像のような感じになります。
（エラー処理はしていません）

以上、参考になれば幸いです。m(__)m

回答No.3

hallo-2007

仮に
A　　B　　C
年　2010　
月　　4
1週目　2週目
と　B1セルに年、B2セルに月を入れている　として
A4セルには、その年月の1日の日付　=DATE(B1,B2,1)
B4セルには、その年月の最初の日曜日の日付　=A4-WEEKDAY(A4-1)+7
C4セルには、更に7日後の日付　=B4+7
D4セルには、更に7日後の日付　=C4+7
・・といった具合になります。

回答No.2

keithin

あなたが言いたかった事は，次のどちらですか？

ケース１（ご質問に書いてあること）
あるA1セルにある月(例えば４月)の１日の日付を4/1のように入れるので，「その月の日曜日の日付」がつるつるっと計算できるようにしたい

=IF(MONTH(A1)<>MONTH(A1+7),"",A1-WEEKDAY(A1+7)+8)
と入れて，あと４週分コピーしておく。

ケース２（ご質問に書いてないこと）
あるA1セルにカレンダーの最初の日付(例えば4/1）を入れるので，その後の日曜日の日付と，更に月が変わったら忘れずに月の１日の日付も計算するようにしたい

=IF(MONTH(A1+7)=MONTH(A1),A1+8-WEEKDAY(A1+7),A1+8-DAY(A1+7))
と入れて，沢山コピーしておく。

回答No.1

SIMM2008

ロジックとしては、
A.まず、第1週は、その月の1日目　　---------> 例) 4月なら、4/1
B.2週目は、1の日付に7日を足す(4/1 + 7 = 4/8)。
C.weekday関数で、Bの曜日を求める ----> weekday(4/1 + 7 ,1)=5
(日曜日-->1、月曜-->2、火曜-->3、・・・、土曜-->7)
D.Cの数値を1つだけ減らす--> weekday(4/1 + 7, 1) - 1
(日曜日-->0、月曜-->1、火曜-->2、・・・、土曜-->6)
E.Bの日付から、Dの日数を引く。---> 4/1 + 7 - (weekday(4/1 + 7, 1) - 1) = 4/4
　これで、2周目の最初の日が求まりました。これは常に日曜日です。
F.3週目以降は、前週の日付に7を足す。

まとめると、
西暦=A1、月=B1、
1週目の初め=A2、2週目の初め=B2、3週目の初め=C2、4週目の初め=D2、5週目の初め=E2。

とすると、n月の値は、

A2=date(A1,B1,1)、B2=A2 + 7 - (weekday(A2 + 7, 1) - 1)、C2=B2+7、D2=C2+7、E2=D2+7

いががでしょう。