【Excel2003】セルの値をクリックで変えたい

質問

標記の通りExcel2003を使用しています。

セルに「□」の文字が入っていて、これをシングルクリックで
「■」の表示に変えるようにしたいのですが、
エクセルの既存の機能でこうしたことは可能でしょうか？
それともVBAの機能を使わないとできませんか？

よろしくお願いします。

回答No.4

Masa2072

チェックボックスとセル値変更との複合です。
指定列を選択したら選択されたセルにチェックボックスを表示
チェックボックスのOn/Offでセルの値を変更
これで擬似的にシングルクリックによる値変更が実現します。
1、Sheet1にチェックボックスを作成し、Visibleの初期値をFalseに設定
２、Worksheetモジュールに以下のマクロを貼り付けます。

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
'#セル選択を変更すると以下のマクロが実行されます
Me.CheckBox1.Caption = ""

If Target.Column = 1 And Target.Cells.Count = 1 Then
'#選択されたセルがA列で、複数セルを選択していない場合は以下を実行
Me.CheckBox1.Left = Target.Left + 10 'CheckBox1の位置を選択セルの左に合わせる（数字は位置調整用、適当に）
Me.CheckBox1.Top = Target.Top + 2 'CheckBox1の位置を選択セルの上に合わせる

'#選択セルの値をCheckBox1に反映
If Target.Value = "■" Then
Me.CheckBox1.Value = True
Else
Me.CheckBox1.Value = False
End If
Me.CheckBox1.Visible = True 'CheckBox1を表示する
Me.CheckBox1.Caption = Target.Address　　'カレントセルのアドレスをCheckBox1の見出しに格納
Else
'#選択セルがA列以外または複数セルを選択した場合はCheckBox1を非表示に
Me.CheckBox1.Visible = False
End If
End Sub

Private Sub CheckBox1_Click()
'#CheckBox1がクリックされたら以下のマクロを実行
'#CheckBox1の見出しに保存されたアドレスのセル（つまりは選択セル)
の値を、チェックボックスの値によって変更する
If CheckBox1.Value Then
Me.Range(CheckBox1.Caption).Value = "■"
Else
Me.Range(CheckBox1.Caption).Value = "□"
End If
End Sub

回答No.3

mshr1962

チェックボックスなら□をレ点付きの□に変えることが出来ます。
もう一度シングルクリックで元に戻りますけどね。
「表示」「ツールバー」から「フォーム」を選んで
レ点付きの□のボタンをクリックしてシート状に配置してください。
□チェック#（#は数値）が貼りつきます。
チェック#の部分をテキスト編集してください。
これ以外だとVBAになりますが、アクションのタイミングは
ダブルクリックかボタンのクリックでしか出来ません。

入力値での切り替えで良いなら、表示形式をユーザー定義で
"■";"■";"■";"□"
だと数値なら■、文字なら□、未入力はブランクになります。
[=1][青]"■";[=2][赤]"■";[黄]"■";"□"
だと1なら青い■、2なら赤い■、1,2以外の数値は黄色い■、文字は□、未入力はブランクになります。

お礼

ご回答有り難うございます。
自分もチェックボックスで対応できれば…と思っていたのですが、
作業の依頼主から黒い塗り潰しの箱にできないかという注文でしたので
VBAは素人ですし頭を悩ませておりました。

今回はアドバイス頂いた内容を活かせませんでしたが、
入力値での切り替えの方法は大変勉強になりました。
今後の機会がありましたら使わせて頂きたいと思います。

お世話になりました！

回答No.2

izmlz

・キーボード操作でセルを移動してもイベントが発生する
・現在選択しているセルをクリックしてもイベントが発生しない

という条件でもよければ↓のマクロになります。なお、クリックするたびに■と□の表示を切り替えるようにしています。シートモジュール（シートタブを右クリック-[コードの表示]）にコピペしてみてください。

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
　Dim c As Range
　For Each c In Target
　　If c.Value = "□" Then
　　　c.Value = "■"
　　ElseIf c.Value = "■" Then
　　　c.Value = "□"
　　End If
　Next
End Sub

　ダブルクリックで表示を変えるようにする、ということでしたら、↓になります。同じくシートモジュールにコピペです。

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
　If Target.Value = "□" Then
　　Target.Value = "■"
　ElseIf Target.Value = "■" Then
　　Target.Value = "□"
　End If
　Cancel = True
End Sub

参考URL：

http://www2.odn.ne.jp/excel/waza/macro.html

補足

ご回答有り難うございます。

考えていたものにかなり近い形で感激しています！
一つ参考に伺いたいのですが、

『・現在選択しているセルをクリックしてもイベントが発生しない』

この条件について、現在選択しているセルをクリックして
イベントを発生させるという方法は難しいのでしょうか？
初歩的な質問で申し訳ありません…。
よろしくお願い致します。

回答No.1

mcsp

おはようございます。
個人的にも非常に興味のある内容ではありますが、左クリックのみでの
イベント発生となると、思い浮かぶのは

　１．ワークシート関数やVBAには実装されていない
　２．Windows API のマウスイベントを利用してみる
　３．もし質問者様の問題が解決したとして、セルの値「□」を修正
　　　しようとした時にマウスの左クリックでそのセルを選択した時
　　　に毎回「■」に変わってしまう(その後に変更は出来るでしょう
　　　けど…)。マウスイベントのON/OFF切替をうまく作らないと
　　　難しそう

という感じがします。
　同様な質問内容が無いかいろいろ検索してみましたが、これといった
ものは見つかりませんでした。答えにはなっていませんが参考URLを
載せておきます(この問題の解決はしていません)。

参考URL：

http://questionbox.jp.msn.com/qa2878695.html?StatusCheck=ON

お礼

早速のご回答有り難うございます。
今回はアドバイスして頂いた内容を活かせませんでしたが、
ご紹介頂きました先も大変勉強になりました。
今後の参考にさせて頂きますね。

お世話になりました！