ユーザーフォームの結果を

質問

お世話になります。
下記の様な記述の
ユーザーフォームで、
テキストボックスを３つ設け、それぞれに
年、月、日を入力し、その値を
シートのあるセルに表示したいのですが、
例えば、月や日が一桁の場合には最初に「０」を
付けたいのですが、うまくいきません。
何卒、ご教示下さいます様お願い申し上げます。

　　　　　　記

Private Sub UserForm_initialize()
SpinButton1.Max = 2050 ' 初期設定
SpinButton2.Max = 12
SpinButton2.Min = 1
SpinButton3.Max = 31
SpinButton3.Min = 1

SpinButton1.Value = Year(Date)
SpinButton2.Value = Month(Date): If month_mm < 10 Then month_mm = "0" & month_mm
SpinButton3.Value = Day(Date): If day_dd < 10 Then day_dd = "0" & day_dd

End Sub
Private Sub SpinButton1_Change()
Call DAY_PUT
End Sub

Private Sub SpinButton2_Change()
Call DAY_PUT
End Sub

Private Sub SpinButton3_Change()
Call DAY_PUT
End Sub
Sub DAY_PUT()

TextBox1.Value = SpinButton1.Value
TextBox2.Value = SpinButton2.Value
TextBox3.Value = SpinButton3.Value

End Sub
Private Sub CommandButton1_Click()

tbox1 = TextBox1.Value
tbox2 = TextBox2.Value
tbox3 = TextBox3.Value

Workbooks("集計表").ActiveSheet.Range("a1") = tbox1 & tbox2 & tbox3

Unload Me

End Sub

回答No.2

redfox63 · ベストアンサー

初期設定時には2桁に整形していますが、スピンボタンで変更した際には整形していないですね

やるなら DAY_PUTプロシージャ側で整形した方がスマートなように思います

Sub DAY_PUT
　　TextBox1.Text = Format(SpinButton1.value, "0000" )
　　TextBox2.Text = Format(SpinButton2.value, "00" )
　　TextBox3.Text = Format(SpinButton3.value, "00" )
End Sub

初期設定時の
SpinButton1.Value = Year(Date)
SpinButton2.Value = Month(Date): If month_mm < 10 Then month_mm = "0" & month_mm
SpinButton3.Value = Day(Date): If day_dd < 10 Then day_dd = "0" & day_dd
を
SpinButton1.Value = Year(Date)
SpinButton2.Value = Month(Date)
SpinButton3.Value = Day(Date)
Call DAY_PUT
してやれば 表示形式を訂正する場合も DAY_PUT側だけいじればいいことになります

セルへの転記ですが 転記したセルの値を 他のセルの数式で日付として扱うのであれば #1の回答のように
DateSerialやDateValue、CDateなどで日付のシリアル値に直してから代入した方がいいでしょう

お礼

大変分かりやすく、且つご丁寧にお教え頂き
ありがとうございました。

回答No.1

imogasi

最終的にエクセルのシートにデータを表示するのだから、エクセルのシートの表示形式の設定を、ユーザー定義の「00」の設置で対処すべきと思う(年月日を３セルに分ける場合）。年月日を１セルに込めてプログラムで、かつプログラムでやる場合は下記コードを参考にすること。
そのとき
＞Workbooks("集計表").ActiveSheet.Range("a1") = tbox1 & tbox2 & tbox3
なんてやるのでなく、
Sub test02()
tbox1 = "2008"
tbox2 = "12"
tbox3 = "23"
Cells(1, 2) = DateSerial(Val(tbox1), Val(tbox2), Val(tbox3))
Cells(1, 2).NumberFormat = "ggge年mm月dd日"
End Sub
を参考に、日付シリアル値でセルにセットし、セルの表示形式で
適当な日付書式にすべきと思う。
このほうが、利用する場合、一般的には役立つ。
ーー
また質問文のコードは、回答に関係ないコードが多すぎる。