Access2000のレコードの変更確認メッセージ

質問

Access2000VBAでmdbファイル起動と同時に、「レコードの変更」と「アクションクエリ」の確認メッセージが表示されないように設定したいのですが、どのようにしたらよいのでしょうか？
困っています。よろしくお願いします。

回答No.2

tutty2 · ベストアンサー

ＶＢＡということなので、アクセス97なら以下のとおりなんですけど、2000でも同じでしょうか？

Option Compare Database
Option Explicit

Public ActQry_Status, RecChg_Status, ObjDel_Status As Variant

Function M_初期設定()
'
'オプションの編集/検索の確認の内容格納
'
ActQry_Status = Application.GetOption("Confirm Action Queries")
RecChg_Status = Application.GetOption("Confirm Record Changes")
ObjDel_Status = Application.GetOption("Confirm Document Deletions")

'
'オプションの内容変更
'
Application.SetOption "Confirm Action Queries", False
Application.SetOption "Confirm Record Changes", False
Application.SetOption "Confirm Document Deletions", False

End Function

これをそのまま貼り付ければできます。
なお、AutoExecという名前のマクロを作り、プロシージャの実行で上記モジュールを指定すれば、起動と同時に実行します。

さらに、以下のモジュールを実行すれば、設定を元に戻して終了します。

Function M_END()
'
'オプションの内容を初期設定に戻す
'
Application.SetOption "Confirm Action Queries", ActQry_Status
Application.SetOption "Confirm Record Changes", RecChg_Status
Application.SetOption "Confirm Document Deletions", ObjDel_Status

'
'終了
'
DoCmd.Quit acSave

End Function

お礼

どうも、ありがとうございました。
２０００でも設定できました。
マクロでのやり方がよく分からなかったので、上記モジュールを
フォームのLoadイベントにそのまま貼り付けて、実行したところ、
無事設定することができました。
とても助かりました。また、分からないことがあればよろしくお願いします。

回答No.1

kurisan

こんばんわ。momo-chanさん。

ツール→オプション→編集/検索タブの確認の項目欄で設定できますよ。
けど、VBAで！って事だったんでしょうか。。。？

お礼

ごめんなさい。この度はVBAということだったので・・・
でも、ありがとうございました。
また、わからないことがあればよろしくお願いします。