VBAの表からシートを作成したい

質問

現在の構文は以下のようになっています。

Dim ws As Range
For Each ws In Worksheets("ユーザー情報").Range("C2:C201")
On Error GoTo myError
If Not ws Is Nothing Then
Worksheets("雛形").Copy After:=Worksheets(Worksheets.Count)
ActiveSheet.name = ws.Value
End If
Next ws
Exit Sub

myError:
nm = "雛形 (2)"

For Each sh In Worksheets
If sh.name = nm Then
Application.DisplayAlerts = False
Worksheets(nm).Delete
Application.DisplayAlerts = True
End If
Next

「ユーザー情報」シートのC列に氏名を記入して上記マクロを実行すれば、その氏名ごとに「雛形」を元にしたシートが連続でコピーされる形になっています。
しかし、1度実行した後、あらたにC列に氏名を追加してもその分のコピーを作ってくれなくなります。
どのようにすればよいでしょうか。アドバイスをいただければと思います。

回答No.1

kkkkkm · ベストアンサー

追加したときに最初にあったシート名でエラーになって"雛形 (2)"を削除して終わっているからです。
このようなかたちでいかがですか。
Sub Test()
Dim ws As Range, sh As Worksheet
Dim flg As Boolean
With Worksheets("ユーザー情報")
For Each ws In .Range(.Cells(2, "C"), .Cells(Rows.Count, "C").End(xlUp))
flg = False
For Each sh In Worksheets
If sh.Name = ws Then
flg = True
Exit For
End If
Next sh
If flg = False Then
Worksheets("雛形").Copy After:=Worksheets(Worksheets.Count)
ActiveSheet.Name = ws.Value
End If
Next ws
End With
End Sub

お礼

ご回答ありがとうございます。
いただいた構文だけでは実行時エラーが出て雛形（2）が作成されてしまったためGoToステートメントで回避しました。