VBN セルの結合と、色分け

質問

VBN教えてください。
画像の左→右のようにしたいのですが、
まず、1列目の上下同じセルを結合します。
2列目、3列目は、1列目の結合範囲内で、上下同じセルを結合します。

さらに、結合された1列目を基準に、交互に色をつけたいのです。

詳しい方、教えていただけませんでしょうか。
よろしくお願い致します。

回答No.1

SI299792

VBN が何だかわからないので、VBA で作りました。
C10 は隣のB10 が変化してますが、分割しなくていいのですか。

Option Explicit
Option Base 1
'
Sub Macro1()
　　Dim Row As Long
　　Dim MergeFlg As Boolean
　　Dim Col As Integer
　　Dim STartArr(3) As Long
　　Dim Start As Variant
　　Dim ColorFlg As Boolean
'
　　Application.DisplayAlerts = False
'
　　For Row = 2 To [A1].End(xlDown).Row
　　　　MergeFlg = False
'
　　　　If Cells(Row, "A") <> Cells(Row + 1, "A") Then
　　　　　　Start = STartArr(1) + 2
　　　　　　MergeFlg = True
　　　　　　ColorFlg = Not ColorFlg
'
　　　　　　If ColorFlg Then
　　　　　　　　Cells(Start, "A").Resize(Row - Start + 1, 3) _
　　　　　　　　　　.Interior.Color = &HDAE9FC
　　　　　　End If
　　　　End If
'
　　　　For Col = 1 To 3
'
　　　　　　If Cells(Row, Col) <> Cells(Row + 1, Col) Or MergeFlg Then
　　　　　　　　Start = STartArr(Col) + 2
　　　　　　　　Cells(Start, Col).Resize(Row - Start + 1).Merge
　　　　　　　　STartArr(Col) = Row - 1
　　　　　　End If
　　　　Next Col
　　Next Row
　　Range("A1:C" & Row).Borders(xlInsideHorizontal).LineStyle = xlContinuous
　　Application.DisplayAlerts = True
End Sub

お礼

早速ありがとうございます。
VBAでした、失礼しました。
そのまま使わせていただいて、できました。
なにが書いてあるか、理解できていないのですが、解読して、応用できるようにしたいです。
大変助かりました。