続ドラッグ＆ドロップ

質問

前に回答頂いたのですが、
お皿に乗った果物の上にさらに置くことができてしまうところを
置けないようにしたいのですが、どのようにしたらいいでしょうか？
もう１点なのですが、果物をお皿以外でreleaseしたら、果物の位置を
元の位置に戻にはどうしたらいいでしょうか？

たいへん申し訳ないのですがよろしくお願いします。

onClipEvent (load) {
// osara の枚数を登録
var o_num = 3;
// kudamono の個数を登録
var k_num = 5;
}
//
on (press) {
// ドラッグ開始（中央に吸着）
startDrag(this, true);
// 全ての osara を フレーム2 に進ませる
for (var i = 0; i<o_num; i++) {
_root["osara"+i].gotoAndStop(2);
}
// もし，osara が kudamono のどれかとヒットしていれば
for (var i = 0; i<o_num; i++) {
for (var j = 0; j<k_num; j++) {
if (_root["osara"+i].hitTest(_root["kudamono"+j])) {
// その osara を フレーム1 へ
_root["osara"+i].gotoAndStop(1);
}
}
}
}
//
on (release) {
for (var i = 0; i<o_num; i++) {
//ドラッグ中のMCの真下にosara? があれば
if (_root["osara"+i].hitTest(_root._xmouse, _root._ymouse, true)) {
// ドラッグ中のMCを osara? に吸着
this._x = _root["osara"+i]._x;
this._y = _root["osara"+i]._y;
}
}
//
// 全ての osara を フレーム1 に進ませる
for (var i = 0; i<o_num; i++) {
_root["osara"+i].gotoAndStop(1);
}
// ドラッグ終了
stopDrag();
}
//
onClipEvent (mouseMove) {
updateAfterEvent();
}

回答No.3

noname#35109

＃２です。

> 1一度果物をお皿に置いて、その果物を持っても
> 同じお皿に置けるにしたいと思っています。

なるほど，
同じお皿に置けるつもりでしたが，そうなっていませんでしたね。
これは次の 2 と 3 によって解消しました。

> 2お皿上以外でマウスを離しても
> 戻るようにしたいと思っています。

これが少し難しかったです。
本当はフラグを使いたくなかったので，
なるべくフラグを使わない方向にしていましたが，
どうも使わないと詰まるようになったので，
フラグである，「adh_flg」という変数を登場させてなんとかできるようにしました。
下のスクリプトで，変更点に ★ 印をつけました。

> 3最初に果物を一個皿に一度置いて
> それを持ち上げた瞬間は、３皿にドラッグ可能なので、
> そのときは３皿光るようにしたい。

これは簡単。

　if (_root["osara"+i].hitTest(_root["kudamono"+j]) && !_root["osara"+i].hitTest(this)) {
　　　　// その osara を フレーム1 へ
　　　　_root["osara"+i].gotoAndStop(1);
　}

条件をプラスしただけです。
下のスクリプトで，変更点に ★★ 印を付けました。

というわけでスクリプト。
kudamono0 ～ kudamono？ のムービークリップに書くスクリプトです。

----------------------
onClipEvent (load) {
// osara の枚数を登録
var o_num = 3;
// kudamono の個数を登録
var k_num = 5;
// 最初の座標の記録
var my_x = this._x;
var my_y = this._y;
// 吸着（adhesion）フラグ（flag）の初期値 ★
var adh_flg = 0;
}
//
on (press) {
// 吸着フラグ を 0 にする ★
var adh_flg = 0;
// ドラッグ開始（中央に吸着）
startDrag(this, true);
// 全ての osara を フレーム2 に進ませる
for (var i = 0; i<o_num; i++) {
_root["osara"+i].gotoAndStop(2);
}
// もし，osara が kudamono のどれかとヒットしていれば
// なおかつ この果物とその osara がヒットしていなければ ★★
for (var i = 0; i<o_num; i++) {
for (var j = 0; j<k_num; j++) {
if (_root["osara"+i].hitTest(_root["kudamono"+j]) && !_root["osara"+i].hitTest(this)) {
// その osara を フレーム1 へ
_root["osara"+i].gotoAndStop(1);
}
}
}
}
//
// MC上もしくはその他でマウスアップしたとき
on (release, releaseOutside) {
for (var i = 0; i<o_num; i++) {
// ドラッグ中のMCの真下にosara? があって
if (_root["osara"+i].hitTest(_root._xmouse, _root._ymouse, true)) {
// なおかつ osara? のフレームが 2 の場合
if (_root["osara"+i]._currentframe == 2) {
// ドラッグ中のMCを osara? に吸着
this._x = _root["osara"+i]._x;
this._y = _root["osara"+i]._y;
// 吸着フラグ を 1 にする ★
var adh_flg = 1;
}
}
}
// もしこの果物がどの皿とも吸着していなければ ★
if (adh_flg == 0) {
// 座標を元に戻す
this._x = my_x;
this._y = my_y;
}
//
// 全ての osara を フレーム1 に進ませる
for (var i = 0; i<o_num; i++) {
_root["osara"+i].gotoAndStop(1);
}
// ドラッグ終了
stopDrag();
}
//
onClipEvent (mouseMove) {
updateAfterEvent();
}
-----------------------------------

と，こんな感じでしょうか。

答えてくださる必要はありませんが，
しかし，一体これは何に使えるのでしょうか(笑)。

回答するために，
こちらでも作っているわけですが，
作りながら，
何を作ろうとされているんだろう？
トランプの ポーカー でもスピードでもないし，
何を一生懸命にされているんだろう？
と，フツフツ疑問が湧いてきます。

自分でも作りながら作ったもので遊んでみて，
結構面白く楽しめるのですが，
その面白さより，何コレ？？？
という不思議さの方おかしくて，笑えてしまいます。

回答No.2

noname#35109

前回回答した者ですが，
こんな感じでしょうか。
★印の部分のみを修正しました。

--------------------------------
onClipEvent (load) {
// osara の枚数を登録
var o_num = 3;
// kudamono の個数を登録
var k_num = 5;
// 最初の座標の記録★
var my_x = this._x;
var my_y = this._y;
}
//
on (press) {
// ドラッグ開始（中央に吸着）
startDrag(this, true);
// 全ての osara を フレーム2 に進ませる
for (var i = 0; i<o_num; i++) {
_root["osara"+i].gotoAndStop(2);
}
// もし，osara が kudamono のどれかとヒットしていれば
for (var i = 0; i<o_num; i++) {
for (var j = 0; j<k_num; j++) {
if (_root["osara"+i].hitTest(_root["kudamono"+j])) {
// その osara を フレーム1 へ
_root["osara"+i].gotoAndStop(1);
}
}
}
}
//
// MC上もしくはその他でマウスアップしたとき★
on (release, releaseOutside) {
for (var i = 0; i<o_num; i++) {
// ドラッグ中のMCの真下にosara? があって★
if (_root["osara"+i].hitTest(_root._xmouse, _root._ymouse, true)) {
// なおかつ osara? のフレームが 2 の場合★
if (_root["osara"+i]._currentframe == 2) {
// ドラッグ中のMCを osara? に吸着
this._x = _root["osara"+i]._x;
this._y = _root["osara"+i]._y;
} else {
// それ以外の場合は座標を元に戻す★
this._x = my_x;
this._y = my_y;
}
}
}
//
// 全ての osara を フレーム1 に進ませる
for (var i = 0; i<o_num; i++) {
_root["osara"+i].gotoAndStop(1);
}
// ドラッグ終了
stopDrag();
}
//
onClipEvent (mouseMove) {
updateAfterEvent();
}
--------------------------------

ActionScript が難しいのではなくて，
「どういう状況の場合どうしたいのか」
という「場合の数」のようなものが少し難しいのです。

> お皿に乗った果物の上にさらに置くことが
> できてしまうところを置けないようにしたい

この状況をよく考えます。

ドラッグ中の果物からマウスを放したとき，
お皿に先に果物が乗っている状況であれば，
お皿ムービークリップ内のタイムラインのフレームは，
フレーム1で光っていない状態のはずです。
ここから，

　もし お皿が光っていれば
　　→そのまま吸着
　もし お皿が光っていなければ
　　→元の位置に戻す

言いかえると

　もし お皿がフレーム2であれば
　　→そのまま吸着
　もし お皿がフレーム1であれば
　　→元の位置に戻す

というプログラムが考えられます。

ここまでが主にプログラミングに当たります。
そして次に，
そのプログラムを実際にActionScript に コーディング すれば良いわけです。
（※ コーディング＝プログラムを具体的なプログラムコードにすること。コード・イング。）

すると次のようになります。

　// osara? のフレームが 2 の場合
　if (_root["osara"+i]._currentframe == 2) {
　　　　// ドラッグ中のMCを osara? に吸着
　　　　this._x = _root["osara"+i]._x;
　　　　this._y = _root["osara"+i]._y;
　} else {
　// それ以外の場合は座標を元に戻す
　　　　this._x = my_x;
　　　　this._y = my_y;
　}

my_x と my_y という変数は，
その果物ムービークリップが表示されたとき，
その初期位置を記録しておいた変数です。

　onClipEvent (load) {
　　　// 最初の座標の記録
　　　var my_x = this._x;
　　　var my_y = this._y;
　}

補足

ありがとうございます。
なるほど、初期位置を記録しておいた変数を使うのですね。
徐々に理解できてきたのですが、

1一度果物をお皿に置いて、その果物を持っても同じお皿に置けるにしたいと思っています。
2お皿上以外でマウスを離しても戻るようにしたいと思っています。
3最初に果物を一個皿に一度置いてそれを持ち上げた瞬間は、３皿にドラッグ可能なので、そのときは３皿光るようにしたい。2個目だと、持ち上げた瞬間は２皿にドラッグ可能なので2皿光るようにしたいと思っています。

本当に何度もお答え頂いていて、補足質問ばかりで申し訳ないのですが
お願いできますでしょうか？

回答No.1

perse

>元の位置に戻にはどうしたらいいでしょうか？
元の位置のxy座標を覚えて置けばいいのです。
あとはrelease時に覚えておいた座標に移動させるだけです。

onClipEvent(load)で変数x,yを定義して
var x
var y

on(press)時に
x = this._x
y = this._y

on(release)時に
this._x = x
this._y = y
ですね。

>置くことができてしまうところを置けないようにしたいのですが
前回の質問のことは知らないのですが「置けないようにしたい」が
元の位置に戻したいという意味ならもう解決ですね。
それ以外なら補足願います。