エクセルのセル内の操作について

質問

いつもお世話になっております。

A1セル【01/29/2013 08:09:46】（文字列）→A2セル【2013/01/29 08:09:46】（日付）としたいのですが操作方法が分かりません。

A2セルに=DATE(MID(A1,7,4),LEFT(A1,2),MID(A1,4,2))と入力して日付までは表示できたのですが、時間はどうすればよろしいのでしょうか？

よろしくお願いします。

回答No.5

tok-okwave · ベストアンサー

参考になれば幸いです。
結論から言えば、既に回答されている結果を総合、補足するだけですが、
数式の一例は
=DATE(MID(A1,7,4),LEFT(A1,2),MID(A1,4,2))+
TIME(MID(A1,12,2),MID(A1,15,2),RIGHT(A1,2))
セルの表示形式は
yyyy/mm/dd hh:mm:ss
とすればよいです。
ポイントは２つです。
ポイント１：日付と時刻・時間はシリアル値で処理される
ポイント２：シリアル値を希望する日付、時刻・時間に表示するための
表示形式の設定が必要
ポイント１では、数式のDATE(・・・) の項が日付のシリアル値となります。、
　　　　　　　　TIME(・・・)の項が時刻・時間のシリアル値となります。
何故、合計するかというと、シリアル値は整数部分が日付、
小数部分が時刻・時間で構成されるからです。
つまり、日付の日数１日間、または 1900年1月1日 が数値「1」と定義され、
　　　　日付の日数２日間、または 1900年1月2日 は数値「2」となります。
　　　　ちなみに2013年8月6日は　41492　という整数になります。
（＝1900年1月1日 から 41492経過した日数）
一方、時間・時刻 は、１日＝24時間　または　時刻＝24時　を数値「1」と
定義しますから、
　　　12時間　または 時刻の12時（正午）は「0.5」というシリアル値です。
　　　つまり、1時間 ＝ 1/24 、1分 = 1/24/60　1秒＝1/24/60/60 という
小数のシリアル値になります。
従って、 2013年8月6日 12時00分00秒　は 41492 + 0.5 = 41492.5 という
シリアル値になります。
ポイント２では、１つのシリアル値に対して、希望する日付、時刻・時間
の表示が数種類用意されていて、それを指定する必要があるのです。
例： 日付　2013年8月6日　2013/08/06 時間・時刻　15時30分　15:30
セルの表示形式（セルの書式設定の一部）は、セルを選択後、
Ctrlキー を押しながら 「ぬ」キー （数字 1 : テンキーはだめ）を押して
「セルの書式設定」ダイアログを起動し、「表示形式」タブ をクリックし、
希望する形式を選択します。
日付と時刻のシリアル値は、表示形式の「標準」を指定すればわかります。
時間・時刻は「数値」を指定し、小数点の桁数を少なくとも 5桁 に指定。
★表示形式を変更しても、元のシリアル値は変更されません。
★「日付」には「西暦」と「和暦」の指定ができます。
★日付・時刻を入力してから「標準」「数値」の表示形式にした後、
「日付」「時刻」から希望の 形式に設定するか、戻しボタンを押せば、
簡単に　元の日付・時刻の形式に戻せます。
ここでは、表示形式を「ユーザ定義 」にし、「種類」欄に半角で
すでに回答されているように
yyyy/mm/dd hh:mm:ss
と入力して「OK]を押します。

回答No.4

bunjii

>時間はどうすればよろしいのでしょうか？
A2セルの関数式に下記の式を追記してください。

+TIME(MID(A1,12,2),MID(A1,15,2),MID(A1,18,2))

桁数が固定されている文字列を日付/時刻の値に変える場合はDATE関数とTIME関数を加算すれば良いことになります。
DATE関数で整数部、TIME関数で小数部に変換されますので単純に加算すればOKです。

お礼

ありがとうございます。

回答No.3

keithin

＞時間はどうすればよろしいのでしょうか

=DATE(MID(A1,7,4),LEFT(A1,2),MID(A1,4,2))+RIGHT(A1,8)
として、yyyy/mm/dd hh:mm:ssの表示形式を付けておくので十分です。

回答No.2

tsubuyuki

=DATE(MID(A1,7,4),LEFT(A1,2),MID(A1,4,2))+TIMEVALUE(RIGHT(A1,8))

というやり方もありかもしれません。

お礼

ありがとうございます。

回答No.1

noname#204879

A2: =(MID(A1,7,4)&"/"&LEFT(A1,5)&MID(A1,11,9))*1
　　書式 yyyy/mm/dd hh:mm:ss

お礼

ありがとうございます。