シートを増やすVBA

質問

フィルタで隠れている場合もある列の値を
シート名として増やしていくVBAで以下のようなものをつくりました
（値は重複している場合もある）

雛型シートがありそれをシート名だけ増やしていくというものです

Sub シートを増やす()

Dim target As Range
Dim h As Range

On Error Resume Next
Set target = Worksheets("一覧シート").Range("E10:E" & Worksheets("一覧シート").Range("E65536").End(xlUp).Row).SpecialCells(xlCellTypeVisible)
If target Is Nothing Then Exit Sub

'シートを増やしていく
For Each h In target
On Error GoTo errhandle
Worksheets(h.Value).Select
On Error GoTo 0
Next
Sheets("一覧シート").Select
Exit Sub
errhandle:
Worksheets("雛型").Copy after:=Worksheets(Worksheets.Count)
ActiveSheet.Name = h.Value
Resume

End Sub

そうすると、実行エラー1004
”シートの名前をほかのシート、Visual　Basicで参照されるオブジェクトライブラリまたはワークシートと同じ名前に変更することはできません。”
というエラーがたまにおきます（シート名が数字の場合におきるようです）

解決方法及び理由をご教授ください

回答No.2

emaxemax · ベストアンサー

ANo1のemaxemaxです、やっぱりそうでしたか。

On Error GoTo errhandle
Worksheets(h.Value).Select

は、エラーとなる重複するシート名をさけるためですよね。
その場合、h.Valueが文字列であれば問題ないのですが、数値の場合、たとえば
h.Valueが10だとすると
Worksheets(h.Value)は、Worksheets(10)となり、左から10番目のシートという意味になってしまいます。
そうならないようにCstr関数でh.Valueをすべて文字に変えてみました。
これで数値の10は文字列化するので
Worksheets("10")というシートになります。

お礼

なるほど、ほぼ完全に理解できました
ありがとうございます

回答No.1

emaxemax

> シート名が数字の場合におきるようです

だとすれば、

On Error GoTo errhandle
Worksheets(h.Value).Select

これを
On Error GoTo errhandle
Worksheets(CStr(h.Value)).Select

としたらどうなりますか？

お礼

ありがとうございます。
こちらで試したところ、問題なくエラーが起きずに
実行完了いたしました