複数条件にあったセルの個数

質問

以下のような月別のお天気表で
算出したい条件は例えば”6月”かつ”雨”のセルの数です。
答えは３なわけですが、どのような式で求めたらいいのかご教示頂きたいのです。
よろしくお願いいたします。

　　A 　　B 　 C 　D　 E　 F
1　4月　晴　晴　雲　雨　雲
2　5月　雨　晴　晴　雲　晴
3　6月　曇　雨　雨　雲　雨
4　7月　雲　晴　晴　晴　雲
5　・
6　・
7　・

回答No.3

noname#204879 · ベストアンサー

=SUMPRODUCT((A1:A100="6月")*(B1:F100="雨"))
または
{=SUM((A1:A100="6月")*(B1:F100="雨"))} ← 配列数式

お礼

なるほどという仕組みでした。
解決にたどりつきました。
何度もありがとうございました。

回答No.4

imogasi

例データＡ１：Ｆ５
A B C D E F
4月 晴 晴 雲 雨 雲
5月 雨 晴 晴 雲 晴
6月 曇 雨 雨 雲 雨
7月 雲 晴 晴 晴 雲
例えば
Ｄ１０：Ｄ１３に
4月
5月
6月
7月
と入れておく
ーー
Ｅ１０に　=SUMPRODUCT((A2:A5=D10)*(B2:F5="雨"))*1
式をＥ１３まで複写
結果　月ごと、雨のセル数
4月 1
5月 1
6月 3
7月 0

お礼

とても参考になりました。
ご親切にありがとうございました。

回答No.2

mu2011

一例です。
=COUNTIF(OFFSET($A$1,MATCH("6月",$A$1:$A$10,0)-1,1,1,5),"雨")

お礼

OFFSETに出会う事がなかったので式の内容を解くのが難しそうですがよく勉強してみようと思います。
ありがとうございました。

回答No.1

noname#204879

A　 B　 C　 D　 E　 F　 G　H　 I　 J　 K
1　　　　　　　　　　　　　　　晴　雲　雨　曇
2　4月　晴　晴　雲　雨　雲　　　2　 2　 1　 0
3　5月　雨　晴　晴　雲　晴　　　3　 1　 1　 0
4　6月　曇　雨　雨　雲　雨　　　0　 1　 3　 1
5　7月　雲　晴　晴　晴　雲　　　3　 2　 0　 0
6　…　 …　…　…　…　…　　 …　…　…　…

H2:=COUNTIF($B2:$F2,H$1)

お礼

質問の仕方が悪かったようです。
A列から6月を探して見つかった場合にその行内に雨がいくつあるかを算出させる計算式をお聞きしたかったのです。

頂いた回答の意味がちょっとわかりませんでしたが
ご親切にご回答いただきありがとうございました。