VBA アクティブセルに対しての作業に関して

質問

-質問内容-VBA作成2つ-

ActiveCell.Offset(RowOffset:=[O1991], Columnoffset:=0).Activate

アクティブセルを指定した段階で
オフセット(縦下方向にO1991のセルに入れた数値分下に、ヨコに0)
移動しアクティブセルにする

------------------------------------------------------
------------------------------------------------------
別々のVBAでやりたいこと

(1)これを、アクティブセルを指定した段階で
セルの値をコピーして
オフセット縦下にO1991.ヨコ0分下にペースト(貼り付け)
したい

例)　　

　　A　　　
1　成功　　←アクティブセルをコピー　　
3　成功　　←　ActiveCell.Offset(RowOffset:=[O1991], Columnoffset:=0).Activate　

アクティブセル～オフセットしたセルまでを最初にアクティブセルからコピーし
→アクティブセル～オフセットしたセルまでペーストする

-----------------------------------------

(2)これを、アクティブセルを指定した段階で
セルの値をコピーして
オフセット縦下にO1991.ヨコ0分下に
アクティブセル～オフセットされたセル位置まで
フィルダウンさせたい

例)　　

　　A　　　
1　1　←アクティブセルをコピー　　
5　 ←オフセットセル

2つのVBAのやり方/プログラムの表記/組み合わせ方を
無知で愚かな私ですが
どうかご教授のほど
宜しくお願い致します
(>_<)謝↓ペコッ
---------------------------------------
---------------------------------------
変数を使うのでしょうか?

セル範囲を指定するとして
Range("ActiveCell:ActiveCell.Offset(RowOffset:=[O1991], Columnoffset:=0).Active")
となるのでしょうか?
又変数の使い方として
Dim a As Range
又は
Dim a As Objectになるのでしょうか

この際代入として使うには
a = ActiveCell
b = ActiveCell.Offset(RowOffset:=[O1991], Columnoffset:=0).Activate
になるのでしょうか

本当に度々申し訳ないのですが
宜しくお願いします
(:>_<:)ペコリ

Range(ActiveCell).copy
ActiveCell.Offset(RowOffset:=[O1991], Columnoffset:=0)ActiveCell.PasteSpecial
End Sub

回答No.1

kagakusuki · ベストアンサー

(1)のVBAの一例としては以下の様なVBAとなります。

Sub QNo9157101_VBA_アクティブセルに対しての作業に関して1()

Const OffsetValueCell = "O1991"
Dim buf As Variant, myOffset As Long

buf = Range(OffsetValueCell).Value
If buf <> "" And IsNumeric(buf) Then _
myOffset = Int(buf)

With Application
.ScreenUpdating = False
.Calculation = xlManual
End With

If buf = myOffset And myOffset + ActiveCell.Row >= 1 _
And myOffset + ActiveCell.Row <= Rows.Count Then
ActiveCell.Offset(myOffset).Value = ActiveCell.Value
Else
MsgBox OffsetValueCell _
& "セルに入力された値が、現在選択されている" _
& "セルの行番号に対して有効な範囲にありません"
End If

With Application
.Calculation = xlAutomatic
.ScreenUpdating = True
End With

End Sub

　(2)のVBAの一例としては以下の様なVBAとなります。

Sub QNo9157101_VBA_アクティブセルに対しての作業に関して2()

Const OffsetValueCell = "O1991"
Dim buf As Variant, myOffset As Long

buf = Range(OffsetValueCell).Value
If buf <> "" And IsNumeric(buf) Then _
myOffset = Int(buf)

With Application
.ScreenUpdating = False
.Calculation = xlManual
End With

If buf = myOffset And myOffset + ActiveCell.Row >= 1 _
And myOffset + ActiveCell.Row <= Rows.Count Then
Range(ActiveCell, ActiveCell.Offset(myOffset)).Value = ActiveCell.Value
Else
MsgBox OffsetValueCell _
& "セルに入力された値が、現在選択されている" _
& "セルの行番号に対して有効な範囲にありません"
End If

With Application
.Calculation = xlAutomatic
.ScreenUpdating = True
End With

End Sub