Excelについて

質問

Excel2003を使用しています。
以下２件、質問です。

１．例えばF列で0(ゼロ)が入力されている行を削除するには
　　どういった方法が簡単でいいでしょうか？

２．例えばA列に数値と文字列が混在している場合に
　　文字列が入力されているセルをある特定の数値(例えば0900)に
　　置き換えるにはどういった方法がいいでしょうか？

以上、よろしくお願いします。

回答No.4

Wendy02 · ベストアンサー

こんにちは。

(1)　オートフィルタを使えば、このようになります。

ご覧の通り、結構、面倒ですが、大量の場合は、これが一番早いかもしれません。なお、0の入っている行全体という意味で取っていますので、EntireRow を使用していまする

Sub FindZeroRowDelete()
Dim i As Long
If ActiveSheet.AutoFilterMode = True Then
　 ActiveSheet.AutoFilterMode = False
End If
With Range("F1", Range("F65536").End(xlUp))
　　.AutoFilter Field:=1, Criteria1:="0"
　　On Error Resume Next
　　i = .Offset(1).Resize(.Rows.Count - 1).SpecialCells(xlCellTypeVisible).Count
　　On Error GoTo 0
　　If i > 0 Then
　　　.Offset(1).Resize(.Rows.Count - 1).EntireRow.Delete
　　End If
　　.AutoFilter
　　'1行目のチェック
　　If .Cells(1).Value = 0 Then .Cells(1).EntireRow.Delete
End With
End Sub

(2)

Sub ReplaceString2Figure()
　With Range("A1", Range("A65536").End(xlUp))
　　On Error Resume Next
　　.SpecialCells(xlCellTypeConstants, 2).NumberFormatLocal = "0000"
　　.SpecialCells(xlCellTypeConstants, 2).Value = 900
　　On Error GoTo 0
　End With

End Sub

なお、Private キーワードは、一般的には、イベントやサブルーチンに使用するものです。なお、セル一つずつ文字列を調べる場合は、VarType　でないと、取れないと思います。

お礼

回答ありがとうございます。
教えていただいた方法でうまくいきました。