特定のワークシートcsvファイル書き出しほか

質問

エクセルブックの中身が、
1番目 graphシート
2番目から19番目 ワークシート
で構成されているエクセルファイルが100個
AAAというフォルダに入っています。
それぞれのエクセルブックにあるシートを、ブックのファイル名にしたフォルダを作成し、その中にcsvで書き出すプログラムを作りました。
また、AAAのフォルダの１つ上のフォルダ（VBA実行するカレントフォルダ）には、テキストファイルもあり、作成されたフォルダに合わせてコピーするようにしています。

一応、期待通りの動作をしましたが、スッキリとしたプログラムとするために、アドバイスをいただけないでしょうか？

また、できれば、それぞれのブックの2番目から7番目のワークシートのみをcsvファイルで書き出したいと思い、シートを2番目から順にアクティブにして書き出すように変更しても1番目のグラフシートからcsvになってしまいました。
特定のワークシートのみをcsvファイルで書き出すにはどのように書いたら良いでしょうか？

よろしくおねがいしむす

Sub ファイル一括作成()

    Application.ScreenUpdating = False

        '対象ブックの選択
    'フォルダ内のブックを順次選択
    Dim FolderPath As String
    Dim objFSO As Object
    Dim objBook As Object
    Dim objFiles As Object
    Dim objFile As Object
    Dim mysma4 As Object

    Set objFSO = CreateObject("Scripting.FileSystemObject")

    FolderPath = ActiveWorkbook.Path & "\AAA"
    Set objBook = objFSO.GetFolder(FolderPath)
    Set objFiles = objFSO.GetFolder(FolderPath).Files
    Set mysma4 = objFSO.GetFile(ActiveWorkbook.Path & "\fig_all.TXT")

    For Each objFile In objFiles
     If objFSO.GetExtensionName(Path:=objFile) Like "xlsx" Then

    'ベースファイル名フォルダ作成&sma4ファイルコピー
      objFSO.CreateFolder Path:=FolderPath & "\" & objFSO.GetBaseName(objFile)
      mysma4.Copy Destination:=FolderPath & "\" & objFSO.GetBaseName(objFile) & "\fig_all.TXT"

    '各ファイルcsv書き出し

     Workbooks.Open objFile.Path

      For Each ws In Worksheets '各シートに対して処理を繰り返す

          ws.Activate

          'ベースファイルと同じ階層に出力
          ActiveWorkbook.SaveAs _
          Filename:=FolderPath & "\" & objFSO.GetBaseName(objFile) & "\" & ws.Name & ".csv", _
          FileFormat:=xlCSV

      Next ws

      ActiveWorkbook.Close SaveChanges:=False

     Else
     End If
    Next

    MsgBox "ファイル作成が完了しました。"

    Set objFSO = Nothing
    Set objBook = Nothing
    Set objFiles = Nothing
    Set mysma4 = Nothing

    Application.ScreenUpdating = True

End Sub

回答No.2

watabe007 · ベストアンサー

>シートを2番目から順にアクティブにして書き出すように変更しても
>1番目のグラフシートからcsvになってしまいました。
For Each ws In Worksheets でループしているのでWorksheetsからは
グラフシートは取得できないのだけどWorksheetに埋め込みグラフかな？
For Each ws In Worksheets
　　If ws.Index >= 2 And ws.Index <= 7 Then
　　　　ws.Activate
　　　　ActiveWorkbook.SaveAs _
　　　　Filename:=FolderPath & "\" & objFSO.GetBaseName(objFile) & "\" & ws.Name & ".csv", FileFormat:=xlCSV
　　End If
Next ws

お礼

回答ありがとうございました
ご指摘の通り埋め込みグラフでした。
回答頂いた内容でやりたい動作できました。
ありがとうございました

回答No.1

HohoPapa

ws.Activate
'ベースファイルと同じ階層に出力
ActiveWorkbook.SaveAs _
Filename:=FolderPath & "\" & objFSO.GetBaseName(objFile) & "\" & ws.Name & ".csv", _
FileFormat:=xlCSV

↑これらのコードを

if ((ws.Type <> xlChart) And (ws.Index < 8)) Then
　'xxxxxxxxx
End If

で挟む対応はいかがでしょうか。

お礼

回答ありがとうございます
動作しましたが、私の質問内容に間違いがあり、2人目のwatabe007さまのご指摘の通り、埋め込みグラフでした。申し訳ありません。

xlchartで分けること初めて知りました。
非常に勉強になりました。
ありがとうございました