ＣＡＳＬ(2)の問題について

質問

今年の夏ごろから興味があってＣＡＳＬ(2)の勉強をはじめたのですが、書籍などを調べても参考のようなものが載っておらず、どうしても分からない問題がありましたので、どなたかお分かりの方いらっしゃいましたらアドバイスをお願いいたします。

【問題】キーボードから得点（1～10）を複数件入力し、「入力された得点」、「平均点」、「合計点」を出力せよ。ただし、0（ゼロ）入力でデータ終了とする。
注）平均点は、小数点以下切り捨て可。

〔出力例〕
3　9　6　　GOKEI= 18　HEIKIN= 6

回答No.1

BLUEPIXY · ベストアンサー

;;正の数値を入力して、合計と平均を出す
;;０が入力されたら、結果を表示
MAIN START
LAD GR0,0
ST GR0,N ;入力した個数のクリア
ST GR0,SUM ;合計のクリア
LOOP IN INBUFF,INLEN
LD GR1,RADIX
LAD GR2,INBUFF
LAD GR3,INLEN
CALL STR2DEC ;数値に変換してGR0に求める
CPL GR0,=0 ;入力した数値が０だったら結果を表示して終了
JZE DISPNUM
LD GR4,N ;GR4はインデックスレジスタ
ST GR0,ARRAY,GR4 ;配列に保存
ADDL GR4,=1 ;N=N+1
ST GR4,N
ADDL GR0,SUM ;符号無しの足し算、入力は正の数
ST GR0,SUM
JUMP LOOP
DISPNUM LAD GR4,0
NEXTN LD GR0,ARRAY,GR4
CALL PUTNUM ;入力された数値の表示
ADDL GR4,=1
CPL GR4,N
JNZ NEXTN
DISPSUM OUT SUMMES,OUTLEN
LD GR0,SUM
CALL PUTNUM
CALCAVE LD GR1,SUM
LD GR2,N
CALL DIV ;GR3に商を求める（小数なし）
DISPAVE OUT AVEMES,OUTLEN
LD GR0,GR3
CALL PUTNUM
EXIT RET
SUM DS 1 ;合計
N DS 1 ;入力した数字の個数
ARRAY DS 20 ;入力した数字の配列
RADIX DC 10 ;入力を解釈する基数（１０進数で解釈）
INBUFF DS 256 ;入力領域
INLEN DS 1 ;入力文字数
SUMMES DC 'GOUKEI='
AVEMES DC 'HEIKIN='
OUTLEN DC 7
END
;
;GR0に入力された数字を出力する
PUTNUM START
PUSH 0,GR1
PUSH 0,GR2
PUSH 0,GR3
PUSH 0,GR4
LD GR1,GR0
LD GR2,BASE
LAD GR3,DISPNUM
LAD GR4,LEN
CALL DEC2STR
OUT DISPNUM,LEN
POP GR4
POP GR3
POP GR2
POP GR1
RET
DISPNUM DS 5 ;表示に使う領域たかだか５桁（６５５３６）
LEN DS 1 ;表示に使う文字の長さ
BASE DC 10 ;表示に使う基数
END
;
;文字列を数字に変換する
;GR0 は破壊される
;GR1 基数
;GR2 文字列アドレス
;GR3 文字数アドレス
;文字列を指定された基数で解釈して数字として、GR0に格納する
;BASEより大きい文字が使われているかどうかは調べない
STR2DEC START
PUSH 0,GR4
ST GR2,STR
ST GR3,LEN
LD GR3,0,GR3
LAD GR4,0 集計するために初期化
TEST CPL GR3,=0 文字数が０になるまで
JZE EXIT
LD GR0,0,GR2 文字を１文字読み出す
CALL TOUPPER GR0の文字を大文字にする
ST GR0,X
CALL STRCHR TABLEから文字Xの位置を調べる
LD GR0,POS
JMI NEXT 無効な文字の時無視する,
PUSH 0,GR2
LD GR2,GR4 GR4=GR4*BASE
CALL MULT GR0=GR1*GR2
LD GR4,GR0
ADDL GR4,POS GR4=GR4*BASE+POS
POP GR2
NEXT ADDL GR2,ONE
SUBL GR3,ONE
JUMP TEST
EXIT LD GR0,GR4
LD GR2,STR
LD GR3,LEN
POP GR4
RET
ONE DC 1
STR DS 1
LEN DS 1
;X で示される文字をTABLEから探して位置をPOSにセットする
;位置は0で始まる、見つからない時－１
X DS 1
POS DS 1
STRCHR PUSH 0,GR1
PUSH 0,GR2
PUSH 0,GR3
LD GR1,X
LAD GR2,0
LOOP LD GR3,TABLE,GR2
CPL GR1,GR3
JZE FINDED ;見つかった
CPL GR3,='Z'
JZE NOTFIND
ADDL GR2,=1
JUMP LOOP
NOTFIND LAD GR2,-1
FINDED ST GR2,POS
POP GR3
POP GR2
POP GR1
RET
TABLE DC '0123456789ABCDEFGHIJKLMNOPQRSTRVWXYZ'
END
;
;数字を文字列に変換する
;GR0 は破壊される
;GR1 変換する数
;GR2 基数
;GR3 文字列アドレス
;GR4 文字数アドレス
;数字を基数で示されたｎ進数の文字列に変換する
DEC2STR START
PUSH 0,GR5 アドレスポインタ
PUSH 0,GR1
PUSH 0,GR2
ST GR1,N
ST GR3,STR
ST GR4,STRLEN
LAD GR5,0
TEST CPL GR1,GR2 ;数>=基数
JMI EXIT
LOOP CALL DIV ;GR3=GR1/GR2,GR4=GR1%GR2
LD GR0,TABLE,GR4 c=TABLE[GR4]
LD GR4,STR
ADDL GR4,GR5
ST GR0,0,GR4 STR[GR5]=c
ADDL GR5,ONE
ST GR3,N
NEXT LD GR1,N
JUMP TEST
EXIT LD GR4,N
LD GR0,TABLE,GR4
LD GR4,STR
ADDL GR4,GR5
ST GR0,0,GR4
ADDL GR5,ONE
LD GR4,STRLEN
ST GR5,0,GR4 [STRLEN] に文字数をセット
LD GR1,STR
LD GR2,STRLEN
CALL REVERSE
POP GR2
POP GR1
POP GR5
RET
TABLE DC '0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ'
ONE DC 1
N DS 1
STR DS 1
STRLEN DS 1
END
;
;割り算する
;GR1 x
;GR2 y
;GR3 [x/y]
;GR4 x%y
;符号無しで商及び余りを求める
DIV START
PUSH 0,GR1
PUSH 0,GR2
ST GR1,X
ST GR2,Y
LAD GR3,0
LAD GR4,0
CPL GR2,ZERO 除数が０でないか？
JNZ COUNTY
OUT ='DIVIDED BY ZERO',=15
JUMP EXIT
COUNTY ADDL GR4,ONE ;カウンタ＋１
SRL GR2,1
JNZ COUNTY
ST GR4,YLEN ;Yのビット数が出る。
CHECK CPL GR1,Y ;x < y になったら
JMI QUIT
LAD GR4,0 ;カウンタ初期化
COUNTX ADDL GR4,ONE ;カウンタ＋１
SRL GR1,1
JNZ COUNTX
ST GR4,XLEN ;Xのビット数が出る。
SUBL GR4,YLEN ;XLEN - YLEN
LD GR0,ONE
SLL GR0,0,GR4
LD GR2,Y
SLL GR2,0,GR4 ;YをXに桁合わせする
LD GR1,X
CPL GR1,GR2 ;YがXより大きくなってしまった？
JPL SUB
JZE SUB
SRL GR0,1 ;１個シフトを戻す
SRL GR2,1
SUB ADDL GR3,GR0
SUBL GR1,GR2
ST GR1,X
JUMP CHECK
QUIT LD GR4,GR1 ;余りのセット
EXIT POP GR2
POP GR1
RET
X DS 1
Y DS 1
XLEN DS 1 ;Xのビット数
YLEN DS 1 ;Yのビット数
ZERO DC 0
ONE DC 1
END
;
;掛け算する
;GR1 x
;GR2 y
;GR0 SUM=x*y
;符号無し乗算,オーバーフロー検査なし
MULT START
PUSH 0,GR1
PUSH 0,GR2
LAD GR0,0 ;SUM=0
CPL GR1,ZERO
JZE EXIT ;x=0なら終了
TEST CPL GR2,ZERO
JZE EXIT ;yが０になったら終了
SRL GR2,1 ;最下位ビットがOVビットに入る
JOV ADD ;yの最下位ビットが立っているか？
JUMP SHIFT
ADD ADDL GR0,GR1 ;SUM=SUM+x
SHIFT SLL GR1,1 ;x=x*2
JUMP TEST
EXIT POP GR2
POP GR1
RET
ZERO DC 0
END
;
;GR0 に入れた文字を大文字にする
TOUPPER START
PUSH 0,GR1
IF CPL GR0,SMALLA ;IF 'z' >= GR0 >= 'a'
JMI EXIT
CPL GR0,='z'
JPL EXIT
THEN LD GR1,SMALLA
SUBL GR1,LARGEA
SUBL GR0,GR1
ENDIF DS 0
EXIT POP GR1
RET
SMALLA DC 'a'
LARGEA DC 'A'
END
;
;文字列を反対に並べる
;GR0 は破壊される
;GR1 文字バッファアドレス
;GR2 文字数アドレス
;反対に並べる
REVERSE START
PUSH 0,GR3 FRONTアドレスポインタ
PUSH 0,GR4 BACKアドレスポインタ
LD GR3,GR1
LD GR0,0,GR2
LD GR4,GR1
ADDL GR4,GR0 BACK = FRONT + LEN -1
SUBL GR4,=1
TEST CPL GR3,GR4 FRONT - BACK < 0?
JMI LOOP
JUMP EXIT
LOOP LD GR0,0,GR3 SWAP(*GR3,*GR4)
ST GR0,WK
LD GR0,0,GR4
ST GR0,0,GR3
LD GR0,WK
ST GR0,0,GR4
NEXT LAD GR3,1,GR3 GR3++
LAD GR4,-1,GR4 GR4--
JUMP TEST
EXIT POP GR4
POP GR3
RET
WK DS 1 避難所
END

お礼

とてもお忙しい中、回答くださってありがとうございます。かなり長いので苦労なさったのではないかと思います。本当にありがとうございました。
些細なことなのですが、内容に関して質問がありまして、一番最後から7行目にある『GR4--』や8行目の『GR3++』などは入力しなくてもいいのでしょうか？すいませんかなり基礎的なことですが・・・。

回答No.2

BLUEPIXY

#1>一番最後から7行目にある『GR4--』や8行目の『GR3++』などは入力しなくてもいいのでしょうか？
それは、コメントなので入力しなくてもいいです。
ＣＡＳＬＩＩの仕様で、
オペランドが無い場合にコメントを書くには、セミコロン';'が必要ですが、
オペランドがある場合、
オペランドの次にスペースをはさんでコメントを書くことができます。
一般的には、統一的に;を書くようですが、仕様上はそうなっています。

入力するより、メールで来た内容をコピー＆ペーストすれば、いいと思いますけどね。

以前に、割り算するルーチンなどは作ってあったので、
今回作ったのは、MAINの部分とPUTNUMだけですが、
そのために、冗長になっていますね。
まあ、使い回しができるとは思います。
なので、それほど、労力は掛かっていません。
まあ、人のプログラムを読み解くのは、難しいと思いますが、がんばって下さい。
別に、これに惑わされずに、自分でも書いてみれば良いと思います。
動作がおかしいとか、わからんとかあれば、
また、遠慮せず聞いて下さい。

お礼

ありがとうございます。なんとか一通りし終えてうまく成功することができました！！まだＣＡＳＬ(2)をはじめて間もないですが、このような問題を自分で頑張ってできるように日々努力して行きたいと思います。ほんとうにありがとございました。また別の内容で不明な点が出てくるかも知れません。そのときはまたお世話になるかもしれませんが、よろしくお願いします。