EXCEL：何点～何点までを評価５と表示させるには？

質問

学校の成績をEXCELでつけるのに、81点～100点を5段階評価のうちの５、
61点～80点を４・・・という風に、各生徒の評価を点数の横のセルに表示させたいのですが、方法を教えて下さい。

　　A　　B
　点数 評価　
1　79　　4
2　43　　2
3　67　　4
4　98

・・・という風にしたいのです。
宜しくお願いしますm(__)m

回答No.1

GOLDEN · ベストアンサー

=IF(A1>80,5,IF(A1>60,4,IF(A1>40,3,IF(A1>20,2,1))))

でどうでしょう？
一応、20点刻みで分けてありますが・・・

もしくは、20で割った値を端数切り上げて表示する
=ROUNDUP(A1/20,0)

お礼

迅速な回答本当にありがとうございます！！
ばっちりできました。
これからもすごく役に立ちます。
本当にありがとうございました。

回答No.5

comv

こんばんは！

セルＢ１に
　=LOOKUP(N(A1),{0,1,21,41,61,81;"",1,2,3,4,5})
必要行まで複写
（Ａ列が０、空白、文字の場合空白を返します）

で如何でしょうか！

お礼

回答ありがとうございます！
みなさん色々な方法を丁寧に教えていただいて感謝してます。
これなら10段階評価にも使えそうです。
本当にありがとうございました。

回答No.4

zinchan

VLOOKUP関数を用いる方法を紹介します。
　事前に、別のセルに、評価対応表を作ります。
　例えば、E2：F6の範囲に、この点数からはこの評価という対応表を下記のように作っておきます。
下限点 評価(5段階)
　0 1
20 2
40 3
60 4
80 5
　A列の各セルに対応するB列のセルに、VLOOKUP関数を下記のように入力しておきます。あとはセルをコピーすれば同様に評価がかえります。対応表の範囲は、絶対参照で指定(範囲を選択したら、F4キーを押して範囲の前に＄マークをつける）しておきます。
A2セルの数値が79なら、B2セルに =VLOOKUP(a2,$E$2:$F$6,2,TRUE)を入力すると4とかえってきます。
　この方法ですと、評価する数値を変更したいときに、いちいち式を変更せずに、対応表の数値を変えるだけで済みます。

お礼

詳しい回答ありがとうございます！！
ばっちりできました。
説明も丁寧にして頂いて感謝してます。
本当にありがとうございました。

回答No.3

noname#8602

=if(a1=>81,5,if(a1=>61,4,if(a1=>41,3,if(a1=>21,2,1))))

上記で、計算可能だと思います。後は、計算式をコピーしてB2以下のセルに貼り付けてください。

お礼

回答ありがとうございます！！
ばっちりできました♪
他の評価方法にも役に立ちます。
本当にありがとうございました。

回答No.2

spice_piri

B1のセルには
=+INT((A1-1)/20)+1

B2のセルには
=+INT((A2-1)/20)+1

B3のセルには
=+INT((A3-1)/20)+1

　　：

という計算式が入ります。100までの数字を５区分にするので、20で割ってあげることを行います。"-1"や"+1"は、その微調整の定数です。

お礼

回答ありがとうございます！！
この方法もばっちりできました。
色々な方法があって勉強になります。
本当にありがとうございました。