Excelの複数シートからcsvファイルを出力

質問

Dim objXL
Dim f
Dim m
Dim ws

Set objXL=CreateObject("Excel.Application")

'objXL.Visible=True

objXL.DisplayAlerts=False

For Each f In WScript.Arguments
objXL.WorkBooks.Open f
For Each ws In objXL.ActiveWorkBook.Worksheets
If ws.UsedRange.Rows.Count=1 and ws.UsedRange.Columns.Count=1 and ws.Cells(1,1)="" Then
'MsgBox ws.Name&"Empty"
Else
ws.SaveAs f & "." & ws.Name & ".csv", 6
End If
Next
objXL.ActiveWorkBook.Close
Next

objXL.Quit
WScript.Quit

上記スクリプトファイルで
ファイル名が「[元Excelファイル名].[シート名].csv」
のcsvファイルが出力されますが、これを
ファイル名を「[シート名].csv」にするには
どのようにすればいいのでしょうか。

ws.SaveAs f & "." & ws.Name & ".csv", 6
の箇所を
ws.SaveAs ws.Name & ".csv", 6
に変更したのですが、うまくいきませんでした。

回答No.3

n-jun · ベストアンサー

＃１＆２です。

Dim objXL
Dim f
Dim m
Dim ws

Set objXL=CreateObject("Excel.Application")

'objXL.Visible=True

objXL.DisplayAlerts=False

For Each f In WScript.Arguments

objXL.WorkBooks.Open f

For Each ws In objXL.ActiveWorkBook.Worksheets
If ws.UsedRange.Rows.Count=1 and ws.UsedRange.Columns.Count=1 and ws.Cells(1,1)="" Then
'MsgBox ws.Name&"Empty"
Else
ws.SaveAs objXL.ActiveWorkBook.Path & "\" & ws.Name & ".csv", 6
End If
Next
objXL.ActiveWorkBook.Close
Next

objXL.Quit
WScript.Quit

こっちの方がわかりやすいかも。

お礼

出来ました！！！！！！！！！！！！！！！
ありがとうございます

回答No.2

n-jun

＃１です。

＞ws.SaveAs path & "." & ws.Name & ".csv", 6
ws.SaveAs path & ws.Name & ".csv", 6
もしかしてこっちかな？

補足

残念ながらどちらも駄目でした．．．

回答No.1

n-jun

Dim objXL
Dim f
Dim m
Dim ws
Dim path

Set objXL=CreateObject("Excel.Application")

'objXL.Visible=True

objXL.DisplayAlerts=False

For Each f In WScript.Arguments

objXL.WorkBooks.Open f
path = Replace(f ,objXL.ActiveWorkBook.Name , "" )

For Each ws In objXL.ActiveWorkBook.Worksheets
If ws.UsedRange.Rows.Count=1 and ws.UsedRange.Columns.Count=1 and ws.Cells(1,1)="" Then
'MsgBox ws.Name&"Empty"
Else
ws.SaveAs path & "." & ws.Name & ".csv", 6
End If
Next
objXL.ActiveWorkBook.Close
Next

objXL.Quit
WScript.Quit

パスがないからうまくいかないとか？