ExcelVBAで任意のシートの任意のセル範囲を削除する方法

質問

http://okwave.jp/qa1222496.html
こちらのページを参考にやってみたのですが、下記コードの3行目で
「アプリケーション定義またはオブジェクト定義のエラーです」となります

コードは以下のとおりです
－－－－－－－－－－
X = Sheets("Sheet1").Cells(1, 1).Value
　Sheets("Sheet2").Select
Sheets("Sheet2").Range(Cells(X, 1), Cells(X, 7)).Select
Selection.Delete shift:=xlUp
－－－－－－－－－－

Sheet1のA1には任意の数字が入り、その数字に対応したセル範囲を削除するというものです

仮に3と入っているとして、Sheet2のA3からG3までを削除して
行を詰めたいと考えています

Sheet1のA1には確かに数字が入っていることは確認しております

あともし可能であれば、Sheets("Sheet2").Selectをしなくても
行を削除する方法があればご教授願いたいと思います

webでいろいろ調べてみましたが、Sheets("Sheet2").Select　としないといけないようでした

VBAはまったくの初心者ですので、そもそも調べ方が間違っているかもしれませんが・・・

回答No.4

imogasi · ベストアンサー

#1でご指摘のCellsを使わず
（下記はSheet2にXの行指定をいれ、Sheet1にデータがある例に変えています）
Sub test01()
x = Sheets("Sheet2").Cells(1, "A").Value
With Sheets("Sheet1")
.Range("A" & x & ":G" & x).Delete shift:=xlUp
End With
End Sub
でやると逃げられるようです。
簡略に
Sub test01()
x = Sheets("Sheet2").Cells(1, "A").Value
Sheets("Sheet1").Range("A" & x & ":G" & x).Delete shift:=xlUp
End Sub
でも出来ました。
私の好みか、列番号が固定なら、数字より、記号（例　G）の方が可視性が良いのでは。

回答No.3

Wendy02

こんばんは。

どこかで、似たような別の質問が出ていましたが、当面は、こんな感じでよいと思います。
Sheets("Sheet1") でもよいのですが、対象とするものは、Worksheet ですから、本来は、Worksheets("Sheet1")のように限定してあげるほうがよいです。

Sub Test1()
Dim i As Long
i = Worksheets("Sheet1").Cells(1, 1).Value
If i < 1 Then Exit Sub
With Worksheets("Sheet2")
　.Range(.Cells(i, 1), .Cells(i, 7)).Delete Shift:=xlUp
End With
End Sub

回答No.2

mitarashi

追伸
セル削除はselectしなくても、下記で可能と思います。
Sheets("Sheet2").Range(Sheets("Sheet2").Cells(x, 1), Sheets("Sheet2").Cells(x, 7)).Delete shift:=xlUp

お礼

ごめんなさい　お礼がかぶっちゃいました(^^

そうですね　selectする必要は、無いといえば無いですね
教本どおりに作ったものを改造していたので
よく理解していませんでした

このたびはありがとうございました

回答No.1

mitarashi

これは、よくはまります。
Sheets("Sheet2").Range(Sheets("Sheet2").Cells(x, 1), Sheets("Sheet2").Cells(x, 7)).Select
と、Cellsの方もシートを明確化する必要があります。

お礼

早速ありがとうございます
なるほど～　エラーについては解決しました

引き続き、Sheets("Sheet2").Selectをしなくても
行を削除する方法があれば教えていただきたいです