バッチでfor文で文字列の中身を繰り返したい

質問

バッチで、for文で、半角スペースやタブ以外で区切られた文字列から、区切り文字毎に
取り出したいのですが、最初の1回しか取り出せません。最後まで繰り返しが行われませ
ん。
バッチでは、そもそも、半角スペースやタブ以外では、文字列の中身を繰り返すことは
できないのでしょうか。
それとも、他に良い方法があります。

やっていることは、
例えば、
for文で、スラッシュ「/」で区切られた文字列からスラッシュ毎に取り出そうとしている
のですが、最初の1回目しか表示されず、最後まで繰り返しが行われません。
以下、色々と試したのですが．．．．．

set str=abc/def/ghi/jkl/mno/pqr/stu/vwx/yz

for %%a in (%str%) do echo %%a
の場合は、
1行そのまま表示されます。（あたりまえです。）

for "delims=/" %%a in (%str%) do echo %%a
for "delims=/" %%a in ('echo %str%') do echo %%a
の場合は、
「"delims=/" の使い方が誤っています。」となります。

for /f "delims=/" %%a in ('echo %str%') do echo %%a
の場合は、
最初の1回目の「abc」しか表示されず、そこで処理が終わり、残りが表示されない。

期待している結果は、
これを、
abc
def
ghi
jkl
mno
pqr
stu
vwx
yz
と表示させたい。

set str=abc def ghi jkl mno pqr stu vwx yz
for %%a in (%str%) do echo %%a
の場合は、
abc
def
ghi
jkl
mno
pqr
stu
vwx
yz
と表示されます。

バッチでは、そもそも、半角スペースやタブ以外では、文字列の中身を繰り返すことは
できないのでしょうか。
できる場合、その方法を教えてください。また、他に良い方法がありましたら、教えて下さい。

回答No.1

notnot · ベストアンサー

結論から書くと、この場合は、

for %%a in (%str:/= %) do echo %%a

と、/ を空白に置換するのが簡単です。空白でなく、カンマかセミコロンでもいいです。

for %%a in (%str:/=,%) do echo %%a

以下、あなたの書いたものが何故だめかを書きます。

＞for "delims=/" %%a in (%str%) do echo %%a
＞for "delims=/" %%a in ('echo %str%') do echo %%a

こんな構文はありません。構文エラーです。
for /? をよく見てください。どこにこんな構文が書いてありますか？書いてないでしょ？

＞for /f "delims=/" %%a in ('echo %str%') do echo %%a

これは構文は正しいです。/ 区切りの最初の塊を %%a で参照するという意味になります。
2番目以降を参照するには、
for /f "delims=/ tokens=1-5" %%a in ('echo %str%') do echo 1: %%a, 2: %%b, 3: %%c, 4: %%d, 5: %%e
などのように、tokensで何番目の塊を参照したいかを指定して、%%a %%b などで参照する事になります。ただ、これでは望む結果は得られませんね。
for /f は、縦方向の繰り返しなので、横方向に繰り返すことは出来ません。
この場合、echo %str% の出力は1行なので、繰り返しは1回になります。

お礼

ありがとうございます。

期待した結果になりました。

> for /?
すみません。よく見ていませんでした。