できると言っちゃったばっかりに、、

質問

あの、、、VBでグラフを書きますよね。それでソレをVBで表示したいんです。JPGとかイメージファイルで保存とかして何とかできませんかねー、、。表はできるのにグラフができないわけがない、なんて言ったら「お願いね」って言われちゃった、、。誰か教えてくださーい。宜しくお願いします。

回答No.4

TAGOSAKU7

OLEオブジェクトなら以下のソースで大丈夫だと思います。
あらかじめデザイン時に、フォームのScaleModeをピクセルにしてください。
あとはcreBitMap関数を呼ぶだけで可能なはずです。

欠点としては、実行時にオブジェクトの上に何らかのフォームやウィンドウが前面にあったりすると、それもファイルイメージに取り込まれます。
それを回避する方法もありますが、以前に作成したサンプルがどこかに消えちゃいました。。。
結構大変な処理だった記憶がありますので勘弁してください。。。

Option Explicit

Private Declare Function StretchBlt Lib "gdi32" (ByVal hdc As Long, ByVal x As Long, ByVal y As Long, ByVal nWidth As Long, ByVal nHeight As Long, ByVal hSrcDC As Long, ByVal xSrc As Long, ByVal ySrc As Long, ByVal nSrcWidth As Long, ByVal nSrcHeight As Long, ByVal dwRop As Long) As Long

Private Sub Command1_Click()
　　'ファイルにしたいオブジェクトと、ファイルパスを指定
　　Call creBitMap(Me.OLE1, "c:\test.bmp")
End Sub

Private Sub creBitMap(inObj As Object, inFilePath As String)
　　Dim picWork As PictureBox

　　Dim lngL As Long, lngT As Long, lngW As Long, lngH As Long

　　'オブジェクトの左位置／上位置／幅／高さ を取得
　　With inObj
　　　　lngL = .Left: lngT = .Top: lngW = .Width: lngH = .Height
　　End With

　　'ピクチャボックスを作成
　　Set picWork = Controls.Add("VB.PictureBox", "picDmy")
　　'ピクチャボックスの初期設定
　　With picWork
　　　　.Appearance = 0
　　　　.AutoRedraw = True
　　　　.AutoSize = False
　　　　.BorderStyle = 0
　　　　.ScaleMode = vbPixels
　　　　.Width = lngW
　　　　.Height = lngH
　　End With

　　With picWork

　　　　'描画実行
　　　　Call StretchBlt(.hdc, 0, 0, lngW, lngH, Me.hdc, lngL, lngT, lngW, lngH, vbSrcCopy)

　　　　'画像の保存
　　　　Call SavePicture(.Image, inFilePath)
　　End With

　　'ピクチャボックスの破棄
　　Controls.Remove picWork
End Sub