VBAFontStyle取得について

質問

お世話になります。

エクセルVBAでのFontStyle取得についてお聞きします。
ある行に対して太字にする作業を行った後に、太字にされたことを確認するために、

FontStyle = "太字"

で取得FontStyleを取得したいのですが、
行の中の一つでも太字になっていない場合、エラーになってはじかれてしまいます。
試しに取得をしてみたのですが、　Null　と表示されました。
目的のものが取得できないのであれば、エラーの処理に移動させたいのですが、
こういった行や列に対する場合というのは、やはりループで回して一つ一つ確かめるしか方法がないのでしょうか？
ループを使わずに処理をする方法などがありましたら、ぜひともご指導をお願いしたく思います。

よろしくお願いいたします。

回答No.1

vba_2007 · ベストアンサー

セル１つ１つをチェックする必要があれば、ループでまわす必要があると思います。

指定の範囲が全て、太字かどうか。という状況だけ
チェックしたいのであれば、IsNull()で確認すればどうでしょう。

ただし、罫線のチェック等になると、逆に、全てが指定の罫線で
なくてもTrueになることがありますので、このような場合は、
やはりループでまわすしかないと思われます。

回答No.2

KenKen_SP

こんにちは。

> ループを使わずに処理をする方法

規定のメソッドやプロパティーで対応できないことであれば、ループ
処理は必須です。
したがって、「ループを使わずに処理をする」ではなく、いかに効率的に
ループに処理をするかという点で回答してみます。

Excel2002 以降に限定されますが、FindFormat を使ってみては？

' // フォントが太字に設定されているセルを検索して選択する
Sub Sample()

　　Dim r　　　　　As Range
　　Dim rFound　　 As Range
　　Dim sFirstAddr As String

　　With Application.FindFormat
　　　　.Clear
　　　　.Font.Bold = True
　　End With

　　Set r = Cells.Find(What:="", _
　　　　　　　　　　　 LookIn:=xlValues, _
　　　　　　　　　　　 LookAt:=xlPart, _
　　　　　　　　　　　 SearchOrder:=xlByRows, _
　　　　　　　　　　　 SearchFormat:=True)
　　If r Is Nothing Then
　　　　MsgBox "該当なし"
　　Else
　　　　Set rFound = r
　　　　sFirstAddr = r.Address
　　　　Do
　　　　　　Set rFound = Union(rFound, r)
　　　　　　' FindNext は使わない XL2002 対策
　　　　　　' http://support.microsoft.com/kb/282151/ja
　　　　　　Set r = Cells.Find(What:="", _
　　　　　　　　　　　　　　　 After:=r, _
　　　　　　　　　　　　　　　 SearchFormat:=True)
　　　　Loop Until r Is Nothing Or r.Address = sFirstAddr
　　　　If Not rFound Is Nothing Then
　　　　　　rFound.Select
　　　　End If
　　End If

End Sub