EXCEL 2003 5・4をＡ ３をＢ ２・１をＣと表す方法

質問

ＥＸＣＥＬ２００３　初心者です。
よろしくお願いします。

Ａ１～Ａ３００に１～５までの数字がランダムに入っています。

Ｂ１～Ｂ３００にＡ・Ｂ・Ｃと表示したい。
Ａ列に5・4と書いてある時にＡ
Ａ列に３と書いてある時にＢ
Ａ列に２・１と書いている時にＣと表示したいのですが

Ｂ１にどのような式を入れたらよいのでしょうか
教えてください。

よろしくお願いします。

回答No.2

anju_z · ベストアンサー

No.１です。
ごめんなさい、質問文を読み間違えました。
式を以下のように訂正していただけますか。

=CHOOSE(A1,"C","C","B","A","A")

=IF(A1="","",CHOOSE(A1,"C","C","B","A","A"))

回答No.5

maron--5

◆A,B,Cの3区分ならば
◆こんな方法はいかがでしょう
=IF(A1="","",TEXT(A1-3,"!A;!C;!B"))

回答No.4

imogasi

典型的なVLOOKUP（TRUE型）の問題です。
E1:F3に段階別索引表を作ります。実はデータの在る列以外何処の範囲でも良い。
E劣　　F劣
0 C
3 B
4 A
B1に　=VLOOKUP(A1,$E$1:$F$3,2,TRUE)
IF関数やChoose関数に比べ、区間が増えたときも、式の長さが余り変わらない。
本件はA列に離散的な整数しか入らないようなので、VLOOKUP関数の
FALSE型でも出来る。
検索表は、
１C
２C
３B
４A
５A
のように作る。第４引数はFALSE。
G列　　H列
1 C
2 C
3 B
4 A
5 A
=VLOOKUP(A1,$G$1:$H$5,2,FALSE)
ーー
A列空白の場合Cになるのを防ぐには
=IF(A1="","",VLOOKUP(A1,$E$1:$F$3,2,FALSE))
ーーー
A列が整数の場合
ほかに=MID("CCBAA",A1,1)などでも出来る。

回答No.3

KURUMITO

次のような式をＢ1セルに入力して下方にオートフィルドラッグします。
ご質問の内容をそのまま式にしています。

=IF(OR(A1=4,A1=5),"A",IF(A1=3,"B",IF(OR(A1=1,A1=2),"C","")))

回答No.1

anju_z

=CHOOSE(A1,"A","A","B","C","C")
です。

しかしこれではA列に数値が入っていないとエラーが出ますので、
それを避けるためにIF関数で「空白の場合は空白を返す」と指定します。
=IF(A1="","",CHOOSE(A1,"A","A","B","C","C"))